R_FIXEDASSETUSAGEOBJECTTP

CDS View

Fixed Asset Usage Object

R_FIXEDASSETUSAGEOBJECTTP is a CDS View in S/4HANA. Fixed Asset Usage Object. 4 CDS views read from this table.

Used by 4 CDS view(s)

CDS Views using this table (4)

ViewTypeJoinVDMDescription
A_FixedAssetUsageObject view_entity projection CONSUMPTION Fixed Asset Usage Object
C_FixedAssetUsageObjectTP view_entity projection CONSUMPTION Fixed Asset Usage Object
C_FixedAssetUsageObjectTP_2 view_entity projection CONSUMPTION Fixed Asset Usage Object
I_FixedAssetUsageObjectTP view_entity projection TRANSACTIONAL Fixed Asset Usage Object - TP 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Fixed Asset Usage Object'
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #TRANSACTIONAL
}
@VDM.viewType: #TRANSACTIONAL
@ObjectModel.sapObjectNodeType.name:     'FixedAssetUsageObject'

define root view entity R_FixedAssetUsageObjectTP
  as select from I_FixedAssetUsageObject
  composition [0..*] of R_FixedAssetUsageObjectPerdTP as _UsageObjectPeriod
  composition [0..*] of R_FixedAssetUsageObjectTotTP  as _UsageObjectTotal
{
  key    CompanyCode,

  key    FixedAssetUsageObject,

         cast( rpad( concat( CompanyCode, FixedAssetUsageObject ), 16, '' ) as cdtabkey ) as ChangeDocTableKey,

         FixedAssetUsageObjectDesc,

         BaseUnit,

         FixedAssetUsageObjLfcycSts,

         cast (case
              when FixedAssetUsageObjLfcycSts = '1' then 'X'
              else ''
          end
         as faa_uo_is_active preserving type )                                            as IsActive,

         @Semantics.systemDateTime.createdAt: true  
         CreationDateTime,

         @Semantics.user.createdBy: true
         CreatedByUser,

         //local ETag field --> OData ETag

         @Semantics.systemDateTime.localInstanceLastChangedAt: true
         LastChangeDateTime,

         @Semantics.user.lastChangedBy: true
         LastChangedByUser,

         //total ETag field

         @Semantics.systemDateTime.lastChangedAt: true
         DraftLastChangedDateTime,

         /* Associations */
         _CompanyCode,
         _UnitOfMeasure,
         _UsageObjectLifecycleStatus,
         _UsageObjectPeriod,
         _UsageObjectTotal

}

Learn More