C_MfgOpNotStartedReleased

DDL: C_MFGOPNOTSTARTEDRELEASED Type: view_entity CONSUMPTION Package: MPE_EXEC_SFO

Manufacturing Operation not started

C_MfgOpNotStartedReleased is a Consumption CDS View that provides data about "Manufacturing Operation not started" in SAP S/4HANA. It reads from 2 data sources (I_OrderOperation, I_MfgOrderBasic) and exposes 12 fields with key fields OrderInternalBillOfOperations, OrderIntBillOfOperationsItem. It has 4 associations to related views. Part of development package MPE_EXEC_SFO.

2 data source(s) 12 fields

Data Sources (2)

SourceAliasJoin Type
I_OrderOperation afvg from
I_MfgOrderBasic aufv inner

Associations (4)

CardinalityTargetAliasCondition
[1..1] I_OrderInternalID _OrdInternalBillOfOperations $projection.OrderInternalBillOfOperations = _OrdInternalBillOfOperations.OrderInternalID
[1..1] I_Plant _ProductionPlant $projection.ProductionPlant = _ProductionPlant.Plant
[0..1] I_WorkCenter _WorkCenter $projection.WorkCenterTypeCode = _WorkCenter.WorkCenterTypeCode and $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
[0..1] I_WorkCenterType _WorkCenterType $projection.WorkCenterTypeCode = _WorkCenterType.WorkCenterTypeCode

Annotations (7)

NameValueLevelField
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Manufacturing Operation not started view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #CONSUMPTION view

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY OrderInternalBillOfOperations
KEY OrderIntBillOfOperationsItem
ManufacturingOrderCategory I_MfgOrderBasic ManufacturingOrderCategory
ManufacturingOrderType I_MfgOrderBasic ManufacturingOrderType
Reservation I_MfgOrderBasic Reservation
ProductionPlant
WorkCenterInternalID
WorkCenterTypeCode I_OrderOperation WorkCenterTypeCode_2
_OrdInternalBillOfOperations _OrdInternalBillOfOperations
_ProductionPlant _ProductionPlant
_WorkCenter _WorkCenter
_WorkCenterType _WorkCenterType 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Manufacturing Operation not started'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}
@VDM.viewType: #CONSUMPTION
define view entity C_MfgOpNotStartedReleased
  as select from           I_OrderOperation          as afvg
    inner join             I_MfgOrderBasic           as aufv                        on aufv.OrderInternalID = afvg.OrderInternalID
    left outer to one join I_StatusObjectStatusBasic as DeletedOperation            on  DeletedOperation.StatusObject     = afvg.ObjectInternalID
                                                                                    and DeletedOperation.StatusCode       = 'I0013'
                                                                                    and DeletedOperation.StatusIsInactive = ''
    left outer to one join I_StatusObjectStatusBasic as ReleasedOperation           on  ReleasedOperation.StatusObject     = afvg.ObjectInternalID
                                                                                    and ReleasedOperation.StatusCode       = 'I0002'
                                                                                    and ReleasedOperation.StatusIsInactive = ''
    left outer to one join I_StatusObjectStatusBasic as PartiallyConfirmedOperation on  PartiallyConfirmedOperation.StatusObject     = afvg.ObjectInternalID
                                                                                    and PartiallyConfirmedOperation.StatusCode       = 'I0010'
                                                                                    and PartiallyConfirmedOperation.StatusIsInactive = ''
    left outer to one join I_StatusObjectStatusBasic as FinallyConfirmedOperation   on  FinallyConfirmedOperation.StatusObject     = afvg.ObjectInternalID
                                                                                    and FinallyConfirmedOperation.StatusCode       = 'I0009'
                                                                                    and FinallyConfirmedOperation.StatusIsInactive = ''
    left outer to one join I_StatusObjectStatusBasic as ClosedOperation             on  ClosedOperation.StatusObject     = afvg.ObjectInternalID
                                                                                    and ClosedOperation.StatusCode       = 'I0046'
                                                                                    and ClosedOperation.StatusIsInactive = ''

  association [1..1] to I_OrderInternalID as _OrdInternalBillOfOperations on  $projection.OrderInternalBillOfOperations = _OrdInternalBillOfOperations.OrderInternalID
  association [1..1] to I_Plant           as _ProductionPlant             on  $projection.ProductionPlant = _ProductionPlant.Plant
  association [0..1] to I_WorkCenter      as _WorkCenter                  on  $projection.WorkCenterTypeCode   = _WorkCenter.WorkCenterTypeCode
                                                                          and $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
  association [0..1] to I_WorkCenterType  as _WorkCenterType              on  $projection.WorkCenterTypeCode = _WorkCenterType.WorkCenterTypeCode
{
      @ObjectModel.foreignKey.association: '_OrdInternalBillOfOperations'
  key cast(afvg.OrderInternalID          as pph_aufpl           preserving type) as OrderInternalBillOfOperations,
  key cast(afvg.OrderOperationInternalID as operationinternalid preserving type) as OrderIntBillOfOperationsItem,
      aufv.ManufacturingOrderCategory                                            as ManufacturingOrderCategory,
      aufv.ManufacturingOrderType                                                as ManufacturingOrderType,
      aufv.Reservation                                                           as Reservation,
      @ObjectModel.foreignKey.association: '_ProductionPlant'
      cast(afvg.Plant as pwwrk preserving type)                                  as ProductionPlant,
      @ObjectModel.foreignKey.association: '_WorkCenter'
      cast(afvg.WorkCenterInternalID as pph_arbid preserving type)               as WorkCenterInternalID,
      @ObjectModel.foreignKey.association: '_WorkCenterType'
      afvg.WorkCenterTypeCode_2                                                  as WorkCenterTypeCode,


      _OrdInternalBillOfOperations,
      _ProductionPlant,
      _WorkCenter,
      _WorkCenterType
}
where
      afvg.OperationIsToBeDeleted            = '' //Non-deleted operations only

  and aufv.MfgOrderIsToBeDeleted             = '' //from non-deleted orders only

  and aufv.ManufacturingOrderCategory        = '10'
  and DeletedOperation.StatusCode            is null
  and ReleasedOperation.StatusCode           = 'I0002'
  and ClosedOperation.StatusCode             is null
  and PartiallyConfirmedOperation.StatusCode is null
  and FinallyConfirmedOperation.StatusCode   is null

Learn More