@AbapCatalog.sqlViewName: 'CCHGIMPCTPLR'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey: true
@EndUserText.label: 'Planning Routing Details'
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #MIXED}
@ObjectModel.semanticKey: [ 'BillOfOperationsGroup', 'BillOfOperationsType', 'BillOfOperationsVariant' ]
@UI.headerInfo:
{
title:{value:'BillOfOperationsGroup'}
}
define view C_ChgImpactPlngRoutingDets
as select from I_BillOfOperationsChangeState as ChgImpactPlngRoutingDets
association [0..*] to I_BillOfOperationsTypeText as _BillOfOperationsTypeText on $projection.BillOfOperationsType = _BillOfOperationsTypeText.BillOfOperationsType
association [1..1] to I_BillOfOperationsUsageText as _BillOfOperationsUsageText on $projection.BillOfOperationsUsage = _BillOfOperationsUsageText.BillOfOperationsUsage
and _BillOfOperationsUsageText.Language = $session.system_language
association [0..1] to I_BillOfOperationsStatusText as _BillOfOperationsStatusText on $projection.BillOfOperationsStatus = _BillOfOperationsStatusText.BillOfOperationsStatus
and _BillOfOperationsStatusText.Language = $session.system_language
association [0..*] to C_ChgImpactPlngRoutingMBOM as _ChgImpactPlngRoutingMBOM on $projection.BillOfOperationsGroup = _ChgImpactPlngRoutingMBOM.BillOfOperationsGroup
and $projection.BillOfOperationsType = _ChgImpactPlngRoutingMBOM.BillOfOperationsType
and $projection.BillOfOperationsVariant = _ChgImpactPlngRoutingMBOM.BillOfOperationsVariant
association [0..*] to C_ChgImpactPlngRoutingOp as _ChgImpactPlngRoutingOP on $projection.BillOfOperationsGroup = _ChgImpactPlngRoutingOP.BillOfOperationsGroup
and $projection.BillOfOperationsType = _ChgImpactPlngRoutingOP.BillOfOperationsType
and $projection.BillOfOperationsVariant = _ChgImpactPlngRoutingOP.BillOfOperationsVariant
association [0..*] to I_BillOfOperationsOpBasic as _BillOfOperationsOpBasic on $projection.BillOfOperationsGroup = _BillOfOperationsOpBasic.BillOfOperationsGroup
and $projection.BillOfOperationsType = _BillOfOperationsOpBasic.BillOfOperationsType
{
@UI.facet: [
----HeaderFacets
{ type: #FIELDGROUP_REFERENCE, position: 10, targetQualifier: 'GeneralData'},
{ type: #FIELDGROUP_REFERENCE, position: 30, targetQualifier: 'AdministrativeData'}
]
@UI.fieldGroup:[{position: 10,qualifier: 'Qualifier1',label:'Group', importance: #HIGH}]
key ChgImpactPlngRoutingDets.BillOfOperationsGroup,
@UI.fieldGroup:[{position: 20,qualifier: 'Qualifier1',label:'Task List Type', importance: #HIGH}]
@ObjectModel.text.element: [ 'BillOfOperationsTypeName' ]
key ChgImpactPlngRoutingDets.BillOfOperationsType,
@UI.fieldGroup:[{position: 10,qualifier: 'Qualifier2',label:'Group Counter', importance: #HIGH}]
key ChgImpactPlngRoutingDets.BillOfOperationsVariant,
//@UI.fieldGroup:[{position: 20,qualifier: 'Qualifier2',label:'Internal Version Counter', importance: #HIGH}]
@ObjectModel.text.element: null
key ChgImpactPlngRoutingDets.BOOInternalVersionCounter,
// General Data Facet
@UI.fieldGroup:[{position: 40,qualifier: 'GeneralData',groupLabel: 'General Data' }]
ChgImpactPlngRoutingDets.BillOfOperationsDesc,
@UI.fieldGroup:[{position: 50,qualifier: 'GeneralData',groupLabel: 'General Data'}]
ChgImpactPlngRoutingDets.ChangeNumber,
@UI.fieldGroup:[{position: 60,qualifier: 'GeneralData',groupLabel: 'General Data'}]
@ObjectModel.text.element: [ 'BillOfOperationsUsageDesc' ]
ChgImpactPlngRoutingDets.BillOfOperationsUsage,
@UI.hidden: true
ChgImpactPlngRoutingDets.BillOfOperationsStatus,
@UI.fieldGroup:[{position: 70,qualifier: 'GeneralData',groupLabel: 'General Data'}]
_BillOfOperationsStatusText.BillOfOperationsStatusDesc,
@UI.fieldGroup:[{position: 80,qualifier: 'GeneralData',groupLabel: 'General Data'}]
ChgImpactPlngRoutingDets.Plant as ProductionPlant,
@UI.fieldGroup:[{position: 90,qualifier: 'GeneralData',groupLabel: 'General Data'}]
@Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
ChgImpactPlngRoutingDets.MinimumLotSizeQuantity,
@UI.fieldGroup:[{position: 100,qualifier: 'GeneralData',groupLabel: 'General Data'}]
@Semantics.quantity.unitOfMeasure: 'BillOfOperationsUnit'
ChgImpactPlngRoutingDets.MaximumLotSizeQuantity,
//@UI.fieldGroup:[{position: 110,qualifier: 'GeneralData',groupLabel: 'General Data'}]
ChgImpactPlngRoutingDets.ResponsiblePlannerGroup,
//@UI.fieldGroup:[{position: 120,qualifier: 'GeneralData',groupLabel: 'General Data'}]
ChgImpactPlngRoutingDets.WorkCenterTypeCode,
@UI.fieldGroup:[{position: 120,qualifier: 'GeneralData',groupLabel: 'General Data'}]
ChgImpactPlngRoutingDets.EffectivityType,
@UI.fieldGroup:[{position: 130,qualifier: 'GeneralData',groupLabel: 'General Data'}]
ChgImpactPlngRoutingDets.ValidityStartDate, // For Filterring data based on Date Range
@UI.fieldGroup:[{position: 140,qualifier: 'GeneralData',groupLabel: 'General Data'}]
ChgImpactPlngRoutingDets.ValidityEndDate, // For Filterring data based on Date Range
@Semantics.unitOfMeasure: true
ChgImpactPlngRoutingDets.BillOfOperationsUnit,
// Quality Management
// @UI.fieldGroup:[{position: 10,qualifier: 'QualityManagement',groupLabel: 'Quality Management'}]
// ChgImpactPlngRoutingDets.InspectionPartialLot,
// @UI.fieldGroup:[{position: 20,qualifier: 'QualityManagement',groupLabel: 'Quality Management'}]
// ChgImpactPlngRoutingDets.InspExternalNumberingOfValues,
// @UI.fieldGroup:[{position: 30,qualifier: 'QualityManagement',groupLabel: 'Quality Management'}]
// ChgImpactPlngRoutingDets.InspSubsetFieldCombination,
// @UI.fieldGroup:[{position: 40,qualifier: 'QualityManagement',groupLabel: 'Quality Management'}]
// ChgImpactPlngRoutingDets.SmplDrawingProcedure,
// @UI.fieldGroup:[{position: 50,qualifier: 'QualityManagement',groupLabel: 'Quality Management'}]
// ChgImpactPlngRoutingDets.InspLotDynamicRule,
// @UI.fieldGroup:[{position: 60,qualifier: 'QualityManagement',groupLabel: 'Quality Management'}]
// ChgImpactPlngRoutingDets.InspectionLotDynamicLevel,
// Administrative Data
@UI.fieldGroup:[{position: 10,qualifier: 'AdministrativeData',groupLabel: 'Administrative Data'}]
ChgImpactPlngRoutingDets.CreationDate,
@UI.fieldGroup:[{position: 20,qualifier: 'AdministrativeData',groupLabel: 'Administrative Data'}]
ChgImpactPlngRoutingDets.CreatedByUser,
@UI.fieldGroup:[{position: 30,qualifier: 'AdministrativeData',groupLabel: 'Administrative Data'}]
ChgImpactPlngRoutingDets.LastChangeDate,
@UI.fieldGroup:[{position: 40,qualifier: 'AdministrativeData',groupLabel: 'Administrative Data'}]
ChgImpactPlngRoutingDets.LastChangedByUser,
@UI.fieldGroup:[{position: 50,qualifier: 'AdministrativeData',groupLabel: 'Administrative Data'}]
ChgImpactPlngRoutingDets.LastUsageDate,
@UI.fieldGroup:[{position: 60,qualifier: 'AdministrativeData',groupLabel: 'Administrative Data'}]
ChgImpactPlngRoutingDets.NumberOfUsages,
@UI.hidden: true
_BillOfOperationsTypeText[1:Language = $session.system_language].BillOfOperationsTypeName as BillOfOperationsTypeName,
_BillOfOperationsUsageText[1:Language = $session.system_language].BillOfOperationsUsageDesc as BillOfOperationsUsageDesc,
_ChgImpactPlngRoutingMBOM,
_ChgImpactPlngRoutingOP,
_BillOfOperationsOpBasic,
_BillOfOperations,
_BillOfOperationsGroup,
_BillOfOperationsStatus,
_BillOfOperationsType,
_BillOfOperationsTypeText,
_BillOfOperationsStatusText,
_BillOfOperationsUsageText
}
where
ChgImpactPlngRoutingDets.BillOfOperationsType = 'P'