C_MatlBsdCmpstnAfterProdCompVH

@EndUserText.label: 'After Production Components of MbC'

@AbapCatalog:
{
  sqlViewName: 'MBCAFTPRCOMPVH',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  // blocking of personal data not required (no personal data fields exposed for material)

  personalData.blocking: #NOT_REQUIRED
}

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  dataCategory: #VALUE_HELP,

  usageType:
  {
    dataClass: #MIXED,
    sizeCategory: #L,
    serviceQuality: #C
  },
  representativeKey: 'MatlBsdCompUUID',
  semanticKey: ['ChmlCmplncInfoCombinedName']
}

@Metadata.ignorePropagatedAnnotations: true

@ClientHandling.algorithm: #SESSION_VARIABLE

@UI:{
  presentationVariant: [{
    sortOrder: [{ by: 'ChmlCmplncInfoCombinedName', direction: #ASC }],
     requestAtLeast: ['ChmlCompositionUUID',
                      'ChmlCmplncInfoCombinedName',
                      'Material',
                      'ChmlCompQtyAsText',
                      'ChmlCompOperatorLowerLimit',
                      'ChmlCompQtyLowerLimitAsText',
                      'ChmlCompOperatorUpperLimit',
                      'ChmlCompQtyUpperLimitAsText',
                      'ChmlCompQtyUnit',
                      'ChmlCompSubstancesTxt'
                    ]
  }]
}

@Search.searchable: true

/*
 * This view is used in the object page of the material based composition
 * to diplay all CCIs with type = 'Bulk' and role 'Produced' or 'Sourced'
 * in a value help
 */

define view C_MatlBsdCmpstnAfterProdCompVH
  with parameters
    P_ChmlCompositionUUID : sysuuid_x
  -- select Raw Material
  as select from I_MatlBsdBeforeProdnCompDraft as MatlBsdBeforeProdnComp

  association [0..1] to C_ChmlCmplncPrimMatl as _PrimaryMaterial on $projection.CompChmlCmplncInfoUUID = _PrimaryMaterial.ChmlCmplncInfoUUID

{

  key MatlBsdBeforeProdnComp.MatlBsdCompUUID,
      MatlBsdBeforeProdnComp.ActiveMatlBsdCompUUID,
      $parameters.P_ChmlCompositionUUID                                                              as ChmlCompositionUUID,
      MatlBsdBeforeProdnComp.ChmlCmplncInfoUUID,
      MatlBsdBeforeProdnComp.CompChmlCmplncInfoUUID,
      -- Preferred Material of Component
      @ObjectModel.readOnly: true
      @ObjectModel.text.element: ['ChmlCmplncInfoCombinedName']
      @Semantics.text:true
      cast( _PrimaryMaterial.Material as matnr preserving type)                                      as Material,

      -- Combined component name
      @ObjectModel.readOnly: true
      @Semantics.text: true
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold:   0.8,
        ranking: #HIGH
      }
      cast(_PrimaryMaterial.ChmlCmplncInfoCombinedName as ehfnd_cci_component_name preserving type ) as ChmlCmplncInfoCombinedName,

      MatlBsdBeforeProdnComp.MatlBsdCompProductionType,

      @Semantics.quantity.unitOfMeasure: 'ChmlCompQtyUnit'
      MatlBsdBeforeProdnComp.ChmlCompQty,
      MatlBsdBeforeProdnComp.ChmlCompQtyAsText,
      MatlBsdBeforeProdnComp.ChmlCompQtyUnit,
      MatlBsdBeforeProdnComp.ChmlCompOperatorLowerLimit,
      @Semantics.quantity.unitOfMeasure: 'ChmlCompQtyUnit'
      MatlBsdBeforeProdnComp.ChmlCompQtyLowerLimit,
      MatlBsdBeforeProdnComp.ChmlCompQtyLowerLimitAsText,
      MatlBsdBeforeProdnComp.ChmlCompOperatorUpperLimit,
      @Semantics.quantity.unitOfMeasure: 'ChmlCompQtyUnit'
      MatlBsdBeforeProdnComp.ChmlCompQtyUpperLimit,
      MatlBsdBeforeProdnComp.ChmlCompQtyUpperLimitAsText,
      MatlBsdBeforeProdnComp.ChmlCompIsRemoved,

      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_MCMPS_APC_SUB_EXIT'
      cast( 0 as ehfnd_text1333 )                                                                    as ChmlCompSubstancesTxt,

      /* Associations */
      MatlBsdBeforeProdnComp._ChmlCmplncInfo,
      _PrimaryMaterial
}
where
      MatlBsdBeforeProdnComp.ChmlCompositionUUID = $parameters.P_ChmlCompositionUUID
  and MatlBsdBeforeProdnComp.ChmlCompIsRemoved   <> 'X'