C_CndnContrTypeSuplrDisplay

@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@Consumption.ranked: true
@ObjectModel.semanticKey: [ 'CndnContrType' ]
@ObjectModel.representativeKey: 'CndnContrType'
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.sizeCategory: #S
@ObjectModel.dataCategory: #VALUE_HELP
@Analytics.technicalName: 'CWCBCCTYPESUPLRD'
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Supplier Contract Types for Display'
@Metadata.ignorePropagatedAnnotations: true

// Supplier Condition Contract Types with authority 03 (display)

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view entity C_CndnContrTypeSuplrDisplay
  as select from I_CndnContrType as CCType_Suplr

  association [0..1] to I_CndnContrProcessCategory as _CndnContrProcessCategory on $projection.CndnContrProcessCategory = _CndnContrProcessCategory.CndnContrProcessCategory

{
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 1.0  }
      @ObjectModel.text.element: [ 'CndnContrTypeDesc' ]
      @UI: {
          selectionField: [{position: 10}],
          textArrangement: #TEXT_LAST
        }
  key CCType_Suplr.CndnContrType                                                                                                     as CndnContrType,

      @Semantics.text:true
      @Search: { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8  }
      @UI: {
          selectionField: [{position: 20}]
        }
      _Text[1: Language = $session.system_language ].CndnContrTypeDesc                                                               as CndnContrTypeDesc,

      @ObjectModel.text.element: ['CndnContrProcessCategoryDesc']
      @Consumption.valueHelpDefinition: [{
          entity: { name: 'I_CndnContrProcessCategory', element: 'CndnContrProcessCategory' }
      }]
      @UI: {
      //      hidden: true,

          selectionField: [{ position: 30, exclude: false }],
          textArrangement: #TEXT_ONLY,
          lineItem: [{hidden: true}]
        }
      cast ( coalesce( CCType_Suplr._CndnContrClassfctnType.CndnContrProcessCategory, '' ) as wcb_process_category preserving type ) as CndnContrProcessCategory,

      @Semantics.text: true
      @Consumption.filter.hidden: true
      @UI: {
          hidden: true
        }
      _CndnContrClassfctnType._CndnContrProcessCategory._Text[1: Language = $session.system_language ].CndnContrProcessCategoryDesc  as CndnContrProcessCategoryDesc,

      //Associations

      @Consumption.filter.hidden: true
      _CndnContrProcessCategory

}
where
    ( CCType_Suplr.CndnContrPartnerCat     = 'V'
   or CCType_Suplr.CndnContrSettlmtType    = '1' )
  and CCType_Suplr.CndnContrChangeability  = ''
  and CCType_Suplr.CndnContrTypeBlockUsage = ''