C_MfgOrderObjPgComp

@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Manufacturing Order Object Page Com'
@VDM.viewType: #CONSUMPTION
@ObjectModel.representativeKey: 'ReservationItem'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@Metadata.allowExtensions: true
@UI.headerInfo.typeName: 'Component'
@UI.headerInfo.typeNamePlural: 'Components'

define view entity C_MfgOrderObjPgComp
  as select from I_MfgOrderOperationComponent as comp

  association [1..1] to I_MfgOrderOperationBySemanKey as _MfgOrderOperationBySemanKey on  $projection.ManufacturingOrder          = _MfgOrderOperationBySemanKey.ManufacturingOrder
                                                                                      and $projection.ManufacturingOrderSequence  = _MfgOrderOperationBySemanKey.ManufacturingOrderSequence
                                                                                      and $projection.ManufacturingOrderOperation = _MfgOrderOperationBySemanKey.ManufacturingOrderOperation

{
       @ObjectModel.foreignKey.association: '_Reservation'
  key  comp.Reservation,
       @UI.hidden: true
  key  comp.ReservationItem,
       @UI.hidden: true
  key  comp.RecordType,
       @UI.lineItem:[{position:10}]
       comp.BillOfMaterialItemNumber,
       @UI.lineItem: [{position: 20}]
       @EndUserText.label: 'BOM Item Text'
       @Semantics.text: true
       comp.BOMItemDescription,      // BOMItemDescription,

       @Consumption.semanticObject: 'Material'
       @UI.lineItem:[{position: 30}]
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MaterialStdVH', element: 'Material' } } ]
       @UI.identification:[{type: #WITH_INTENT_BASED_NAVIGATION,semanticObjectAction: 'display' }]
    
       comp.Material,                // Material,

       @UI.lineItem: [{position:35}]
       cast(comp._Material._Text[1:Language=$session.system_language].MaterialName as maktx) as MaterialName,  //MaterialDescription

       @UI.lineItem: [{position:40}]
       @ObjectModel.foreignKey.association: '_Plant'
       @Consumption.valueHelpDefinition: [{ entity: { name: 'I_PlantVH', element: 'Plant' } }]
       comp.Plant,                   // IssuingPlant,

       @UI.hidden: true
       comp.ProductionPlant,
       @UI.lineItem: [{position:50}]
       comp.MatlCompRequirementDate, // RequirementsDate,

       @EndUserText.label: 'Unit'
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' } } ]
       comp.BaseUnit,                // BaseUOM,

       @Semantics.quantity.unitOfMeasure: 'BaseUnit'
       @UI.lineItem: [{position: 60}]
       comp.RequiredQuantity,        // RequiredQuantity,

       comp.WithdrawnQuantity,       // Issued Quantity

       @UI.hidden: true
       comp.BOMItem,                 // BOMItem,

       @ObjectModel.foreignKey.association: '_StorageLocation'
       @Consumption.valueHelpDefinition: [ { entity:  { name:    'I_ProductionStorageLocationVH', element: 'StorageLocation' } } ]      
       cast(comp.StorageLocation as pph_lgort preserving type ) as StorageLocation, // IssuingStorageLocation,

       @Consumption.valueHelpDefinition: [ { entity:  { name:    'I_ProductionSupplyAreaVH', element: 'ProductionSupplyArea' } } ]
       comp.SupplyArea, // ProductionSupplyArea

       @UI.hidden: true
       @ObjectModel.foreignKey.association: '_MfgOrderSequence'
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderSequenceStdVH', element: 'ManufacturingOrderSequence' } } ]
       comp.ManufacturingOrderSequence,
       @UI.hidden: true
       @ObjectModel.foreignKey.association: '_MfgOrder'
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
       @EndUserText.label: 'Production Order'
       comp.ManufacturingOrder, //ProductionOrder,

       //@Consumption.semanticObject: 'Operation'  // Semantic Object still to be created

       @ObjectModel.foreignKey.association: '_MfgOrderOperationBySemanKey'
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderOperationVH', element: 'ManufacturingOrderOperation' } } ]
       //@UI.lineItem:{type: #WITH_INTENT_BASED_NAVIGATION,semanticObjectAction: 'display' }

       comp.ManufacturingOrderOperation, // AssignedOperation,

       @ObjectModel.foreignKey.association: '_MfgOrderCategory'
       @UI.hidden: true
       comp.ManufacturingOrderCategory,
       @ObjectModel.foreignKey.association: '_MfgOrderType'
       @Consumption.valueHelpDefinition: [ { entity: { name: 'I_OrderTypeVH', element: 'OrderType' } } ]
       comp.ManufacturingOrderType,
       @UI.hidden: true
       comp.OrderInternalBillOfOperations, //AssignedOperation

       //Associations      

       comp._OrdInternalBillOfOperations,
       comp._Material,
       comp._MfgOrderSequence,
       comp._MfgOrder,
       comp._MfgOrderOperationBySemanKey,
       comp._StorageLocation,
       comp._SupplyArea,
       comp._Plant,
       comp._MfgOrderType,
       comp._Reservation,
       comp._MfgOrderCategory
};