C_MasterDataChangeProcess

@EndUserText.label: 'Master Data Change Process'
@VDM.viewType: #CONSUMPTION
@ObjectModel: {
    compositionRoot: true,
    transactionalProcessingDelegated:true,
    createEnabled:true,
    updateEnabled:true,
    deleteEnabled:false,
    draftEnabled:false,
    usageType.serviceQuality: #C,
    usageType.sizeCategory : #L,
    usageType.dataClass: #MIXED,
    alternativeKey: [{
        id : 'MASTERDATACHANGEPROCESS',
        uniqueness : #UNIQUE_IF_NOT_INITIAL,
        element : ['MASTERDATACHANGEPROCESS']
    }]
//    entityChangeStateId: 'MDChgProcessUpdateToken'

}
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations:  [
  '_ProcessRequestorContactCard'
]
@Search.searchable: true
@Metadata.allowExtensions: true
@ObjectModel.semanticKey: ['MasterDataChangeProcess']
@ObjectModel.delegatedAction: [
  { name: 'CHECK_AND_CREATE_MASS_PROCESS', exposureName: 'CheckAndCreateMassProcess' },
  { name: 'CHECK_SELECTION', exposureName: 'CheckProcessSelection' },
  { name: 'CONTINUE_PROCESS', exposureName: 'ContinueProcess' },
  { name: 'FINISH_STEP', exposureName: 'CompleteProcessStep' },
  { name: 'GET_AUDIT_TRAIL', exposureName: 'GetProcessAuditTrail' },
  { name: 'GET_AUDIT_TRAIL_USERS', exposureName: 'GetProcessAuditTrailUsers' },
  { name: 'GET_GRADES', exposureName: 'GetProcessGrades' },
//  { name: 'GET_FREE_SOURCES', exposureName: 'GetFreeProcessSources' },

  { name: 'REPLENISH_WORKLIST_QUERIES', exposureName: 'ReplenishWorklistQueries' },
  { name: 'REMOVE_RECORDS', exposureName: 'RemoveProcessRecords' },
  { name: 'RETRY_STEP', exposureName: 'RetryProcessStep' },
  { name: 'REVALIDATE_AND_CONTINUE', exposureName: 'RecheckAndContinueProcess' },
  { name: 'ROLLBACK_PROCESS', exposureName: 'RollbackProcess' },
  { name: 'SPLIT_RECORDS', exposureName: 'SplitProcessRecords' },
  { name: 'START_PROCESS_WITHOUT_SCOPE', exposureName: 'TriggerProcessWithoutScope' },
  { name: 'STOP_PROCESS', exposureName: 'CancelProcess' },
  { name: 'TERMINATE_PROCESS', exposureName: 'TerminateProcess' },
  { name: 'TOUCH', exposureName: 'TriggerProcessDeterminations' },
  { name: 'MANUAL_START_STEP_WORKFLOW', exposureName: 'TriggerProcessStepWorkflow' },
  { name: 'RETRY_START_STEP_WORKFLOW', exposureName: 'RetryStartProcessStepWorkflow' },
  { name: 'ERASE_PROCESS', exposureName: 'DeleteProcess' },
  { name: 'ERASE_PROCESS_WITH_REASON', exposureName: 'DeleteProcessWithReason' },
  { name: 'HAS_PROCESS_OPEN_DRAFTS', exposureName: 'CheckProcessHasOpenDrafts' },
  { name: 'VERIFY_CLOUD_READINESS', exposureName: 'VerifyCloudReadiness' }
]
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define root view entity C_MasterDataChangeProcess
  as select from I_MasterDataChangeProcessTP as Root

  association [0..*] to C_MDChgProcessRelatedProcess   as _RelatedProcess              on  _RelatedProcess.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..*] to C_MDChangeProcessSource        as _Source                      on  _Source.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..1] to I_MDChgProcessSrceRecordsCntr  as _NumberOfSouceRecords        on  _NumberOfSouceRecords.MDChgProcessSourceUUID = $projection.MasterDataChangeProcessUUID
  association [0..*] to C_MasterDataChangeProcessStep  as _Step                        on  _Step.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..1] to P_MDChangeProcessStatusState   as _ProcessState                on  _ProcessState.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..1] to C_MDChangeProcessCriticality   as _Criticality                 on  _Criticality.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..1] to C_MDChangeProcessProgressRatio as _Ratio                       on  _Ratio.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..1] to C_MDChgProcessStepDescription  as _StepDescription             on  $projection.MasterDataChangeProcess       = _StepDescription.MasterDataChangeProcess
                                                                                       and $projection.MDChgProcessCurrentStepNumber = _StepDescription.MDChgProcessStep

  association [0..1] to I_MDChangeProcessIsIdle        as _ProcessIsIdle               on  _ProcessIsIdle.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..1] to C_MasterDataChangeProcessUser  as _ProcessUserVH               on  _ProcessUserVH.MDChgProcessRequestor          = $projection.MDChgProcessRequestor
                                                                                       and _ProcessUserVH.MasterDataChangeProcessVariant = $projection.masterdatachangeprocessvariant
  association [0..1] to I_MDChangeProcessVariant       as _ProcessVariant              on  _ProcessVariant.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..1] to I_MDCloudUserContactCard       as _ProcessRequestorContactCard on  $projection.MDChgProcessRequestor = _ProcessRequestorContactCard.ContactCardID

  association [0..1] to C_MDChangeProcessStatusStateVH as _ProcessStateVH              on  _ProcessStateVH.MDChgProcessStatusStateCode = $projection.MDChgProcessStatusStateCode
  association [0..1] to C_MDChangeProcessGoalValueHelp as _ProcessGoalVH               on  _ProcessGoalVH.MDChgProcessGoal = $projection.MDChgProcessGoal
  association [0..*] to C_MasterDataChangeProcessGoal  as _ProcessGoalText             on  _ProcessGoalText.MDChgProcessGoal = $projection.MDChgProcessGoal
  association [0..1] to C_MDChangeProcessGoalProperty  as _GoalProperty                on  _GoalProperty.MDChgProcessGoal = $projection.MDChgProcessGoal
  association [0..1] to I_MDChangeProcessTypeVH        as _ProcessTypeVH               on  _ProcessTypeVH.MDChgProcessTypeID             = $projection.MDChgProcessTypeID
                                                                                       and _ProcessTypeVH.MDChgProcessSrceObjectTypeCode = $projection.MDChgProcessSrceObjectTypeCode
                                                                                       and _ProcessTypeVH.MDChgProcessGoal               = $projection.MDChgProcessGoal
  association [0..1] to I_MDChangeProcessReasonText    as _ReasonText                  on  _ReasonText.MasterDataChangeProcessReason  = $projection.MasterDataChangeProcessReason
                                                                                       and _ReasonText.MDChgProcessSrceObjectTypeCode = $projection.MDChgProcessSrceObjectTypeCode
                                                                                       and _ReasonText.Language                       = $session.system_language
  association [0..1] to I_MDChangeProcessPriorityText  as _PriorityText                on  _PriorityText.MDChangeProcessPriority = $projection.MDChangeProcessPriority
                                                                                       and _PriorityText.Language                = $session.system_language
  association [0..*] to I_MDChgProcTypeRejectionReason as _TypeRejectionReason         on  _TypeRejectionReason.MDChgProcessTypeID = $projection.MDChgProcessTypeID
  association [0..1] to I_MDChgProcRejectionReasonT    as _RejectionReasonText         on  _RejectionReasonText.MDChangeProcessRejectionReason = $projection.MDChangeProcessRejectionReason
                                                                                       and _RejectionReasonText.Language                       = $session.system_language
  association [0..1] to I_MDChgProcessTypeText         as _ProcessTypeText             on  _ProcessTypeText.MDChgProcessTypeID = $projection.MDChgProcessTypeID
  association [0..1] to C_MDChangeProcessStrategyVH    as _ProcessStrategyVH           on  _ProcessStrategyVH.MDChgProcessDuplicateStrategy = $projection.MDChgProcessDuplicateStrategy
  association [0..1] to C_MDQualityEvaluations         as _MDQualityEvaluations        on  _MDQualityEvaluations.MasterDataChangeProcess = $projection.MasterDataChangeProcess

  association [0..1] to P_MasterDataAttchLinkCount     as _Attachments                 on  $projection.MasterDataChangeProcess         = _Attachments.MasterDataAttachmentObjectID
                                                                                       and _Attachments.MasterDataAttachmentObjectType = 'C_MASTERDATACHANGEPROCESS'
  association [0..1] to P_MasterDataNoteItemCount      as _NoteItem                    on  $projection.MasterDataChangeProcess = _NoteItem.MasterDataNoteObjectIdentifier
                                                                                       and _NoteItem.MasterDataNoteObjectType  = 'C_MASTERDATACHANGEPROCESS'
  association [0..1] to P_MDChgProcTypeRjcnReasonCount as _RejectionReason             on  _RejectionReason.MDChgProcessTypeID = $projection.MDChgProcessTypeID
{
  key Root.MasterDataChangeProcessUUID,
      @EndUserText.label: 'Process'
      @ObjectModel.text.element: ['MDChgProcessDescription']
      @ObjectModel.readOnly: true
      Root.MasterDataChangeProcess                                                                 as MasterDataChangeProcess,
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      @UI.hidden: true
      cast( Root.MasterDataChangeProcess as mdc_process_id_alpha_out )                             as MDChangeProcessNumberDisplay,
      @Semantics.text:true
      @Search.ranking: #HIGH
      @Search.fuzzinessThreshold: 0.8
      Root.MDChgProcessDescription,
      @Consumption.valueHelpDefinition: [{ association: '_ProcessTypeVH', distinctValues: true }]
      @ObjectModel.text.association: '_ProcessTypeText'
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      Root.MDChgProcessTypeID,
      @Consumption.valueHelpDefinition: [{ association: '_ProcessGoalVH', distinctValues: true }]
      @ObjectModel.text.association: '_ProcessGoalText'
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      Root.MDChgProcessGoal,
      @Search.ranking: #LOW
      Root.MDChgProcessStatus,
      Root.MDChgProcessSrceObjectTypeCode,
      Root.MDChgProcessWorkflowTemplate,
      @Consumption.valueHelpDefinition: [{ association: '_ProcessUserVH', distinctValues: true }]
      @ObjectModel.foreignKey.association: '_ProcessRequestorContactCard'
      @Semantics.user.createdBy: true
      @EndUserText.label: 'Process Requestor'
      @Search.ranking: #MEDIUM
      Root.MDChgProcessRequestor,
      @UI.hidden: true
      @ObjectModel.readOnly: true
      _ProcessVariant.MasterDataChangeProcessVariant,
      Root.MDChgProcessCreationDate,
      Root.MDChgProcessCreationTime,
      @ObjectModel.readOnly: true
      @ObjectModel.filter.transformedBy: 'ABAP:CL_MDC_PROCESS_FLT_SORT_EXIT'
      @ObjectModel.sort.transformedBy: 'ABAP:CL_MDC_PROCESS_FLT_SORT_EXIT'
      cast( dats_tims_to_tstmp(Root.MDChgProcessCreationDate, Root.MDChgProcessCreationTime, 'UTC', $session.client, 'NULL')
        as timestamp preserving type )                                                             as MDChgProcessCreationDateTime,
      Root.MDChgProcessChangeDate,
      Root.MDChgProcessChangeTime,
      Root.MDChgProcessDelSrceDataIsRqd,
      Root.MDChgProcessFinishDate,
      Root.MDChgProcessFinishTime,
      Root.MDChgProcessUpdateToken,
      Root.MDChgProcessIsStarted,
      Root.MDChgProcessIsInitialized,
      Root.MDChgProcessIsFinalized,
      Root.MDChgProcessLastStepIsFinished,
      Root.MDChgProcessCurrentStepNumber,
      Root.MDChgProcessChkPointIsActive,
      Root.MDChgProcessCompletionIsReqd,
      Root.MDChgProcessWrkFlwDeltnIsRqd,
      Root.MDChgProcessSrceDeletionIsRqd,
      Root.MDChgProcessFilterChain,
      Root.MDChgProcessErrorsAreLogged,
      Root.MDChgProcessLastActKey,
      @EndUserText.label: 'Related Process'
      Root.MDChgProcessPredecessor,
      Root.MDChgProcessFinalDateTime,
      Root.MDChgProcessNextStpAtDateTime,
      @Semantics.text: true
      @ObjectModel.readOnly: true
      _ProcessStrategyVH._Text[1:Language=$session.system_language].MDChgProcDuplicateStrategyText as MDChgProcDuplicateStrategyText,
      @Consumption.valueHelpDefinition: [{ association: '_ProcessStrategyVH', distinctValues: true }]
      @ObjectModel.foreignKey.association: '_ProcessStrategyVH'
      @ObjectModel.text.element: ['MDChgProcDuplicateStrategyText']
      @Search.ranking: #LOW
      Root.MDChgProcessDuplicateStrategy,
      Root.MDChgProcessIsReliable,
      Root.MDChgProcessProtectionReason,
      @Consumption.filter: { selectionType : #SINGLE,
                             defaultValue : ''
      }
      @EndUserText.label: 'Deleted'
      Root.MDChgProcessIsErased,
      @ObjectModel.readOnly: true
      _Criticality.MDChgProcessStatusCriticality                                                   as MDChgProcessStatusCriticality,
      @ObjectModel.readOnly: true
      cast( '%' as msehi )                                                                         as MDChangeProcessProgressUnit,
      @ObjectModel.readOnly: true
      _Ratio.MDChgProcPrgrsRatioInPercent                                                          as MDChgProcPrgrsRatioInPercent,
      @ObjectModel.readOnly: true
      _Ratio.MDChangeProcessNumberOfSteps,
      @ObjectModel.readOnly: true
      @EndUserText.label: 'Records'
      _NumberOfSouceRecords.MDChgProcessNmbrOfSrceRecords                                          as MDChgProcessNmbrOfSrceRecords,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      _ProcessIsIdle.MDChgProcessIsIdle                                                            as MDChgProcessIsIdle,
      @ObjectModel.readOnly: true
      @Consumption.valueHelpDefinition: [{ association: '_ProcessStateVH', distinctValues: true }]
      @ObjectModel.foreignKey.association: '_ProcessStateVH'
      @ObjectModel.text.association: '_ProcessState'
      @EndUserText.label: 'Process Status'
      @EndUserText.quickInfo: 'Process Status'
      _ProcessState.MDChgProcessStatusStateCode                                                    as MDChgProcessStatusStateCode,
      @ObjectModel.readOnly: true
      @EndUserText.label: 'Process Status'
      @EndUserText.quickInfo: 'Process Status'
      @UI.hidden: true
      _ProcessState.MDChgProcessStatusStateName                                                    as MDChgProcessStatusStateName,
      @ObjectModel.readOnly: true
      @ObjectModel.filter.transformedBy: 'ABAP:CL_MDC_PROCESS_FLT_SORT_EXIT'
      @EndUserText.label: 'Data Source'
      cast( '' as abap.char( 60 ) )                                                                as MDChgProcessSrceSystem,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_CALC_EXIT'
      cast( '                              ' as mdc_table_name preserving type )                   as MDChgProcessModelRootTableName,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_CALC_EXIT'
      cast( '' as abap_boolean preserving type )                                                   as MDChgProcSelectionIsAvailable,

      @Consumption.filter: { selectionType : #SINGLE,
                             defaultValue : ''
      }
      @ObjectModel.readOnly: true
      @EndUserText.label: 'Obsolete'
      cast(
        case when Root.MDChgProcessIsStarted = 'X'
             and _NumberOfSouceRecords.MDChgProcessNmbrOfSrceRecords = 0
        then 'X'
        else ''
      end as abap_boolean preserving type )                                                        as MDChangeProcessIsObsolete,
      @ObjectModel.readOnly: true
      @EndUserText.label: 'Attachments'
      _Attachments.NumberOfAttachments,
      @ObjectModel.readOnly: true
      @EndUserText.label: 'Notes'
      _NoteItem.NumberOfNotes,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_CALC_EXIT'
      cast( '' as abap_boolean preserving type )                                                   as MDChgProcDspAttchIsAllowed,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_CALC_EXIT'
      cast('' as mdc_process_id)                                                                   as MDChgProcVisualizationProcess,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_MDC_PROCESS_CALC_EXIT'
      cast('' as mdc_business_system)                                                              as MDChgProcVisualizationSrceSyst,
      Root.MDChgProcRefcdFederationToken,
      Root.MDChgProcRefcdFederationStp,
      Root.MDChgProcFederationBusSystName,
      @Semantics.businessDate.at: true
      Root.MasterDataChangeProcessDueDate,
      @ObjectModel.text.element: [ 'MDChangeProcessReasonText' ]
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      Root.MasterDataChangeProcessReason,
      @ObjectModel.readOnly: true
      _ReasonText.MDChangeProcessReasonText                                                        as MDChangeProcessReasonText,
      @ObjectModel.readOnly: true
      @ObjectModel.text.element: [ 'MDChangeProcessReasonText' ]
      concat( Root.MDChgProcessSrceObjectTypeCode, Root.MasterDataChangeProcessReason )            as MDChgProcObjectTypeCodeReason,
      @ObjectModel.text.element: [ 'MDChangeProcessPriorityText' ]
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      Root.MDChangeProcessPriority,
      @ObjectModel.readOnly: true
      _PriorityText.MDChangeProcessPriorityText                                                    as MDChangeProcessPriorityText,
      @ObjectModel:{
        text.element: [ 'MDChgProcRejectionReasonText' ],
        foreignKey.association: '_TypeRejectionReason'
      }
      @ObjectModel.text.control: #ASSOCIATED_TEXT_UI_HIDDEN
      @UI.hidden: true
      Root.MDChangeProcessRejectionReason,
      @ObjectModel.readOnly: true
      @EndUserText.label: 'Rejection Reason is required'
      @UI.hidden: true
      cast(
        case when _RejectionReason.MDChgProcNmbrOfRjcnRsn is null
          or MDChgProcessIsFinalized = 'X' or MDChgProcessIsErased = 'X'
        then ' '
        else 'X'
      end as abap_boolean preserving type )                                                        as MDChgProcRjcnReasonIsRequired,
      @ObjectModel.readOnly: true
      @UI.hidden: true
      _RejectionReasonText.MDChgProcRejectionReasonText,

      /* Associations */
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Source,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Step,
      @Consumption.filter.hidden: true
      _MDQualityEvaluations,
      @ObjectModel.readOnly: true
      _StepDescription.MDChgProcessStepDescription                                                 as MDChgProcessTypeStepDspDesc,
      @ObjectModel.readOnly: true
      _StepDescription.MDChgProcessStepType                                                        as MDChgProcessTypeStepDesc,
      _ProcessUserVH,
      @Consumption.filter.hidden: true
      _ProcessVariant,
      _ProcessGoalVH,
      _ProcessStateVH,
      @Search.defaultSearchElement: false
      _ProcessState,
      _ProcessTypeVH,
      @Search.defaultSearchElement: false
      _ProcessGoalText,
      _GoalProperty,
      @Search.defaultSearchElement: false
      _ProcessTypeText,
      _ProcessStrategyVH,
      _RelatedProcess,
      @Consumption.filter.hidden: true
      _ProcessRequestorContactCard,
      @Consumption.filter.hidden: true
      @UI.hidden: true
      _TypeRejectionReason
}