I_BANK

CDS View

Bank

I_BANK is a CDS View in S/4HANA. Bank. It contains 10 fields. 12 CDS views read from this table.

Used by 12 CDS view(s) 10 fields

CDS Views using this table (12)

ViewTypeJoinVDMDescription
C_BankAcctVhTemp view from CONSUMPTION Bank Account
C_BankChainBankStdVH view_entity from CONSUMPTION Bank Master Details
C_DeficitCashPoolAnalytics view left_outer CONSUMPTION Deficit Cash Pool
C_House_Bank_App view left_outer CONSUMPTION House Bank Consumption view
C_NO_SAFTGenLedgerCustBankAcct view inner CONSUMPTION SAF-T Norway GL Customer Bank Accounts
C_NO_SAFTGenLedgerSuplrBkAcct view inner CONSUMPTION SAF-T Norway GL Supplier Bank Accounts
I_Bank_Acct_VH view from BASIC Bank Data
I_BankRating view from COMPOSITE Bank rating
SHSM_JPBNKA view from Find bank
VFCLM_BAM_DDL_AMD_WTTHDESP2 view left_outer Bank Account Master Data with Description (no parameter)
VFCLM_BAM_DDL_BANK view from Bank Master Data
VFCLM_BAM_DDL_BANK_HIER_BGN view left_outer Bank Hierarchy Bank Group Name Mapping

Fields (10)

KeyField CDS FieldsUsed in Views
KEY BankCountry BankCountry 3
KEY BankInternalID BankInternalID 1
Bank Bank,BankNumber 2
BankName Banka,BankName 5
BankNetworkGrouping BankNetworkGrouping 1
Branch Branch 1
CityName CityName 1
Region Region 1
StreetName StreetName 1
SWIFTCode Swift,SWIFTCode 5 
@AbapCatalog.sqlViewName: 'IFIBANKMASTER'
@EndUserText.label: 'Bank'
@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}
@VDM.viewType: #BASIC
@VDM.lifecycle.status: #DEPRECATED
@VDM.lifecycle.successor: 'I_BANK_2'
@ObjectModel.representativeKey: 'BankInternalID'
@AccessControl.authorizationCheck: #CHECK //#NOT_REQUIRED

@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE]
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions:true
@Search.searchable: true
@AbapCatalog.preserveKey:true
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.sapObjectNodeType.name: 'Bank'
define view I_Bank
  as select from bnka
  //    left outer join adr6 as address_mail on  bnka.adrnr = address_mail.addrnumber

  //and bnka.adrnr <> ''

  association [0..1] to I_Address              as _Address              on  $projection.AddressID = _Address.AddressID
  association [0..1] to I_Region               as _Region               on  $projection.Region      = _Region.Region
                                                                        and $projection.BankCountry = _Region.Country
  association [0..*] to I_Housebank            as _HouseBank            on  $projection.Bank        = _HouseBank.HouseBank
                                                                        and $projection.BankCountry = _HouseBank.BankCountry
  association [0..1] to I_Country              as _Country              on  $projection.BankCountry = _Country.Country
  association [0..1] to I_BankAdditionalFields as _BankAdditionalFields on  $projection.BankCountry    = _BankAdditionalFields.BankCountry
                                                                        and $projection.BankInternalID = _BankAdditionalFields.BankInternalID
  association [0..1] to I_BankIntraStaRule     as _IntradayRule         on  $projection.BankCountry    = _IntradayRule.BankCountry
                                                                        and $projection.BankInternalID = _IntradayRule.BankInternalID

{
      @ObjectModel.foreignKey.association: '_Country'
  key banks as BankCountry,
      @ObjectModel.text.element: 'BankName'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8 
      @Search.ranking: #HIGH
  key bankl as BankInternalID,
      erdat as CreationDate,
      ernam as CreatedByUser,
      @Semantics.text: true
      banka as BankName,
      provz as Region,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ShortStreetName'
      stras as StreetName,
      stras as ShortStreetName, //successor for StreetName

      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'ShortCityName'      
      ort01 as CityName,
      ort01 as ShortCityName, //successor for CityName

      swift as SWIFTCode,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'BankNetworkGrouping'
      bgrup as BankGroup,
      bgrup as BankNetworkGrouping, //successor for BankGroup

      xpgro as IsPostBankAccount,
      loevm as IsMarkedForDeletion,
      bnklz as Bank,
      pskto as PostOfficeBankAccount,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: 'BankBranch'
      brnch as Branch,
      brnch as BankBranch, //successor for Branch

      chkme as CheckDigitCalculationMethod,
      vers  as BankDataFileFormat,
      adrnr as AddressID,
      //      address_mail.smtp_addr as RoleOwnerEmailAddress,

      _Address,
      _Region,
      _HouseBank,
      _Country,
      _BankAdditionalFields,
      _IntradayRule
}
where
     loevm = ''
  or loevm = ' ';

Learn More