@AbapCatalog.sqlViewName: 'CCABUSPARLITEM'
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: ''
@AccessControl.personalData.blocking: #REQUIRED
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel: {
// compositionRoot: true,
// draftEnabled: false,
// transactionalProcessingDelegated: true,
semanticKey: 'CADocument',
representativeKey: 'CADocument',
updateEnabled
}
@Search.searchable: true
@UI.headerInfo: {
typeName: 'Geschäftspartnerposition',
typeNamePlural: 'Geschäftspartnerpositionen',
title: {
type: #STANDARD,
value: 'CADocument'
}
}
@UI.presentationVariant.sortOrder: { by: 'CAPostingDate', direction: #DESC }
define view C_CABusinessPartnerLineItem
as select from I_CADocumentBPItemEnhanced as BPItem
association [1..1] to E_CADocumentBPItemPhysical as _Extension on $projection.CADocument = _Extension.CADocumentNumber
and $projection.CARepetitionItemNumber = _Extension.CARepetitionItemNumber
and $projection.CABPItemNumber = _Extension.CABPItemNumber
and $projection.CASubItemNumber = _Extension.CASubItemNumber
{
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
@UI: {
lineItem: [{ position: 30, importance: #HIGH}],
selectionField.position: 30
}
@Consumption.semanticObject: 'CADocument'
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CADocumentHeaderValueHelp', element: 'CADocumentNumber'}}]
key CADocumentNumber as CADocument,
@UI.fieldGroup: { qualifier: 'AdditionalData'}
key CARepetitionItemNumber,
@UI.fieldGroup: { qualifier: 'AdditionalData', groupLabel: 'Weitere Einzelheiten'}
key CABPItemNumber,
@UI.fieldGroup: { qualifier: 'AdditionalData'}
key CASubItemNumber,
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
@UI: {
lineItem: [{ position: 10, importance: #HIGH}],
selectionField.position: 10
}
@ObjectModel: { text.element: [ 'BusinessPartnerFullName' ] }
@Semantics: { contact.type: #PERSON }
@Consumption.semanticObject: 'CAContractPartner'
//@UI.textArrangement: #TEXT_FIRST
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner'}}]
BusinessPartner,
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
@UI.hidden
_BusinessPartner.FirstName,
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
@UI.hidden
_BusinessPartner.LastName,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Geschäftspartnertext'
cast(_BusinessPartner.BusinessPartnerFullName as gpart_text_gfn_kk preserving type ) as BusinessPartnerFullName,
@UI: {
lineItem: [{ position: 20, importance: #HIGH}],
selectionField.position: 20
}
@ObjectModel: { text.element: ['ContractAccountName']}
@Consumption.semanticObject: 'ContractAccount'
@Consumption.valueHelpDefinition: [{entity: { name: 'C_ContractAccountValueHelp', element: 'ContractAccount'}}]
ContractAccount,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Vertragskontotext'
cast(_ContractAccount.ContractAccountName as vkbez_text_gfn_kk preserving type ) as ContractAccountName,
@UI: {
lineItem: [{ position: 40, importance: #HIGH}],
selectionField.position: 40
}
@Consumption.filter.selectionType: #INTERVAL
CAPostingDate,
@UI: {
lineItem: [{ position: 50, importance: #HIGH}],
selectionField.position: 50
}
@EndUserText.label: 'Ausgleichsstatus'
@ObjectModel: { text.element: ['CAClearingStatusName']}
CAClearingStatus,
@Semantics.text: true
@Consumption.filter.hidden: true
cast('' as augst_text_gfn_kk) as CAClearingStatusName,
@UI: {
lineItem: [{ position: 60}],
selectionField.position: 60
}
@ObjectModel: { text.element: [ 'CAClearingReasonName' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CAClearingReasonValueHelp', element: 'CAClearingReason'}}]
CAClearingReason,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(_CAClearingReason._Text[1: Language=$session.system_language].CAClearingReasonName as augrd_text_gfn_kk ) as CAClearingReasonName,
@UI:{ lineItem: { position: 70, importance: #HIGH}}
@UI.fieldGroup: { qualifier: 'ClearingData', groupLabel: 'Ausgleichsdaten' }
@Consumption.filter.selectionType: #INTERVAL
CAClearingDate,
@UI:{ lineItem: { position: 80, importance: #HIGH}}
@UI.fieldGroup: { qualifier: 'ClearingData'}
@Consumption.semanticObject: 'CAClearingDocument'
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CADocumentHeaderValueHelp', element: 'CADocumentNumber'}}]
CAClearingDocumentNumber,
@UI: {
lineItem: [{ position: 90}],
selectionField.position: 90
}
@ObjectModel: { text.element: [ 'CAStstcCodeNameOfOriginItem' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CAStatisticalItemCodeVH', element: 'CAStatisticalItemCode'}}]
@UI.textArrangement: #TEXT_FIRST
CAStatisticalItemCode,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(
_CAStatisticalItemCode._CAStatisticalItemCodeText[1: Language=$session.system_language].CAStatisticalItemCodeText
as stakz_text_gfn_kk preserving type ) as CAStstcCodeNameOfOriginItem,
@UI: {
lineItem: [{ position: 100}],
selectionField.position: 100
}
@ObjectModel.mandatory: true
@Consumption.filter.selectionType: #INTERVAL
CANetDueDate,
@UI: {
lineItem: [{ position: 110, importance: #HIGH}],
selectionField.position: 110
}
@Semantics.amount.currencyCode: 'TransactionCurrency'
CAAmountInTransactionCurrency,
@UI.selectionField.position: 120
@ObjectModel: { text.element: ['CAMainTransactionName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CAMainTransactionValueHelp', element: 'CAMainTransaction'}}]
CAMainTransaction,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Hauptvorgangstext'
_CAMainTransaction._Text[1: Language=$session.system_language].CAMainTransactionName,
@UI.selectionField.position: 130
@ObjectModel: { text.element: ['CASubTransactionName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CASubTransactionValueHelp', element: 'CASubTransaction'}}]
@UI.textArrangement: #TEXT_FIRST
CASubTransaction,
@Semantics.text: true
@Consumption.filter.hidden: true
_CASubTransaction._Text[1: Language=$session.system_language].CASubTransactionName,
@UI.selectionField.position: 140
@Consumption.filter.selectionType: #INTERVAL
CADeferralDate,
// Account Assignment
@UI.fieldGroup: { qualifier: 'AccountAssignment', groupLabel: 'Kontierung'}
@ObjectModel: { text.element: [ 'CompanyCodeName' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CACompanyCodeVH', element: 'CompanyCode'}}]
@Consumption.semanticObject: 'CompanyCode'
CompanyCode,
@Semantics.text: true
@Consumption.filter.hidden: true
cast( _CompanyCode.CompanyCodeName as bukrs_text_gfn_kk preserving type ) as CompanyCodeName,
// @UI.fieldGroup: { qualifier: 'AccountAssignment'}
// @ObjectModel: { text.element: ['BusinessAreaName']}
// @Consumption.valueHelpDefinition: [{entity: { name: 'C_CABusinessAreaValueHelp', element: 'BusinessArea'}}]
@UI.hidden: true
BusinessArea,
@UI.hidden: true
_BusinessArea._Text[1: Language=$session.system_language].BusinessAreaName as BusinessAreaName,
@UI.fieldGroup: { qualifier: 'AccountAssignment'}
@ObjectModel: { text.element: ['SegmentName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'I_SegmentStdVH', element: 'Segment'}}]
Segment,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(_Segment._Text[1: Language=$session.system_language].SegmentName as segmt_text_kk preserving type ) as SegmentName,
// Trading Partner
@UI.fieldGroup: { qualifier: 'AccountAssignment'}
@ObjectModel: { text.element: [ 'PartnerCompanyName' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'I_Partnercompany', element: 'PartnerCompany'}}]
@EndUserText.label: 'Partnergesellschaftsnummer'
PartnerCompany,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Text zur Partnergesellschaftsnummer'
cast(_PartnerCompany.CompanyName as rassc_text_kk preserving type ) as PartnerCompanyName,
@UI.fieldGroup: { qualifier: 'AccountAssignment'}
//No Value help defined.
@Consumption.semanticObject: 'CAContract'
@ObjectModel.text.element: ['CAProviderContractName']
CAContract,
@Semantics.text: true
cast(_CAProviderContract.CAProviderContractName as vtref_text_gfn_kk preserving type) as CAProviderContractName,
@UI.hidden
cast('' as vtref_semobj_kk) as CAContractSemanticObject,
@UI.fieldGroup: { qualifier: 'AccountAssignment'}
//No Value help defined.
CAProviderContractItemNumber,
@UI.fieldGroup: { qualifier: 'AccountAssignment'}
@ObjectModel: { text.element: ['CASubApplicationText']}
@UI.textArrangement: #TEXT_ONLY
CASubApplication,
@Semantics.text: true
@Consumption.filter.hidden: true
_CASubApplication._CASubApplicationText[1:Language = $session.system_language].CASubApplicationText,
// G/L Account
@UI.fieldGroup: { qualifier: 'AccountAssignment'}
@ObjectModel: { text.element: ['CAReconciliationAccountName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'C_GLAccountValueHelp', element: 'GLAccount'}}]
CAReconciliationAccount,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(
_ReconciliationAccount._Text[1: Language=$session.system_language].GLAccountName
as hkont_text_kk preserving type ) as CAReconciliationAccountName,
@Consumption.valueHelpDefinition: [{ entity: { name: 'I_GLAccountHierarchyStdVH', element: 'GLAccountHierarchy' } }]
@Consumption.filter.selectionType: #SINGLE
@ObjectModel.filter.transformedBy: 'ABAP:CL_FINS_HIER_VH_FLTR_TRANSFORM'
@UI.fieldGroup: { qualifier: 'AccountAssignment'}
cast('' as fis_glaccthier) as GLAccountHierarchy,
@Consumption.filter.hidden: true
@ObjectModel.filter.transformedBy: 'ABAP:CL_FINS_HIER_VH_FLTR_TRANSFORM'
cast('' as fis_glacct_hrynid_50) as GLAccountHierarchyNode,
@UI.fieldGroup: { qualifier: 'AccountAssignment' }
@Semantics.amount.currencyCode: 'TransactionCurrency'
cast(PlannedAmtInTransactionCrcy as fdwbt) as PlannedAmtInTransactionCrcy,
// Profit Center
@UI.fieldGroup: { qualifier: 'AccountAssignment'}
@ObjectModel: { text.element: [ 'ProfitCenterName' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'I_ProfitCenterVH', element: 'ProfitCenter'}}]
ProfitCenter,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(_ProfitCenter._Text[1: Language=$session.system_language].ProfitCenterName as prctr_text_gfn_kk preserving type ) as ProfitCenterName,
@UI.fieldGroup: { qualifier: 'AccountAssignment'}
@Consumption.valueHelpDefinition: [{ entity:{ name: 'I_ProfitCenterHierarchyVH', element: 'ProfitCenterHierarchy' } }]
@Consumption.filter.selectionType: #SINGLE
@ObjectModel.filter.transformedBy: 'ABAP:CL_FINS_HIER_VH_FLTR_TRANSFORM'
@ObjectModel.readOnly: true
// @ObjectModel:{
// virtualElement: true,
// virtualElementCalculatedBy: 'ABAP:CL_FCLM_BAM_MBA_CALC_EXIT'
// }
cast('' as fis_prctr_hryid_42) as ProfitCenterHierarchy,
@ObjectModel.filter.transformedBy: 'ABAP:CL_FINS_HIER_VH_FLTR_TRANSFORM'
// @ObjectModel.readOnly: true
// @ObjectModel:{
// virtualElement: true,
// virtualElementCalculatedBy: 'ABAP:CL_FCLM_BAM_MBA_CALC_EXIT'
// }
@Consumption.filter.hidden: true
cast('' as fis_prctr_hrynid_50) as ProfitCenterHierarchyNode,
// Cash Discount
@UI.fieldGroup: { qualifier: 'CashDiscount', groupLabel: 'Skonto' }
@Consumption.filter.selectionType: #INTERVAL
@EndUserText.label: 'Skontofälligkeit'
CACashDiscountDueDate,
@UI.fieldGroup: { qualifier: 'CashDiscount' }
@Semantics.quantity.unitOfMeasure: 'CAPercentageUnit'
CACashDiscountRate,
@UI.hidden: true
@Semantics.unitOfMeasure: true
cast('%' as unit) as CAPercentageUnit,
@UI.fieldGroup: { qualifier: 'CashDiscount'}
@Semantics.amount.currencyCode: 'TransactionCurrency'
CAEligibleAmountForCshDiscount,
@UI.fieldGroup: { qualifier: 'CashDiscount'}
@Semantics.amount.currencyCode: 'TransactionCurrency'
CACashDiscAmountInClearingCrcy,
// Cash Management and Forecast
@UI.fieldGroup: { qualifier: 'CashManagemenetandForecast', groupLabel: 'Finanzdisposition' }
@ObjectModel: { text.element: [ 'CashPlanningGroupName' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CashPlanningGroup', element: 'CashPlanningGroup'}}]
CashPlanningGroup,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Dispositionsgruppentext'
_CashPlanningGroup._Text[1: Language=$session.system_language].CashPlanningGroupName,
@UI.fieldGroup: { qualifier: 'CashManagemenetandForecast' }
@ObjectModel: { text.element: [ 'PlanningLevelName' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'I_PlanningLevel', element: 'PlanningLevel'}}]
PlanningLevel,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(_PlanningLevel._Text[1: Language=$session.system_language].PlanningLevelName as fdlev_text_kk preserving type ) as PlanningLevelName,
// Clearing Data
@UI.fieldGroup: { qualifier: 'ClearingData'}
@Consumption.filter.selectionType: #INTERVAL
CAPostingDateOfClearingDoc,
@UI.fieldGroup: { qualifier: 'ClearingData'}
@Semantics.currencyCode: true
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CurrencyValueHelp', element: 'Currency'}}]
CAClearingCurrency,
@UI.fieldGroup: { qualifier: 'ClearingData'}
@Semantics.amount.currencyCode: 'CAClearingCurrency'
CAClearingAmountInClearingCrcy,
@UI.fieldGroup: { qualifier: 'ClearingData'}
@Consumption.filter.selectionType: #INTERVAL
CAValueDateForClearing,
@UI.fieldGroup: { qualifier: 'ClearingData'}
@ObjectModel: { text.element: [ 'CAClearingRestrictionCodeName' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CAClearingRestrictionCodeVH', element: 'CAClearingRestrictionCode'}}]
CAClearingRestrictionCode,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Ausgleichsrestriktionstext'
cast(
_CAClearingRestrictionCode._Text[1: Language=$session.system_language].CAClearingRestrictionCodeName
as augrs_text_gfn_kk preserving type ) as CAClearingRestrictionCodeName,
// Dunning Data
@UI.fieldGroup: { qualifier: 'DunningData', groupLabel: 'Mahndaten' }
@ObjectModel: { text.element: [ 'CAItemIsExcludedFromDunText' ] }
CAItemIsExcludedFromDunning,
@Semantics.text: true
@UI.hidden: true
cast('' as val_text) as CAItemIsExcludedFromDunText,
@UI.fieldGroup: { qualifier: 'DunningData'}
@ObjectModel: { text.element: [ 'CADunningProcedureName' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CADunningProcedure', element: 'CADunningProcedure'}}]
CADunningProcedure,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Text zum Mahnverfahren'
cast(
_CADunningProcedure._Text[1: Language=$session.system_language].CADunningProcedureName
as mahnv_text_kk preserving type ) as CADunningProcedureName,
// Factoring
@UI.fieldGroup: { qualifier: 'Factoring', groupLabel: 'Factoring' }
CACurrentFactoringStatusOfRbl,
@Semantics.text: true
@UI.hidden: true
cast('' as val_text) as CACurrentFactoringStsNameOfRbl,
@UI.fieldGroup: { qualifier: 'Factoring' }
CAFactoringCheckStsForClrgInfo,
@UI.hidden
cast('' as val_text) as CAFactoringClrgInfoChkStsName,
// Miscellaneous
@UI.fieldGroup: { qualifier: 'Further', groupLabel: 'Sonstiges'}
@Consumption.valueHelpDefinition: [{entity: { name: 'I_Branch', element: 'Branch'}}]
BusinessPlace,
@UI.fieldGroup: { qualifier: 'Further'}
@ObjectModel: { text.element: [ 'CAReceivingCountryName' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'I_Country', element: 'Country'}}]
CAReceivingCountry,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(_ReceivingCountry._Text[1: Language=$session.system_language].CountryName as landl_text_kk) as CAReceivingCountryName,
@UI.fieldGroup: { qualifier: 'Further'}
@ObjectModel: { text.element: [ 'CAWorkflowCheckReasonName' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CAWorkflowCheckReason', element: 'CAWorkflowCheckReason'}}]
CAWorkflowCheckReason,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(
_CAWorkflowCheckReason._Text[1: Language=$session.system_language].CAWorkflowCheckReasonName
as c4eye_text_kk) as CAWorkflowCheckReasonName,
@UI.fieldGroup: { qualifier: 'Further'}
CAGrpgCodeForTransfToCollAgcy,
@UI.fieldGroup: { qualifier: 'Further'}
@ObjectModel: { text.element: [ 'CAIsIncludedInCollCaseText' ] }
CAIsIncludedInCollectionCase,
@Semantics.text: true
@Consumption.filter.hidden: true
cast('' as xcolc_text_kk) as CAIsIncludedInCollCaseText,
// Header Data
@UI.fieldGroup: { qualifier: 'HeaderData', groupLabel: 'Kopfdaten'}
@ObjectModel: { text.element: ['CADocumentTypeName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CADocumentTypeValueHelp', element: 'CADocumentType'}}]
CADocumentType,
@Semantics.text: true
@Consumption.filter.hidden: true
_CADocumentType._Text[1: Language=$session.system_language].CADocumentTypeName,
@UI.fieldGroup: { qualifier: 'HeaderData'}
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CADocumentHeaderValueHelp', element: 'CADocumentNumber'}}]
@Consumption.semanticObject: 'CADocument'
CASubstituteDocumentNumber,
@Consumption.filter.hidden
@ObjectModel: { text.element: [ 'CASubstituteDocCategoryName' ] }
@EndUserText.label: 'Stellvertretender Belegtyp'
CASubstituteDocumentCategory,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Text zum stellvertretenden Belegtyp'
cast('' as abwtp_text_gfn_kk) as CASubstituteDocCategoryName,
@UI.fieldGroup: { qualifier: 'HeaderData'}
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CADocumentHeaderValueHelp', element: 'CADocumentNumber'}}]
@Consumption.semanticObject: 'CADocument'
CADocumentNumberOfOriginItem,
@UI.fieldGroup: { qualifier: 'HeaderData'}
@Consumption.semanticObject: 'CAReferenceDocument'
CAReferenceDocument,
// Individual Value Adjustment
@UI.fieldGroup: { qualifier: 'IVA', groupLabel: 'Einzelwertberichtigung' }
@ObjectModel: { text.element: ['CADoubtfulOrValueAdjmtCodeName']}
CADoubtfulOrValueAdjmtCode,
@Semantics.text: true
@Consumption.filter.hidden: true
cast('' as infoz_text_gfn_kk) as CADoubtfulOrValueAdjmtCodeName,
// Interest Data
@ObjectModel: { text.element: [ 'CAInterestCodeName' ] }
@UI.fieldGroup: { qualifier: 'InterestData', groupLabel: 'Zinsdaten'}
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CAInterestCodeValueHelp', element: 'CAInterestCode'}}]
CAInterestCode,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(
_CAInterestCode._Text[1: Language=$session.system_language].CAInterestCodeName
as ikey_text_kk preserving type ) as CAInterestCodeName,
// Payment Data
// Payment Order
@ObjectModel: { text.element: [ 'CAPaymentPreNotifCodeName' ] }
@UI.fieldGroup: { qualifier: 'PaymentData'}
CAPaymentPreNotificationCode,
@Semantics.text: true
@Consumption.filter.hidden: true
cast('' as xpyor_text_gfn_kk) as CAPaymentPreNotifCodeName,
//Can only be cleared
@UI.fieldGroup: { qualifier: 'PaymentData', groupLabel: 'Zahldaten'}
//@ObjectModel: { text.element: ['CAItemIsOnlyForSettlementText']}
CAItemIsOnlyForSettlement,
@Semantics.text: true
@UI.hidden: true
cast('' as val_text) as CAItemIsOnlyForSettlementText,
@UI.fieldGroup: { qualifier: 'PaymentData'}
//@ObjectModel: { text.element: ['CAIsDownPaymentRequestText']}
CAIsDownPaymentRequest,
@Semantics.text: true
@UI.hidden: true
cast('' as val_text) as CAIsDownPaymentRequestText,
@UI.fieldGroup: { qualifier: 'PaymentData'}
@ObjectModel: { text.element: ['CAPaymentMethodName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CAPaymentMethodVH', element: 'CAPaymentMethod'}}]
CAPaymentMethod,
@Semantics.text: true
@Consumption.filter.hidden: true
_CAPaymentMethod._Text[1: Language=$session.system_language].CAPaymentMethodName,
@ObjectModel: { text.element: ['CAPaymentCompanyCodeName']}
@UI.fieldGroup: { qualifier: 'PaymentData'}
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CACompanyCodeVH', element: 'CompanyCode'}}]
CAPaymentCompanyCode,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Text zum zahlenden Buchungskreis'
cast(_PaymentCompanyCode.CompanyCodeName as pybuk_text_kk preserving type ) as CAPaymentCompanyCodeName,
@UI.fieldGroup: { qualifier: 'PaymentData'}
CAGroupingForPayment,
@UI.fieldGroup: { qualifier: 'PaymentData'}
@ObjectModel: { text.element: ['CAPaymentSpecificationCatName']}
@EndUserText.label: 'Zahlungsfestlegungstyp'
CAPaymentSpecificationCategory,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Zahlungsfestlegungstyptext'
cast('' as pdtyp_text_gfn_kk) as CAPaymentSpecificationCatName,
@ObjectModel: { text.element: [ 'CAAltvBPForPaymentFullName' ] }
@UI.fieldGroup: { qualifier: 'PaymentData'}
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner'}}]
CAAltvBPForPayment,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Text zum Partner für die Zahlung'
cast(_PaytAltvBusinessPartner.BusinessPartnerFullName as emgpa_text_kk) as CAAltvBPForPaymentFullName,
@UI.hidden
CABankOfAltvBPForPayment,
@UI.hidden
CACardOfAltvBPForPayment,
// Revenue Distribution
@UI.fieldGroup: { qualifier: 'RevenueDistribution', groupLabel: 'Einnahmeverteilung' }
@ObjectModel: { text.element: [ 'CARevenueDistrFinalRcpntName' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'I_ContractAccountHeaderStdVH', element: 'ContractAccount'}}]
CARevenueDistrFinalRecipient,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(_RevnDistrFnlRcpntContrAccount.ContractAccountName as finre_text_kk preserving type) as CARevenueDistrFinalRcpntName,
//Revenue Sharing
@UI.fieldGroup: { qualifier: 'RevenueDistribution'}
@ObjectModel: { text.element: [ 'CAPartnerSettlementStatusName' ] }
CAPartnerSettlementStatus,
@Semantics.text: true
@Consumption.filter.hidden: true
cast('' as ptitm_text_gfn_kk) as CAPartnerSettlementStatusName,
@UI.fieldGroup: { qualifier: 'RevenueDistribution' }
@ObjectModel: { text.element: [ 'CARevenueDistrCurrentStsName' ] }
@EndUserText.label: 'Aktueller Verteilungsstatus'
CARevenueDistrCurrentStatus,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: ' Text zum aktuellen Verteilungsstatus'
cast('' as rdsta_text_gfn_kk) as CARevenueDistrCurrentStsName,
@UI.fieldGroup: { qualifier: 'RevenueDistribution' }
@ObjectModel: { text.element: [ 'CARevenueDistrLastStatusName' ] }
@EndUserText.label: 'Letzter Verteilungsstatus'
CARevenueDistrLastStatus,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Text zum letzten Verteilungsstatus'
cast('' as rdstb_text_kk) as CARevenueDistrLastStatusName,
// Tax Data
@UI.fieldGroup: { qualifier: 'TaxData'}
@ObjectModel: { text.element: ['TaxCodeName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'I_TaxCode', element: 'TaxCode'}}]
TaxCode,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(_TaxCode._Text[1: Language=$session.system_language].TaxCodeName as mwskz_text_kk preserving type) as TaxCodeName,
@UI.fieldGroup: { qualifier: 'TaxData', groupLabel: 'Steuerdaten' }
@Semantics.amount.currencyCode: 'TransactionCurrency'
CATaxAmountInLocalCurrency,
@UI.fieldGroup: { qualifier: 'TaxData'}
@Semantics.amount.currencyCode: 'TransactionCurrency'
CATaxAmountInTransCurrency,
@UI.fieldGroup: { qualifier: 'TaxData'}
@ObjectModel: { text.element: ['CADownPaymentTaxAcctLongName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'C_GLAccountValueHelp', element: 'GLAccount'}}]
CADownPaymentTaxAccount,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(
_DownPaymentTaxAccount._Text[1: Language=$session.system_language].GLAccountLongName
as mwsko_text_kk preserving type ) as CADownPaymentTaxAcctLongName,
@UI.fieldGroup: { qualifier: 'TaxData'}
@ObjectModel: { text.element: ['CADownPaymentOffsetTaxAcctName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'C_GLAccountValueHelp', element: 'GLAccount'}}]
CADownPaymentOffsetTaxAccount,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Text zum Steuerverrechnungskonto'
cast(
_DownPaymentOffsetTaxAccount._Text[1: Language=$session.system_language].GLAccountName
as mwvko_text_kk preserving type ) as CADownPaymentOffsetTaxAcctName,
@UI.fieldGroup: { qualifier: 'TaxData'}
@ObjectModel: { text.element: ['TaxJurisdictionName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'I_TaxJurisdiction', element: 'TaxJurisdiction'}}]
TaxJurisdiction,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Tax-Jurisdiction-Text'
cast(
_TaxJurisdiction._Text[1: Language=$session.system_language].TaxJurisdictionName
as txjcd_text_kk preserving type) as TaxJurisdictionName,
@UI.hidden
TaxCalculationProcedure,
@UI.fieldGroup: { qualifier: 'TaxData'}
@EndUserText.label: 'Quellensteuerprozentsatz'
@EndUserText.quickInfo: 'Quellensteuerprozentsatz'
@Semantics.quantity.unitOfMeasure: 'CAPercentageUnit'
CAWithholdingTaxPercentage,
@UI.fieldGroup: { qualifier: 'TaxData'}
@ObjectModel: { text.element: ['CAOtherTaxCodeName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CAOtherTaxCode', element: 'CAOtherTaxCode'}}]
@EndUserText.label: 'Kennzeichen für sonstige Steuer'
CAOtherTaxCode,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Text zum Kennzeichen für sonstige Steuer'
cast(
_CAOtherTaxCode._Text[1: Language=$session.system_language].CAOtherTaxCodeName
as strkz_text_kk preserving type) as CAOtherTaxCodeName,
@UI.fieldGroup: { qualifier: 'TaxData'}
@Semantics.amount.currencyCode: 'TransactionCurrency'
CATaxPortionInLocalCurrency,
@UI.fieldGroup: { qualifier: 'TaxData'}
@Semantics.amount.currencyCode: 'TransactionCurrency'
CATaxPortionInTransCurrency,
// Witholding Tax
@UI.fieldGroup: { qualifier: 'WitholdingTax'}
@ObjectModel: { text.element: ['WhldgTaxCodeName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'I_WithholdingTaxCode', element: 'WithholdingTaxCode'}}]
WithholdingTaxCode,
@Semantics.text: true
@Consumption.filter.hidden: true
cast(_WithholdingTaxCode.WhldgTaxCodeName as qsskz_text_kk preserving type) as WhldgTaxCodeName,
@UI.fieldGroup: { qualifier: 'WitholdingTax', groupLabel: 'Quellensteuer' }
@ObjectModel: { text.element: ['CAWithholdingTaxSuplmntName']}
@Consumption.valueHelpDefinition: [{entity: { name: 'I_CAWithholdingTaxSupplement', element: 'CAWithholdingTaxSupplement'}}]
@EndUserText.label: 'Quellensteuerzusatz'
CAWithholdingTaxSupplement,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Text zum Quellensteuerzusatz'
cast(
_CAWithholdingTaxSupplement._Text[1: Language=$session.system_language].CAWithholdingTaxSuplmntName
as qssew_text_kk preserving type) as CAWithholdingTaxSuplmntName,
@UI.fieldGroup: { qualifier: 'WitholdingTax'}
@ObjectModel: { text.element: ['CAWithholdingTaxCategoryName']}
@EndUserText.label: 'Quellensteuerkategorie'
CAWithholdingTaxCategory,
@Semantics.text: true
@Consumption.filter.hidden: true
@EndUserText.label: 'Text zur Quellensteuerkategorie'
cast('' as qsptp_text_gfn_kk) as CAWithholdingTaxCategoryName,
@UI.fieldGroup: { qualifier: 'WitholdingTax'}
@Semantics.amount.currencyCode: 'TransactionCurrency'
@EndUserText.label: 'Quellsteuerbetrag'
CAWithholdingTaxAmount,
@UI.fieldGroup: { qualifier: 'WitholdingTax' }
@EndUserText.label: 'Quellensteuerzertifikat'
WithholdingTaxCertificate,
// Further Details
@UI.fieldGroup: { qualifier: 'AdditionalData'}
@Semantics.currencyCode: true
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CurrencyValueHelp', element: 'Currency'}}]
TransactionCurrency,
@UI.fieldGroup: { qualifier: 'AdditionalData'}
@ObjectModel: { text.element: [ 'CAPeriodCodeName' ] }
@Consumption.valueHelpDefinition: [{entity: { name: 'C_CAPeriodCodeValueHelp', element: 'CAPeriodCode'}}]
CAPeriodCode,
@Semantics.text: true
@Consumption.filter.hidden: true
_CAPeriodCode._Text[1: Language=$session.system_language].CAPeriodCodeName,
@UI.fieldGroup: { qualifier: 'AdditionalData'}
@Consumption.filter.selectionType: #SINGLE
CAStartDateOfBillingPeriod,
@UI.fieldGroup: { qualifier: 'AdditionalData'}
@Consumption.filter.selectionType: #SINGLE
CAEndDateOfBillingPeriod,
// Canceled
@UI.fieldGroup: { qualifier: 'AdditionalData'}
@ObjectModel: { text.element: [ 'CAItemIsWithdrawnText' ] }
CAItemIsWithdrawn,
@Semantics.text: true
@UI.hidden: true
cast('' as val_text) as CAItemIsWithdrawnText,
@UI.fieldGroup: { qualifier: 'AdditionalData'}
@Semantics.amount.currencyCode: 'TransactionCurrency'
@EndUserText.label: 'Betrag Hauswährung'
CAAmountInLocalCurrency,
@UI.fieldGroup: { qualifier: 'AdditionalData'}
@Semantics.amount.currencyCode: 'TransactionCurrency'
CAAmountInSecondCurrency,
@UI.fieldGroup: { qualifier: 'AdditionalData'}
@Semantics.amount.currencyCode: 'TransactionCurrency'
CAAmountInThirdCurrency,
@UI.fieldGroup: { qualifier: 'AdditionalData'}
@Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
CABPItemText,
@UI.hidden
CAChangeIsForbidden,
@Consumption.filter.hidden
@ObjectModel: { text.element: [ 'CASEPAPreNotifOriginCodeText' ] }
CASEPAPreNotifOriginCode,
@Semantics.text: true
@Consumption.filter.hidden: true
cast('' as pnhkf_text_gfn_kk) as CASEPAPreNotifOriginCodeText,
@UI.hidden
cast('' as abap.char(120)) as UICT_FieldsChangedToEmpty,
// extra fields for authority checks
@UI.hidden
_ContractAccountPartner.CAAuthorizationGroup,
@UI.hidden
_CAProviderContract.CAAuthorizationGroup as CAProviderContractAuthznGroup
}