C_FixedAssetUsageObjectTP_2

DDL: C_FIXEDASSETUSAGEOBJECTTP_2 Type: view_entity CONSUMPTION Package: FINS_FAA_UO_VDM

Fixed Asset Usage Object

C_FixedAssetUsageObjectTP_2 is a Consumption CDS View that provides data about "Fixed Asset Usage Object" in SAP S/4HANA. It reads from 1 data source (R_FixedAssetUsageObjectTP) and exposes 18 fields with key fields CompanyCode, FixedAssetUsageObject. It has 2 associations to related views. Part of development package FINS_FAA_UO_VDM.

1 data source(s) 18 fields

Data Sources (1)

SourceAliasJoin Type
R_FixedAssetUsageObjectTP R_FixedAssetUsageObjectTP projection

Associations (2)

CardinalityTargetAliasCondition
[0..*] C_FixedAssetUsageObjWhereUsd _UsageObjectWhereUsd $projection.CompanyCode = _UsageObjectWhereUsd.CompanyCode and $projection.FixedAssetUsageObject = _UsageObjectWhereUsd.FixedAssetUsageObject
[0..*] C_FixedAssetUsageObjectRmng _UsageObjectRmng $projection.CompanyCode = _UsageObjectRmng.CompanyCode and $projection.FixedAssetUsageObject = _UsageObjectRmng.FixedAssetUsageObject

Annotations (8)

NameValueLevelField
EndUserText.label Fixed Asset Usage Object view
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.viewType #CONSUMPTION view
Metadata.allowExtensions true view
Search.searchable true view

Fields (18)

KeyFieldSource TableSource FieldDescription
KEY CompanyCode CompanyCode
KEY FixedAssetUsageObject FixedAssetUsageObject
ChangeDocTableKey ChangeDocTableKey
FixedAssetUsageObjectDesc FixedAssetUsageObjectDesc
BaseUnit BaseUnit
UnitOfMeasureName
FixedAssetUsageObjLfcycSts FixedAssetUsageObjLfcycSts
FixedAssetUsageObjLfcycName
CreationDateTime CreationDateTime
CreatedByUser CreatedByUser
LastChangeDateTime LastChangeDateTime
LastChangedByUser LastChangedByUser
CompanyCodeName _CompanyCode CompanyCodeName
_CompanyCode _CompanyCode
_UnitOfMeasure _UnitOfMeasure
_UsageObjectLifecycleStatus _UsageObjectLifecycleStatus
_UsageObjectWhereUsd _UsageObjectWhereUsd
_UsageObjectRmng _UsageObjectRmng 
@EndUserText.label: 'Fixed Asset Usage Object'
@AccessControl.authorizationCheck: #MANDATORY
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #TRANSACTIONAL
}
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE] 
@VDM.viewType: #CONSUMPTION
@Metadata.allowExtensions: true
@Search.searchable: true
@ObjectModel.semanticKey: [ 'CompanyCode', 'FixedAssetUsageObject' ]

define root view entity C_FixedAssetUsageObjectTP_2
  provider contract transactional_query
  as projection on R_FixedAssetUsageObjectTP
  association [0..*] to C_FixedAssetUsageObjWhereUsd as _UsageObjectWhereUsd on  $projection.CompanyCode           = _UsageObjectWhereUsd.CompanyCode
                                                                             and $projection.FixedAssetUsageObject = _UsageObjectWhereUsd.FixedAssetUsageObject
  association [0..*] to C_FixedAssetUsageObjectRmng  as _UsageObjectRmng     on  $projection.CompanyCode           = _UsageObjectRmng.CompanyCode
                                                                             and $projection.FixedAssetUsageObject = _UsageObjectRmng.FixedAssetUsageObject
{
         @Consumption.valueHelpDefinition: [ { entity: { name: 'I_CompanyCodeStdVH', element: 'CompanyCode' } } ]
         @Search.defaultSearchElement: true
         @ObjectModel.text.element: ['CompanyCodeName']
  key    CompanyCode,

         @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
         @Consumption.valueHelpDefinition: [ { entity: { name: 'I_FixedAssetUsageObjectVH', element: 'FixedAssetUsageObject' },
                                               additionalBinding:  [ { localElement: 'CompanyCode', element:'CompanyCode' } ]
                                           } ]
  key    FixedAssetUsageObject,

         @Consumption.filter.hidden: true
         ChangeDocTableKey,

         @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
         @Consumption.filter.hidden: true
         FixedAssetUsageObjectDesc,

         @ObjectModel.text.element: ['UnitOfMeasureName']
         @Consumption.valueHelpDefinition: [ { entity: { name: 'I_UnitOfMeasureStdVH', element: 'UnitOfMeasure' } } ]
         BaseUnit,

         @Consumption.filter.hidden: true
         _UnitOfMeasure._Text[ 1: Language = $session.system_language ].UnitOfMeasureName,

         @ObjectModel.text.element: ['FixedAssetUsageObjLfcycName']
         @Consumption.filter.hidden: true
         FixedAssetUsageObjLfcycSts,

         @Consumption.valueHelpDefinition: [ { entity: { name: 'I_FxdAstUsageObjectLfcycStsVH', element: 'FixedAssetUsageObjLfcycName' },
                                               additionalBinding:[ { localElement: 'FixedAssetUsageObjLfcycSts',
                                                                     element: 'FixedAssetUsageObjLfcycSts',
                                                                     usage: #FILTER } ]
                                           } ]
         _UsageObjectLifecycleStatus._Text[ 1: Language = $session.system_language ].FixedAssetUsageObjLfcycName,

         @Consumption.filter.selectionType:  #SINGLE
         CreationDateTime,

         CreatedByUser,

         @Consumption.filter.selectionType:  #SINGLE
         LastChangeDateTime,

         LastChangedByUser,

         @Consumption.filter.hidden: true
         _CompanyCode.CompanyCodeName,

         /* Associations */
         _CompanyCode,
         _UnitOfMeasure,
         _UsageObjectLifecycleStatus,
         _UsageObjectWhereUsd,
         @ObjectModel.filter.enabled: false
         _UsageObjectRmng,
         _UsageObjectPeriod : redirected to composition child C_FixedAssetUsageObjPerdTP_2,
         _UsageObjectTotal  : redirected to composition child C_FixedAssetUsageObjectTotTP_2

}

Learn More