C_CustomerProject

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@AbapCatalog.sqlViewName: 'CCUSTOMERPROJECT'
@EndUserText.label: 'Customer Project'
@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck:#CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
define view C_CustomerProject
  as select from           I_EngagementProject         as EngagementProject


    left outer to one join C_EngagementProjectPlanData as EngagementProjectPlanData on EngagementProjectPlanData.EngagementProject = EngagementProject.EngagementProject
    left outer to one join P_ProjectsWthMyInvlmnt      as MyProjects                on MyProjects.EngagementProject = EngagementProject.EngagementProject
    
  //replacing C_WorkpackageDetails with C_WorkPackage as of 2302 release..

  association [0..*] to C_WorkPackage           as _WorkPackage         on  $projection.EngagementProjFinPlanUUID = _WorkPackage.EngagementProjFinPlanUUID
  association [0..1] to I_EngagementProjectRole as _ProjectController   on  $projection.CustomerProject                  = _ProjectController.EngagementProject
                                                                        and _ProjectController.EngagementProjectTeamRole = 'P003'
  association [0..1] to I_EngagementProjectRole as _ProjectAccountant   on  $projection.CustomerProject                  = _ProjectAccountant.EngagementProject
                                                                        and _ProjectAccountant.EngagementProjectTeamRole = 'P002'
  association [0..1] to I_EngagementProjectRole as _ProjectPartner      on  $projection.CustomerProject               = _ProjectPartner.EngagementProject
                                                                        and _ProjectPartner.EngagementProjectTeamRole = 'P004'
  association [0..1] to E_CustomerProject       as _Extension           on  $projection.CustomerProject = _Extension.CustomerProject


  association [0..*] to I_PersnWrkAgreementDet  as _PersonWorkAgreement on  $projection.ProjectManagerWorkAgreement = _PersonWorkAgreement.PersonWorkAgreement
{
  key EngagementProject.EngagementProject                    as CustomerProject,
      EngagementProject.EngagementProjectUUID                as CustomerProjectUUID,
      _EngagementProjFinancialPlan.EngagementProjFinPlanUUID as EngagementProjFinPlanUUID,
      EngagementProject.ProjectVisibility                    as ProjectVisibility,
      EngagementProject.EngagementProjectType                as CustomerProjectType,
      EngagementProject.EngagementProjectStage               as CustomerProjectStage,
      EngagementProject.CompanyCode                          as CompanyCode,
      EngagementProject.ProjectProfileCode                   as ProjectProfileCode,
      EngagementProject.ControllingArea                      as ControllingArea,
      //--[ GENERATED:012:GlBfhyJl7kY4nNBXcDIuRm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_CostCenterStdVH',
                     element: 'CostCenter' },
          additionalBinding: [{ localElement: 'ControllingArea',
                                element: 'ControllingArea' }]
        }]
      // ]--GENERATED

      EngagementProject.CostCenter                           as CostCenter,
      //--[ GENERATED:012:GlBfhyJl7kY4nNBXcDIuRm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_EngmntProjSrvcOrgStdVH',
                     element: 'EngagementProjectServiceOrg' }
        }]
      // ]--GENERATED

      EngagementProject.EngagementProjectServiceOrg          as CustomerProjectServiceOrg,
      EngagementProject.EngagementProjectCategory            as EngagementProjectCategory,
      //--[ GENERATED:012:GlBfhyJl7kY4nNBXcDIuRm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_ProfitCenterStdVH',
                     element: 'ProfitCenter' },
          additionalBinding: [{ localElement: 'ControllingArea',
                                element: 'ControllingArea' }]
        }]
      // ]--GENERATED

      EngagementProject.ProfitCenter                         as ProfitCenter,
      EngagementProject.EngagementProjectName                as CustomerProjectName,
      //--[ GENERATED:012:GlBfhyJl7kY4nNBXcDIuRm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_Customer_VH',
                     element: 'Customer' }
        }]
      // ]--GENERATED

      EngagementProject.Customer                             as Customer,
      @Semantics.dateTime:true
      @Semantics.systemDateTime.lastChangedAt:true
      EngagementProject.LastChangeDateTime                   as LastChangeDateTime,
      EngagementProject.LastChangedByUser                    as LastChangedByUser,
       @VDM.lifecycle.status: #DEPRECATED
       @VDM.lifecycle.successor: 'ProjectManagerWorkAgreement'      
      EngagementProject.ProjectManager                       as ProjectManager,
      EngagementProject.ProjectManagerWorkAgreement          as ProjectManagerWorkAgreement,      
      EngagementProject.ProjectStartDate                     as ProjectStartDate,      
      EngagementProject.ProjectEndDate                       as ProjectEndDate,
      
      @Semantics.currencyCode: true
      EngagementProjectPlanData.Currency                     as Currency,

      @Semantics.amount.currencyCode:'Currency'
      EngagementProjectPlanData.PlndCostAmt                  as PlndCostAmt,
      
      EngagementProjectPlanData.PlndEffortQty                as PlndEffortQty,
      
      @Semantics.amount.currencyCode:'Currency'
      EngagementProjectPlanData.PlndRevnAmt                  as PlndRevnAmt,
      MyProjects.IsMyProject                                 as IsMyProject,

      _ControllingArea,
      _CostCenter,
      _ProfitCenter,
      _Customer,
      _EngagementProjectItem,
      //need to adapt after i_engagementproject is active

      _PersonWorkAgreement,
      _ProjectController,
      _ProjectAccountant,
      _ProjectPartner,
      _EngagementProjectServiceOrg,
      _EngagementProjectStage,
      _EngagementProjFinancialPlan,
      _WorkPackage
      //  _Employment

}
where
  EngagementProject.EngagementProjectCategory = 'C'