I_CNDNCONTRTYPE

CDS View

Condition Contract Type

I_CNDNCONTRTYPE is a CDS View in S/4HANA. Condition Contract Type. It contains 1 fields. 19 CDS views read from this table.

Used by 19 CDS view(s) 1 fields

CDS Views using this table (19)

ViewTypeJoinVDMDescription
A_BusVolFldCombnSetTypeAssgmt view from COMPOSITE Field Combination Assignment
A_CndnContrType view from COMPOSITE Condition Contract Type
C_CndnContrTypeCustCreate view_entity from CONSUMPTION Customer Contract Types for Creation
C_CndnContrTypeCustDisplay view_entity from CONSUMPTION Customer Contract Types for Display
C_CndnContrTypeRoytyCreate view_entity from CONSUMPTION Royalty Contract Types for Creation
C_CndnContrTypeSuplrCreate view_entity from CONSUMPTION Supplier Contract Types for Creation
C_CndnContrTypeSuplrDisplay view_entity from CONSUMPTION Supplier Contract Types for Display
C_MngCustCndnContr view_entity inner CONSUMPTION Monitor Customer Condition Contracts
C_MngSuplrCndnContr view_entity inner CONSUMPTION Monitor Supplier Condition Contracts
C_MntrRoytyCndnContr view_entity inner CONSUMPTION Monitor Royalty Condition Contracts
I_CndnContrCustomerListStdVH view_entity inner COMPOSITE Condition Contract Customer List
I_CndnContrCustomerStdVH view_entity inner COMPOSITE Customer Condition Contracts
I_CndnContrExtSlsCommsnStdVH view_entity inner COMPOSITE External Sales Commissions
I_CndnContrPlantListStdVH view_entity inner COMPOSITE Condition Contract Plant List
I_CndnContrPurgRbteStdVH view_entity inner COMPOSITE Purchasing Rebate Condition Contracts
I_CndnContrRoyaltyStdVH view_entity inner COMPOSITE Royalty Condition Contracts
I_CndnContrSupplierListStdVH view_entity inner COMPOSITE Condition Contract Supplier List
I_CndnContrSupplierStdVH view_entity inner COMPOSITE Supplier Condition Contracts
I_CndnContrTypeStdVH view_entity from COMPOSITE Condition Contract Type

Fields (1)

KeyField CDS FieldsUsed in Views
KEY CndnContrType CndnContrType 6 
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  privilegedAssociations: ['_Text'],
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey:     'CndnContrType',
   sapObjectNodeType.name: 'ConditionContractType',
   modelingPattern: #ANALYTICAL_DIMENSION,
   supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                           #CDS_MODELING_ASSOCIATION_TARGET, 
                           #SQL_DATA_SOURCE, 
                           #CDS_MODELING_DATA_SOURCE,
                           #EXTRACTION_DATA_SOURCE],
   usageType: {
     dataClass:      #CUSTOMIZING,
     serviceQuality: #A,
     sizeCategory:   #S
  }
} 
@Analytics: {
    dataCategory: #DIMENSION,
    dataExtraction.enabled: true,
    internalName: #LOCAL
}
@Analytics.technicalName: 'IWLFCOCOTYPE'
@EndUserText.label: 'Condition Contract Type'
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions:true

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view entity I_CndnContrType
  as select from R_CndnContrType

  association [0..*] to I_CndnContrTypeText       as _Text                    on $projection.CndnContrType = _Text.CndnContrType
  association [0..1] to I_CndnContrTypeBlockUsage as _CndnContrTypeBlockUsage on $projection.CndnContrTypeBlockUsage = _CndnContrTypeBlockUsage.CndnContrTypeBlockUsage
  association [0..1] to I_CndnContrPartnerCat     as _CndnContrPartnerCat     on $projection.CndnContrPartnerCat = _CndnContrPartnerCat.CndnContrPartnerCat
  association [0..1] to I_CndnContrChangeability  as _CndnContrChangeability  on $projection.CndnContrChangeability = _CndnContrChangeability.CndnContrChangeability
  association [0..1] to I_BusVolFldCombnSet       as _BusVolFldCombnSet       on $projection.BusVolFldCombnSet = _BusVolFldCombnSet.BusVolFldCombnSet
  association [0..1] to I_CndnContrClassfctnType  as _CndnContrClassfctnType  on $projection.CndnContrClassfctnType = _CndnContrClassfctnType.CndnContrClassfctnType
  association [0..1] to I_CndnContrItemCategory   as _CndnContrItemCategory   on $projection.CndnContrItemCategory = _CndnContrItemCategory.CndnContrItemCategory
  association [0..1] to I_CndnContrEligibleCat    as _CndnContrEligibleCat    on $projection.CndnContrEligibleCat = _CndnContrEligibleCat.CndnContrEligibleCat
  association [0..1] to I_CndnContrSettlmtType    as _CndnContrSettlmtType    on $projection.CndnContrSettlmtType = _CndnContrSettlmtType.CndnContrSettlmtType
  association [0..1] to I_CndnContrPrtlSettlmtCat as _CndnContrPrtlSettlmtCat on $projection.CndnContrPrtlSettlmtCat = _CndnContrPrtlSettlmtCat.CndnContrPrtlSettlmtCat
  association [0..1] to I_CndnContrAccrRvslCat    as _CndnContrAccrRvslCat    on $projection.CndnContrAccrRvslCat = _CndnContrAccrRvslCat.CndnContrAccrRvslCat

{
      @ObjectModel.text.association: '_Text'
  key CndnContrType,

      @ObjectModel.foreignKey.association: '_CndnContrTypeBlockUsage'
      CndnContrTypeBlockUsage,
      @ObjectModel.foreignKey.association: '_CndnContrPartnerCat'
      CndnContrPartnerCat,
      @ObjectModel.foreignKey.association: '_CndnContrEligibleCat'
      CndnContrEligibleCat,
      @ObjectModel.foreignKey.association: '_CndnContrClassfctnType'
      CndnContrClassfctnType,
      CndnContrHasNoConditions,
      @ObjectModel.foreignKey.association: '_CndnContrSettlmtType'
      CndnContrSettlmtType,
      @ObjectModel.foreignKey.association: '_CndnContrChangeability'
      CndnContrChangeability,
      @ObjectModel.foreignKey.association: '_BusVolFldCombnSet'
      BusVolFldCombnSet,
      @ObjectModel.foreignKey.association: '_CndnContrPrtlSettlmtCat'
      CndnContrPrtlSettlmtCat,
      @ObjectModel.foreignKey.association: '_CndnContrItemCategory'
      CndnContrItemCategory,
      @ObjectModel.foreignKey.association: '_CndnContrAccrRvslCat'
      CndnContrAccrRvslCat,

      //Associations

      _Text,
      _CndnContrTypeBlockUsage,
      _CndnContrPartnerCat,
      _CndnContrClassfctnType,
      _CndnContrChangeability,
      _BusVolFldCombnSet,
      _CndnContrItemCategory,
      _CndnContrEligibleCat,
      _CndnContrSettlmtType,
      _CndnContrPrtlSettlmtCat,
      _CndnContrAccrRvslCat
}

Learn More