C_DeficitCashPoolAnalytics

DDL: C_DEFICITCASHPOOLANALYTICS SQL: CDCSHPLANLYTS Type: view CONSUMPTION Package: FINS_FIS_CASH_APPS

Deficit Cash Pool

C_DeficitCashPoolAnalytics is a Consumption CDS View that provides data about "Deficit Cash Pool" in SAP S/4HANA. It reads from 4 data sources (I_Bank, I_BankAccount, I_CompanyCode, P_Fclm_Deficit_Cash_Pool_Tb) and exposes 13 fields with key fields CompanyCode, BankAccountInternalID, BankAccountCurrency. Part of development package FINS_FIS_CASH_APPS.

4 data source(s) 13 fields

Data Sources (4)

SourceAliasJoin Type
I_Bank _Bank left_outer
I_BankAccount _BankAccount left_outer
I_CompanyCode _CompanyCode inner
P_Fclm_Deficit_Cash_Pool_Tb P_Fclm_Deficit_Cash_Pool_Tb from

Parameters (4)

NameTypeDefault
P_KeyDate sydate
P_ExchangeRateType kurst
P_DisplayCurrency vdm_v_display_currency
P_Language sylangu

Annotations (11)

NameValueLevelField
EndUserText.label Deficit Cash Pool view
OData.publish true view
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #CHECK view
AbapCatalog.sqlViewName CDCSHPLANLYTS view
AbapCatalog.compiler.compareFilter true view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.serviceQuality #D view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view
Metadata.ignorePropogatedAnnotations true view

Fields (13)

KeyFieldSource TableSource FieldDescription
KEY CompanyCode pos CompanyCode
KEY BankAccountInternalID pos BankAccountInternalID
BankAccountCurrency Bank Account Currency
KEY BankAccountCurrency I_BankAccount BankAccountCurrency
BankAccount pos BankAccount
BankAccountDescription
CompanyCodeName I_CompanyCode CompanyCodeName
Bank pos Bank
BankName I_Bank BankName
DisplayCurrency pos DisplayCurrency
CashPool pos CashPool
CashPoolName pos CashPoolName
AmountInDisplayCurrency pos AmountInDisplayCurrency 
@EndUserText.label: 'Deficit Cash Pool'
@OData.publish: true
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'CDCSHPLANLYTS'
@AbapCatalog.compiler.compareFilter: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #MIXED
@Metadata.ignorePropogatedAnnotations: true
define view C_DeficitCashPoolAnalytics
  with parameters
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_DATE
    P_KeyDate          : sydate,
    P_ExchangeRateType : kurst,
    P_DisplayCurrency  : vdm_v_display_currency,
    @Consumption.hidden: true
    @Environment.systemField: #SYSTEM_LANGUAGE
    P_Language         : sylangu
  as select from P_Fclm_Deficit_Cash_Pool_Tb
                 (
                                       P_KeyDate: $parameters.P_KeyDate ,
                                       P_DisplayCurrency :$parameters.P_DisplayCurrency,
                                       P_ExchangeRateType :$parameters.P_ExchangeRateType,
                                       P_SAPClient: $session.client ) as pos
                 inner join I_CompanyCode  as _CompanyCode
                        on  pos.CompanyCode = _CompanyCode.CompanyCode
                 left outer join I_BankAccount as _BankAccount
                        on  pos.BankAccountInternalID = _BankAccount.BankAccountInternalID
                 left outer join I_Bank as _Bank
                        on  pos.Bank  = _Bank.BankInternalID and pos.BankCountry = _Bank.BankCountry
{

      @ObjectModel.text.element:  [ 'CompanyCodeName' ]
      key pos.CompanyCode,

      @ObjectModel.text.element:  [ 'BankAccountDescription' ]
      key pos.BankAccountInternalID,

     @EndUserText.label: 'Bank Account Currency'
     @Semantics.currencyCode: true
--      key cast(pos.Currency as fclm_bank_acct_currency) as BankAccountCurrency,
      key _BankAccount.BankAccountCurrency  as BankAccountCurrency,


      pos.BankAccount,
      @Semantics.text: true
      _BankAccount._Text[1:Language=$parameters.P_Language].BankAccountDescription,

      @Semantics.text: true
      _CompanyCode.CompanyCodeName,

      @ObjectModel.text.element:  [ 'BankName' ]
      pos.Bank,
      @Semantics.text: true
      _Bank.BankName,


      @Semantics.currencyCode: true
      @Consumption.hidden: true
      pos.DisplayCurrency,

      @ObjectModel.text.element: 'CashPoolName'
      pos.CashPool,
      @Semantics.text: true
      pos.CashPoolName,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'DisplayCurrency'
      pos.AmountInDisplayCurrency

}

Learn More