C_ChgImpactPlngRoutingOp

@AbapCatalog.sqlViewName: 'CCHGIMPLNGROUOP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Planning Routing Operation'
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@VDM.viewType: #CONSUMPTION
@UI.presentationVariant.requestAtLeast: ['ChangeNumber', 'Plant', 'ChangeRecord','IsDefinite','IsChanged', 'EffectivityParameterDesc', 'EffectivityType']
define view C_ChgImpactPlngRoutingOp as select from I_ChgImpactPlngRoutingOp as RoutingOperation {

  key RoutingOperation.BillOfOperationsType,
  key RoutingOperation.BillOfOperationsGroup,
  @UI.hidden: true
  key RoutingOperation.BOOOperationInternalID,
  key RoutingOperation.BillOfOperationsVariant,
  @UI.hidden: true
  key RoutingOperation.BOOOpInternalVersionCounter,
  
      RoutingOperation.BillOfOperationsSequence,

      RoutingOperation.BillOfOperationsVersion,

      RoutingOperation.WorkCenterInternalID,
      @UI.lineItem:[{position: 30,importance: #HIGH, label: 'Work Center' }]
      RoutingOperation.WorkCenterTypeCode,
     
      @UI.hidden: true
      RoutingOperation.IsDeleted,
      @UI.hidden: true
      RoutingOperation.IsImplicitlyDeleted,

      // ************************** Operation Header ***************************


      RoutingOperation.OperationExternalID,
      @UI.lineItem:[{position: 10,importance: #HIGH, label: 'Operation' }]
      RoutingOperation.Operation,

      // ************************** Operation General **************************


      -- Operation
      @UI.lineItem:[{position: 20,importance: #HIGH }]
      RoutingOperation.OperationText,
      @UI.hidden: true
      RoutingOperation.LongTextLanguageCode,
      RoutingOperation.Plant,
      @UI.lineItem:[{position: 40,importance: #HIGH }]
      RoutingOperation.OperationControlProfile,

      RoutingOperation.OperationStandardTextCode,

      -- Origin
      RoutingOperation.BillOfOperationsRefType,
      RoutingOperation.BillOfOperationsRefGroup,
      RoutingOperation.BillOfOperationsRefVariant,

      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement:true
      @UI.lineItem:[{position: 50,importance: #HIGH, label: 'Component Exist' }]
      cast( ' ' as abap.char( 1 ) ) as OpActyHasAssignedComponents,     
//      case when RoutingOperation.BillOfMaterial <> '' and RoutingOperation.BillOfMaterialItemNodeNumber <> '' then 'X'

//      else ' ' end  as OpActyHasAssignedComponents,

          
      // *************************** Administration ****************************


      -- Administrative Data
      //@Semantics.systemDate.createdAt: true

      RoutingOperation.CreationDate,
      //@Semantics.user.createdBy: true

      RoutingOperation.CreatedByUser,

      //@Semantics.systemDate.lastChangedAt: true

      RoutingOperation.LastChangeDate,
      //@Semantics.user.lastChangedBy: true

      RoutingOperation.LastChangedByUser,

      -- Validity
      RoutingOperation.ChangeNumber,

      @UI.lineItem:[{position: 70,importance: #HIGH}]
      RoutingOperation.ValidityStartDate,
      @UI.lineItem:[{position: 80,importance: #HIGH}]
      RoutingOperation.ValidityEndDate,
      
        @UI.hidden: true
        @ObjectModel.virtualElement:true
        cast('' as cc_efft)                                                                                                           as EffectivityType,
        
      
        @UI.lineItem:[{position: 90,importance: #HIGH }]
        @ObjectModel: {
        filter: {
           transformedBy: 'ABAP:CL_MPE_CIMA_SADL_FILTER_CONV'
        }
        }
        cast('' as text255 )                                                                                                           as EffectivityParameterDesc,
      
        @UI.hidden: true
        @ObjectModel: {
        filter: {
           transformedBy: 'ABAP:CL_MPE_CIMA_SADL_FILTER_CONV'
        }
        }
        cast( ' ' as abap.char( 255 ) )                                                                                                 as NetChangeAnalysisPath,
        @ObjectModel: {
            filter: {
                transformedBy: 'ABAP:CL_MPE_CIMA_SADL_FILTER_CONV'
            }
        }
        cast(' '  as mpe_mec_cima_isdefinite)                                                                                           as IsDefinite,
        @ObjectModel: {
        filter: {
           transformedBy: 'ABAP:CL_MPE_CIMA_SADL_FILTER_CONV'
        }
        }
        cast(' ' as mpe_mec_cima_ischanged )                                                                                            as IsChanged,
        
        @UI.hidden: true
        @ObjectModel: {
        filter: {
           transformedBy: 'ABAP:CL_MPE_CIMA_SADL_FILTER_CONV'
        }
        }
        cast('' as /plmb/cr_id )  as ChangeRecord
        
}