I_ORDEROPERATION

@AbapCatalog.sqlViewName: 'IORDEROPERATION'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.representativeKey: 'OrderOperationInternalID'
@ObjectModel.semanticKey: ['OrderInternalID', 'OrderOperationInternalID']
@ObjectModel.usageType: {serviceQuality: #B, sizeCategory: #XL, dataClass: #TRANSACTIONAL}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Order Operation'
// basic view for order operations of any category (AUFTYP)


/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_OrderOperation
  as select from P_AFVG as afvg
  association [1..1] to I_OrderInternalID        as _OrderInternalID   on  $projection.OrderInternalID = _OrderInternalID.OrderInternalID
  association [1..1] to I_UnitOfMeasure          as _OperationUnit     on  $projection.OperationUnit = _OperationUnit.UnitOfMeasure
  association [0..1] to I_Currency               as _OperationCurrency on  $projection.Currency = _OperationCurrency.Currency
-- for ESH  
  association [0..1] to I_WorkCenterType         as _WorkCenterType    on  $projection.WorkCenterTypeCode_2 = _WorkCenterType.WorkCenterTypeCode
  association [0..1] to I_WorkCenter             as _WorkCenter        on  $projection.WorkCenterTypeCode_2 = _WorkCenter.WorkCenterTypeCode
                                                                       and $projection.WorkCenterInternalID = _WorkCenter.WorkCenterInternalID
  association [0..1] to I_OrderOperationLongText as _LongText          on  $projection.OrderInternalID          = _LongText.OrderInternalID
                                                                       and $projection.OrderOperationInternalID = _LongText.OrderOperationInternalID
{
      // Key

      @ObjectModel.foreignKey.association: '_OrderInternalID'
  key afvg.aufpl as OrderInternalID,
  key afvg.aplzl as OrderOperationInternalID,

      // Semantic key

      afvg.aplfl as Sequence,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'Operation_2'
      afvg.vornr as Operation,                                      // with conv. exit NUMCV

      cast(afvg.vornr as vdm_vornr preserving type) as Operation_2, // without conversion exit


      // BOO data

      afvg.plnfl as BillOfOperationsSequence,
      afvg.plnty as BillOfOperationsType,
      afvg.plnnr as BillOfOperationsGroup,
      afvg.plnal as BillOfOperationsVariant,
      afvg.plnkn as BOOOperationInternalID,
      afvg.tl_versn as BillOfOperationsVersion,

      // BOM data

      afvg.istty as BillOfMaterialCategory,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'BillOfMaterialInternalID_2'
      afvg.istnr as BillOfMaterialInternalID,                                      // with conv. exit NUMCV

      cast(afvg.istnr as pph_stnum preserving type) as BillOfMaterialInternalID_2, // with conv. exit ALPHA

      afvg.istkn as BillOfMaterialItemNodeNumber,
      afvg.istpo as BOMItemNodeCount,

      // Assignments

      afvg.sumnr as SuperiorOperationInternalID,
      afvg.steus as OperationControlProfile,
      afvg.arbid as WorkCenterInternalID,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: 'WorkCenterTypeCode_2'
      afvg.arbty as WorkCenterTypeCode,    // CHAR1 field

      afvg.arbty2 as WorkCenterTypeCode_2, // CHAR2 field

      afvg.werks as Plant,
      afvg.kalid as FactoryCalendar,
      afvg.bedid as CapacityRequirement,
      afvg.bedzl as CapacityRequirementItem,
      afvg.spanz as ActualNumberOfSplits,
      afvg.anzzl as NumberOfCapacities,
      afvg.loekz as OperationIsToBeDeleted,
      afvg.pprio as NetworkActivityPriority,
      afvg.nprio as OperationImportance,
      afvg.prznt as OperationWorkPercent,
      afvg.mlstn as UsageCode,
      afvg.istru as Assembly, 
      cast(afvg.projn as ps_s4_proj_pspnr preserving type) as ProjectInternalID,
      afvg.objnr as ObjectInternalID,
      afvg.rueck as OperationConfirmation,
      afvg.rmzhl as NumberOfOperationConfirmations,
      afvg.aufkt as NumberOfOperationExecutions,
      afvg.anlzu as OperationSystemCondition,
      afvg.aennr as ChangeNumber,
      afvg.pernr as OperationPersonResponsible,
      afvg.equnr as Equipment,
      cast(afvg.tplnr as vdm_eam_tplnr preserving type)    as FunctionalLocation,

      // Text

      afvg.ktsch as StandardTextInternalID,
      @Semantics.text: true
      afvg.ltxa1 as OperationText,
      afvg.txtsp as Language,
     
      // HR data

      afvg.loanz as NumberOfTimeTickets,
      afvg.loart as EmployeeWageType,
      afvg.logrp as EmployeeWageGroup,
      afvg.rsanz as NumberOfConfirmationSlips,
      afvg.qualf as EmployeeSuitability,
      afvg.pernr as Personnel,
      afvg.anzma as NumberOfEmployees,
      
      // Setup and Overlapping

      afvg.rfgrp as OperationSetupGroupCategory,
      afvg.rfsch as OperationSetupGroup, 
      afvg.rasch as OperationSetupType,
      afvg.aufak as OperationScrapPercent,
      afvg.uemus as OperationOverlappingIsRequired,
      afvg.uekan as OperationOverlappingIsPossible,
      afvg.flies as OperationsIsAlwaysOverlapping,
      afvg.spmus as OperationSplitIsRequired,
      afvg.splim as MaximumNumberOfSplits,
      afvg.zeimb as MinProcessingDurnPerSplitUnit,
      @Semantics.quantity.unitOfMeasure: 'MinProcessingDurnPerSplitUnit'
      afvg.zminb as MinProcessingDurationPerSplit,
      afvg.rstra as LeadTimeReductionStrategy,
      afvg.zschl as OverheadCode,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      afvg.minwe as OverlapMinimumTransferQty,
      
      // Subcontracting/Purchasing

      afvg.sortl as OperationPurgInfoRecdSearchTxt,
      @Semantics.booleanIndicator
      afvg.frdlb as ExtProcgOperationHasSubcontrg,
      afvg.lifnr as Supplier,
      @Semantics.currencyCode: true
      afvg.waers as Currency,
      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'Currency'
      afvg.preis as OpExternalProcessingPrice,
      @Consumption.hidden:true
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      afvg.peinh as OpExternalProcessingPriceUnit,
      cast(afvg.peinh as pph_peinh preserving type) as NumberOfOperationPriceUnits,
      afvg.kzfix as PurgInfoRecdDataIsFixed,
      afvg.infnr as PurchasingInfoRecord,
      afvg.esokz as PurchasingInfoRecordCategory,
      afvg.ekorg as PurchasingOrganization,
      afvg.ekgrp as PurchasingGroup,
      afvg.banfn as PurchaseRequisition,
      afvg.bnfpo as PurchaseRequisitionItem,
      afvg.ebeln as PurchasingDocument,
      afvg.ebelp as PurchasingDocumentItem,
      afvg.sortl as PurgInfoRecNonStockItmSortTerm,
      afvg.matkl as MaterialGroup,
      afvg.wempf as GoodsRecipientName,
      afvg.ablad as UnloadingPointName,

      // FI/CO Data

      afvg.bukrs as CompanyCode,
      afvg.gsber as BusinessArea,
      afvg.prctr as ProfitCenter,
      afvg.sakto as CostElement,
      afvg.klvar as CostingVariant,
      afvg.kalnr as CostEstimate,
      afvg.kalsm as CostingSheet,
      afvg.anfko as RequestingCostCenter,
      afvg.indet as OperationCalculationControl,
      afvg.selkz as OperationCostingRelevancyType,
      @Aggregation.default: #SUM
      @Semantics.amount.currencyCode: 'Currency'
      afvg.prkst as NetworkActivityCost,         -- PS
      afvg.netzkont as NtwkAccountAssignmentCode,-- PS
      afvg.clasf as ActyIsTakenAcctForProjSmmry, -- PS
      afvg.owaer as ControllingObjectCurrency,
      afvg.scope as ControllingObjectClass,
      afvg.txjcd as TaxJurisdiction,
      afvg.func_area as FunctionalArea,

      // Business Process

      afvg.prz01 as BusinessProcess,
      @Semantics.unitOfMeasure: true
      afvg.ipre1 as BusinessProcessEntryUnit,
      @Semantics.quantity.unitOfMeasure: 'BusinessProcessEntryUnit'
      @Aggregation.default: #SUM
      afvg.iprz1 as BusinessProcessConfirmedQty,
      afvg.iprk1 as NoFurtherBusinessProcQtyIsExpd,
      @Semantics.unitOfMeasure: true
      afvg.opre1 as BusinessProcRemainingQtyUnit,
      @Semantics.quantity.unitOfMeasure: 'BusinessProcRemainingQtyUnit'
      @Aggregation.default: #SUM
      afvg.oprz1 as BusinessProcessRemainingQty,

      // Work Quantities and Activitiy Types

      afvg.vgwts as StandardWorkFormulaParamGroup,

      afvg.lar01 as CostCtrActivityType1,
      afvg.lar02 as CostCtrActivityType2,
      afvg.lar03 as CostCtrActivityType3,
      afvg.lar04 as CostCtrActivityType4,
      afvg.lar05 as CostCtrActivityType5,
      afvg.lar06 as CostCtrActivityType6,
      afvg.larnt as CostCtrActivityType,         --for PM and PS

      afvg.lek01 as NoFurtherOpWorkQuantity1IsExpd,
      afvg.lek02 as NoFurtherOpWorkQuantity2IsExpd,
      afvg.lek03 as NoFurtherOpWorkQuantity3IsExpd,
      afvg.lek04 as NoFurtherOpWorkQuantity4IsExpd,
      afvg.lek05 as NoFurtherOpWorkQuantity5IsExpd,
      afvg.lek06 as NoFurtherOpWorkQuantity6IsExpd,
      afvg.leknw as NoFurtherWorkQuantityIsExpd, --PM and PS

      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit1'
      @Aggregation.default: #SUM
      afvg.vgw01 as WorkCenterStandardWorkQty1,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit2'
      @Aggregation.default: #SUM
      afvg.vgw02 as WorkCenterStandardWorkQty2,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit3'
      @Aggregation.default: #SUM
      afvg.vgw03 as WorkCenterStandardWorkQty3,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit4'
      @Aggregation.default: #SUM
      afvg.vgw04 as WorkCenterStandardWorkQty4,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit5'
      @Aggregation.default: #SUM
      afvg.vgw05 as WorkCenterStandardWorkQty5,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit6'
      @Aggregation.default: #SUM
      afvg.vgw06 as WorkCenterStandardWorkQty6,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit'
      @Aggregation.default: #SUM
      afvg.arbei as OpPlannedWorkQuantity,       --PM and PS

      @Semantics.unitOfMeasure: true
      afvg.vge01 as WorkCenterStandardWorkQtyUnit1,
      @Semantics.unitOfMeasure: true
      afvg.vge02 as WorkCenterStandardWorkQtyUnit2,
      @Semantics.unitOfMeasure: true
      afvg.vge03 as WorkCenterStandardWorkQtyUnit3,
      @Semantics.unitOfMeasure: true
      afvg.vge04 as WorkCenterStandardWorkQtyUnit4,
      @Semantics.unitOfMeasure: true
      afvg.vge05 as WorkCenterStandardWorkQtyUnit5,
      @Semantics.unitOfMeasure: true
      afvg.vge06 as WorkCenterStandardWorkQtyUnit6,

      @Semantics.unitOfMeasure: true
      afvg.ile01 as OpWorkQuantityUnit1,
      @Semantics.unitOfMeasure: true
      afvg.ile02 as OpWorkQuantityUnit2,
      @Semantics.unitOfMeasure: true
      afvg.ile03 as OpWorkQuantityUnit3,
      @Semantics.unitOfMeasure: true
      afvg.ile04 as OpWorkQuantityUnit4,
      @Semantics.unitOfMeasure: true
      afvg.ile05 as OpWorkQuantityUnit5,
      @Semantics.unitOfMeasure: true
      afvg.ile06 as OpWorkQuantityUnit6,
      @Semantics.unitOfMeasure: true
      afvg.arbeh as OpWorkQuantityUnit,          --PM and PS

      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit1'
      @Aggregation.default: #SUM
      afvg.ism01 as OpConfirmedWorkQuantity1,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit2'
      @Aggregation.default: #SUM
      afvg.ism02 as OpConfirmedWorkQuantity2,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit3'
      @Aggregation.default: #SUM
      afvg.ism03 as OpConfirmedWorkQuantity3,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit4'
      @Aggregation.default: #SUM
      afvg.ism04 as OpConfirmedWorkQuantity4,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit5'
      @Aggregation.default: #SUM
      afvg.ism05 as OpConfirmedWorkQuantity5,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit6'
      @Aggregation.default: #SUM
      afvg.ism06 as OpConfirmedWorkQuantity6,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit'
      @Aggregation.default: #SUM
      afvg.ismnw as ActualWorkQuantity,          --PM and PS

      // Forecast

      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit1'
      @Aggregation.default: #SUM
      afvg.ofm01 as ForecastWorkQuantity1,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit2'      
      @Aggregation.default: #SUM
      afvg.ofm02 as ForecastWorkQuantity2,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit3'
      @Aggregation.default: #SUM
      afvg.ofm03 as ForecastWorkQuantity3,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit4'
      @Aggregation.default: #SUM
      afvg.ofm04 as ForecastWorkQuantity4,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit5'
      @Aggregation.default: #SUM
      afvg.ofm05 as ForecastWorkQuantity5,
      @Semantics.quantity.unitOfMeasure: 'WorkCenterStandardWorkQtyUnit6'
      @Aggregation.default: #SUM
      afvg.ofm06 as ForecastWorkQuantity6,
      @Semantics.quantity.unitOfMeasure: 'OpWorkQuantityUnit'
      @Aggregation.default: #SUM
      afvg.ofmnw as ForecastWorkQuantity,        --PM and PS

      // Determination of Standard Values

      afvg.zerma as StandardWorkQtyDetnType,
      afvg.zgdat as StandardWorkQtyDetnYear,
      afvg.zcode as StandardWorkQuantityReference,
      afvg.zulnr as StandardWorkQuantityCalcBasis,

      // PP-PI data

      afvg.pvzkn as OrderIntBillOfOpItemOfPhase,
      afvg.phflg as MfgOrderOperationIsPhase,
      afvg.phseq as ControlRecipeDestination,

      afvg.knobj as DependencyObjectNumber,
      afvg.objektid as LineHierarchyInternalID,
      afvg.rstuf as OpSchedldReductionLevel,
      afvg.subsys as InspectionSubSystem,
      afvg.packno as ServicePackage,
      afvg.no_disp as MaterialPlanningRelevance,
      afvg.cuobj_arb as ProductConfiguration,
      afvg.evgew as ProgressAnlysAggregationWeight,
      afvg.afnam as OperationRequisitionerName,
      afvg.bednr as OperationTrackingNumber,
      afvg.qpart as InspectionLotType,
      afvg.wkurs as ExchangeRate,
      afvg.fplnr as BillingPlan,
      afvg.rfpnt as ReferencePoint,
 
      // Operation Unit

      @Semantics.unitOfMeasure: true
      afvg.meinh as OperationUnit,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @Aggregation.default: #MAX
      afvg.bmsch as OperationReferenceQuantity,
      afvg.umren as OpQtyToBaseQtyDnmntr,
      afvg.umrez as OpQtyToBaseQtyNmrtr,
      
      // Quantities

      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @Aggregation.default: #SUM
      afvg.mgvrg as OpPlannedTotalQuantity,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @Aggregation.default: #SUM
      afvg.asvrg as OpPlannedScrapQuantity,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @Aggregation.default: #SUM
      afvg.lmnga as OpTotalConfirmedYieldQty,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @Aggregation.default: #SUM
      afvg.xmnga as OpTotalConfirmedScrapQty,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @Aggregation.default: #SUM
      afvg.rmnga as OperationConfirmedReworkQty,
      @Semantics.quantity.unitOfMeasure: 'OperationUnit'
      @Aggregation.default: #SUM
      afvg.gmnga as OpTotConfdYieldQtyInOrdQtyUnit,

      // Durations

      @Semantics.unitOfMeasure: true
      afvg.zeier as BreakDurationUnit,
      afvg.zmerh as PlannedBreakDuration,
      afvg.iserh as ConfirmedBreakDuration,
      @Semantics.unitOfMeasure: true
      afvg.zeimu as OverlapMinimumDurationUnit,
      afvg.zminu as OverlapMinimumDuration,
      @Semantics.unitOfMeasure: true
      afvg.zeilm as MaximumWaitDurationUnit,
      afvg.zlmax as MaximumWaitDuration,
      @Semantics.unitOfMeasure: true
      afvg.zeilp as MinimumWaitDurationUnit,
      afvg.zlpro as MinimumWaitDuration,
      @Semantics.unitOfMeasure: true
      afvg.zeitn as StandardMoveDurationUnit,
      afvg.ztnor as StandardMoveDuration,
      @Semantics.unitOfMeasure: true
      afvg.zeiwn as StandardQueueDurationUnit,
      afvg.zwnor as StandardQueueDuration,
      @Semantics.unitOfMeasure: true
      afvg.zeiwm as MinimumQueueDurationUnit,
      afvg.zwmin as MinimumQueueDuration,
      @Semantics.unitOfMeasure: true
      afvg.zeitm as MinimumMoveDurationUnit,
      afvg.ztmin as MinimumMoveDuration,
      afvg.dauno as OperationStandardDuration,
      @Semantics.unitOfMeasure: true
      afvg.daune as OperationStandardDurationUnit,
      afvg.daumi as MinimumDuration,
      @Semantics.unitOfMeasure: true
      afvg.daume as MinimumDurationUnit,
      afvg.zminb as MinimumProcessingDuration,
      @Semantics.unitOfMeasure: true
      afvg.zeimb as MinimumProcessingDurationUnit,
      afvg.tranz as ScheduledMoveDuration,
      @Semantics.unitOfMeasure: true
      afvg.traze as ScheduledMoveDurationUnit,
      afvg.wartz as ScheduledQueueDuration,
      @Semantics.unitOfMeasure: true
      afvg.wrtze as ScheduledQueueDurationUnit,
      afvg.liegz as ScheduledWaitDuration,
      @Semantics.unitOfMeasure: true
      afvg.ligze as ScheduledWaitDurationUnit,
      afvg.plifz as PlannedDeliveryDuration,
      afvg.ruest as OpPlannedSetupDurn,
      @Semantics.unitOfMeasure: true
      afvg.rstze as OpPlannedSetupDurnUnit,
      afvg.bearz as OpPlannedProcessingDurn,
      @Semantics.unitOfMeasure: true
      afvg.beaze as OpPlannedProcessingDurnUnit,
      afvg.abrue as OpPlannedTeardownDurn,
      @Semantics.unitOfMeasure: true
      afvg.aruze as OpPlannedTeardownDurnUnit,
      afvg.einsa as ActyBscStartDateConstraintType,
      afvg.einse as ActyBscEndDateConstraintType,
      afvg.ewste as ActyFcstEndDateConstraintType, 
      afvg.ewsta as ActyFcstStartDteConstraintType,
      afvg.pdau  as ActualForecastDuration,
      @Semantics.unitOfMeasure: true
      afvg.pdae  as ActualForecastDurationUnit,
      afvg.ewdan as ForecastedStandardDuration,
      @Semantics.unitOfMeasure: true
      afvg.ewdne as FcstdStandardDurationUnit,
      afvg.ewdam as ForecastedMinimumDuration,
      @Semantics.unitOfMeasure: true
      afvg.ewdme as ForecastedMinimumDurationUnit,

      // Dates and Times

      afvg.fsavd as OpErlstSchedldExecStrtDte,
      afvg.fsavz as OpErlstSchedldExecStrtTme,
      afvg.fssbd as OpErlstSchedldProcgStrtDte,
      afvg.fssbz as OpErlstSchedldProcgStrtTme,
      afvg.fssad as OpErlstSchedldTrdwnStrtDte,
      afvg.fssaz as OpErlstSchedldTrdwnStrtTme,
      afvg.fsedd as OpErlstSchedldExecEndDte,
      afvg.fsedz as OpErlstSchedldExecEndTme,
      afvg.fssld as EarliestScheduledWaitStartDate,
      afvg.fsslz as EarliestScheduledWaitStartTime,
      afvg.fseld as EarliestScheduledWaitEndDate,
      afvg.fselz as EarliestScheduledWaitEndTime,
      afvg.ssavd as OpLtstSchedldExecStrtDte,
      afvg.ssavz as OpLtstSchedldExecStrtTme,
      afvg.sssbd as OpLtstSchedldProcgStrtDte,
      afvg.sssbz as OpLtstSchedldProcgStrtTme,
      afvg.sssad as OpLtstSchedldTrdwnStrtDte,
      afvg.sssaz as OpLtstSchedldTrdwnStrtTme,
      afvg.ssedd as OpLtstSchedldExecEndDte,
      afvg.ssedz as OpLtstSchedldExecEndTme,
      afvg.sssld as LatestScheduledWaitStartDate,
      afvg.ssslz as LatestScheduledWaitStartTime,
      afvg.sseld as LatestScheduledWaitEndDate,
      afvg.sselz as LatestScheduledWaitEndTime,
      afvg.isavd as OperationConfirmedStartDate,
      afvg.ieavd as OperationConfirmedEndDate,
      afvg.isdd  as OpActualExecutionStartDate,
      afvg.isdz  as OpActualExecutionStartTime,
      afvg.ierd  as OpActualSetupEndDate,
      afvg.ierz  as OpActualSetupEndTime,
      afvg.isbd  as OpActualProcessingStartDate,
      afvg.isbz  as OpActualProcessingStartTime,
      afvg.iebd  as OpActualProcessingEndDate,
      afvg.iebz  as OpActualProcessingEndTime,
      afvg.isad  as OpActualTeardownStartDate,
      afvg.isaz  as OpActualTeardownStartTme,
      afvg.iedd  as OpActualExecutionEndDate,
      afvg.iedz  as OpActualExecutionEndTime,
      afvg.pedd  as ActualForecastEndDate,
      afvg.pedz  as ActualForecastEndTime,
      afvg.fpavd as SchedldFcstdEarliestStartDate,
      afvg.fpavz as SchedldFcstdEarliestStartTime,
      afvg.fpedd as SchedldFcstdEarliestEndDate,
      afvg.fpedz as SchedldFcstdEarliestEndTime,
      afvg.spavd as LatestSchedldFcstdStartDate,
      afvg.spavz as SchedldFcstdLatestStartTime,
      afvg.spedd as LatestSchedldFcstdEndDate,
      afvg.spedz as SchedldFcstdLatestEndTime,
      afvg.ntanf as ConstraintDateForBscStartDate,
      afvg.ntanz as ConstraintTimeForBscStartTime,
      afvg.ewstd as ForecastedStartDate,
      afvg.ewstz as ForecastedStartTime,
      afvg.ewend as ForecastedEndDate,
      afvg.ewenz as ForecastedEndTime,
      @Semantics.unitOfMeasure: true
      afvg.beazp as ForecastProcessingDurationUnit,
      afvg.bearp as ForecastProcessingDuration,
      afvg.epanf as OpDispatchedExecStartDate,
      afvg.epanz as OpDispatchedExecStartTime,
      afvg.epend as OpDispatchedExecEndDate,
      afvg.epenz as OpDispatchedExecEndTime,

      // Floats

      afvg.puffr as BasicDatesFreeFloat,
      afvg.pufgs as TotalFloatForBasicDates,
      afvg.pufgp as TotalFloatForForecastedDates,
      afvg.puffp as ForecastedDatesFreeFloat,

      // Offset

      afvg.bzoffb as StartDateOffsetReferenceCode,
      @Semantics.unitOfMeasure: true
      afvg.ehoffb as StartDateOffsetDurationUnit,
      afvg.offstb as StartDateOffsetDuration,
      afvg.bzoffe as EndDateOffsetReferenceCode,
      afvg.offste as EndDateOffsetDuration,
      @Semantics.unitOfMeasure: true
      afvg.ehoffe as EndDateOffsetDurationUnit,

      // Free-defined fields

      afvg.slwid as FreeDefinedTableFieldSemantic,
      afvg.usr00 as FreeDefinedAttribute01,
      afvg.usr01 as FreeDefinedAttribute02,
      afvg.usr02 as FreeDefinedAttribute03,
      afvg.usr03 as FreeDefinedAttribute04,
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity1Unit'
      @Aggregation.default: #SUM
      afvg.usr04 as FreeDefinedQuantity1,
      @Semantics.unitOfMeasure: true
      afvg.use04 as FreeDefinedQuantity1Unit,
      @Semantics.quantity.unitOfMeasure: 'FreeDefinedQuantity2Unit'
      @Aggregation.default: #SUM
      afvg.usr05 as FreeDefinedQuantity2,
      @Semantics.unitOfMeasure: true
      afvg.use05 as FreeDefinedQuantity2Unit,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount1Currency'
      @Aggregation.default: #SUM
      afvg.usr06 as FreeDefinedAmount1,
      @Semantics.currencyCode: true
      afvg.use06 as FreeDefinedAmount1Currency,
      @Semantics.amount.currencyCode: 'FreeDefinedAmount2Currency'
      @Aggregation.default: #SUM
      afvg.usr07 as FreeDefinedAmount2,
      @Semantics.currencyCode: true
      afvg.use07 as FreeDefinedAmount2Currency,
      afvg.usr08 as FreeDefinedDate1,
      afvg.usr09 as FreeDefinedDate2,
      afvg.usr10 as FreeDefinedIndicator1,
      afvg.usr11 as FreeDefinedIndicator2,

      // EAM

      cast(afvg.maintopexecutionphasecode as eam_premainpost_cds preserving type) as MaintOperationExecStageCode,
      afvg.maintordopprocessphasecode                                             as MaintOrdOpProcessPhaseCode,
      afvg.maintordopprocesssubphasecode                                          as MaintOrdOpProcessSubPhaseCode,   

      // OAN data

      afvg.oan_inst_id_setup    as SetupOpActyNtwkInstance,
      afvg.oan_inst_id_produce  as ProduceOpActyNtwkInstance,
      afvg.oan_inst_id_teardown as TeardownOpActyNtwkInstance,

      // Associations

      _OrderInternalID,
      _OperationUnit,
      _OperationCurrency,
      _WorkCenterType,
      _WorkCenter,
      _LongText
};