I_MfgOrderOperationBySemanKey

@AbapCatalog.sqlViewName: 'IPPMFGORDOPBYSMK'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'ManufacturingOrderOperation'
@ObjectModel.semanticKey: ['ManufacturingOrder', 'ManufacturingOrderSequence', 'ManufacturingOrderOperation']
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API  //status "not to be released - Stable", see DINC0265162

@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'I_MfgOrderOperationBySemKey'
@VDM.viewType: #BASIC
@EndUserText.label: 'Manufacturing Order Operation By Semantic Key'
// To be used mainly for foreign key purposes using the semantic key

// Please use successor view I_MfgOrderOperationBySemKey for operation field w/o conversion exit


define view I_MfgOrderOperationBySemanKey
  as select distinct from I_MfgOrderOperationBasic as afvc

  association [1..1] to I_ManufacturingOrder as _ManufacturingOrder on  $projection.ManufacturingOrder = _ManufacturingOrder.ManufacturingOrder
  association [1..1] to I_MfgOrder           as _MfgOrder           on  $projection.ManufacturingOrder = _MfgOrder.ManufacturingOrder
  association [1..1] to I_MfgOrderSequence   as _MfgOrderSequence   on  $projection.ManufacturingOrder         = _MfgOrderSequence.ManufacturingOrder
                                                                    and $projection.ManufacturingOrderSequence = _MfgOrderSequence.ManufacturingOrderSequence
  association [1..1] to I_Plant              as _ProductionPlant    on  $projection.ProductionPlant = _ProductionPlant.Plant
  association [1..1] to I_OrderInternalID    as _OrderInternalID    on  $projection.OrderInternalBillOfOperations = _OrderInternalID.OrderInternalID

{
      // Key

      @ObjectModel.foreignKey.association: '_MfgOrder'
  key afvc.ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_MfgOrderSequence'
  key afvc.ManufacturingOrderSequence,
      @ObjectModel.text.element: ['MfgOrderOperationText']
  key afvc.ManufacturingOrderOperation,

      // SubOp/Phase

      afvc.OperationIsSubOperation,
      afvc.MfgOrderOperationIsPhase,
 
      // Order header data

      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      afvc.ManufacturingOrderCategory,
      @ObjectModel.foreignKey.association: '_MfgOrderType'
      afvc.ManufacturingOrderType,
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      afvc.ProductionPlant,

      // Text

      @Semantics.text: true
      cast(afvc.MfgOrderOperationText as mfgorderoperationtext preserving type) as MfgOrderOperationText,

      // Technical Key

      @ObjectModel.foreignKey.association: '_OrderInternalID'
      afvc.OrderInternalBillOfOperations,
      afvc.OrderIntBillOfOperationsItem,
      
      // Confirmation

      @ObjectModel.foreignKey.association: '_ConfirmationGroup'      
      afvc.OperationConfirmation,
      afvc.NumberOfOperationConfirmations,
      
      // Associations

      _ManufacturingOrder,
      @VDM.lifecycle.successor: '_ManufacturingOrder'
      @VDM.lifecycle.status: #DEPRECATED
      _MfgOrder,
      _MfgOrderSequence,
      _MfgOrderCategory,
      _MfgOrderType,
      _ProductionPlant,
      _OrderInternalID,
      _ConfirmationGroup
};