I_CADOCUMENTBPITEMENHANCED
Enhanced Document Business Partner Item
I_CADOCUMENTBPITEMENHANCED is a CDS View in S/4HANA. Enhanced Document Business Partner Item. It contains 16 fields. 5 CDS views read from this table.
CDS Views using this table (5)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_CABusinessPartnerLineItem | view | from | CONSUMPTION | |
| C_CAOpenItemLockedOnDocument | view | from | CONSUMPTION | Offene Posten gesperrt durch Belegsperre |
| I_CAInterestNoticeItem | view | from | COMPOSITE | View for Interest Notice Item Data |
| R_CADocumentBPItemTP | view_entity | from | TRANSACTIONAL | Document Business Partner Item - TP |
| R_CADocumentBPItemTP_2 | view_entity | from | TRANSACTIONAL | Document Business Partner Item - TP |
Fields (16)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | CABPItemNumber | CABPItemNumber | 1 |
| KEY | CADocumentNumber | CADocumentNumber | 1 |
| KEY | CARepetitionItemNumber | CARepetitionItemNumber | 1 |
| KEY | CASubItemNumber | CASubItemNumber | 1 |
| BusinessArea | BusinessArea | 1 | |
| BusinessPartner | BusinessPartner | 1 | |
| CAContract | CAContract | 1 | |
| CADunningProcedure | CADunningProcedure | 1 | |
| CAMainTransaction | CAMainTransaction | 1 | |
| CAPaymentMethod | CAPaymentMethod | 1 | |
| CASubTransaction | CASubTransaction | 1 | |
| CompanyCode | CompanyCode | 1 | |
| ContractAccount | ContractAccount | 1 | |
| Division | Division | 1 | |
| Segment | Segment | 1 | |
| TransactionCurrency | TransactionCurrency | 1 |
@AccessControl: { authorizationCheck: #MANDATORY,
personalData: { blocking: #REQUIRED,
blockingIndicator: ['_BusinessPartner.IsBusinessPurposeCompleted'] } }
@EndUserText.label: 'Enhanced Document Business Partner Item'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: { modelingPattern: #NONE,
supportedCapabilities: [ #CDS_MODELING_ASSOCIATION_TARGET,
#SQL_DATA_SOURCE,
#CDS_MODELING_DATA_SOURCE ],
usageType: { serviceQuality: #C,
sizeCategory: #XXL,
dataClass: #TRANSACTIONAL } }
@VDM.viewType: #COMPOSITE
define view entity I_CADocumentBPItemEnhanced
as select from I_CADocumentBPItem
association [1..1] to I_AdditionalCurrencyRoles as _AdditionalCurrencyRoles on $projection.CompanyCode = _AdditionalCurrencyRoles.CompanyCode
and _AdditionalCurrencyRoles.Ledger = ''
and _AdditionalCurrencyRoles.LedgerGroup = ''
association [0..1] to I_CashPlanningGroup as _CashPlanningGroup on $projection.CashPlanningGroup = _CashPlanningGroup.CashPlanningGroup
association [0..1] to I_TaxCalculationProcedure as _TaxCalculationProcedure on $projection.TaxCalculationProcedure = _TaxCalculationProcedure.TaxCalculationProcedure
association [0..1] to I_TaxCode as _TaxCode on $projection.TaxCalculationProcedure = _TaxCode.TaxCalculationProcedure
and $projection.TaxCode = _TaxCode.TaxCode
association [0..1] to I_TaxJurisdiction as _TaxJurisdiction on $projection.TaxCalculationProcedure = _TaxJurisdiction.TaxJurisdictionCalcProcedure
and $projection.TaxJurisdiction = _TaxJurisdiction.TaxJurisdiction
{
key CADocumentNumber,
key CARepetitionItemNumber,
key CABPItemNumber,
key CASubItemNumber,
CreationDate,
CreationTime,
LastChangeDate,
LastChangeTime,
CompanyCode,
BusinessArea,
BusinessPlace,
Segment,
ProfitCenter,
Division,
PersonnelNumber,
PartnerCompany,
BusinessPartner,
CAContract,
CAProviderContractItemNumber,
CAAdditionalContract,
ContractAccount,
CASubApplication,
AltvContractAcctForCollvBills,
CAReconciliationAccount,
CAApplicationArea,
CAMainTransaction,
CASubTransaction,
CAAccountDeterminationCode,
CADoubtfulOrValueAdjmtCode,
CAAccountAssignmentCategory,
CAAccountAssignment,
CADocumentType,
CAIsDownPaymentRequest,
@Semantics.booleanIndicator: true
CAItemIsOnlyForSettlement,
CAStatisticalItemCode,
CABPItemText,
CANumberOfRepetitionItems,
CARepetitionGroup,
CAStartDateOfBillingPeriod,
CAEndDateOfBillingPeriod,
CAGroupingCodeForBPItems,
CAPeriodCode,
CAChangeIsForbidden,
CAInterestCode,
CARoundingItemCode,
CAReceivingCountry,
CAInternalPostingReasonCode,
CAWorkflowCheckReason,
CAWorkflowCheckProcess,
CANegativePostingControlCode,
CAPartnerSettlementStatus,
@Semantics.booleanIndicator: true
CAIsPartOfJointLiability,
CADocumentOriginCode,
CAGroupingKeyDocumentItems,
CASubstituteDocumentNumber,
CASubstituteDocumentCategory,
CAStatisticalCodeOfOriginItem,
CADocumentNumberOfOriginItem,
CAReferenceDocument,
CAClassificationKey,
DocumentDate,
CAPostingDate,
CANetDueDate,
CADeferralDate,
TransactionCurrency,
CompanyCodeCurrency,
@ObjectModel.foreignKey.association: '_AdditionalCurrency1'
_AdditionalCurrencyRoles._AdditionalCrcyRole1Currency.Currency as AdditionalCurrency1,
@ObjectModel.foreignKey.association: '_AdditionalCurrency2'
_AdditionalCurrencyRoles._AdditionalCrcyRole2Currency.Currency as AdditionalCurrency2,
CAExchangeRate,
ExchRateIsIndirectQuotation,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
CAAmountInLocalCurrency,
@Semantics.amount.currencyCode: 'TransactionCurrency'
CAAmountInTransactionCurrency,
@Semantics.amount.currencyCode: 'AdditionalCurrency1'
CAAmountInSecondCurrency,
@Semantics.amount.currencyCode: 'AdditionalCurrency2'
CAAmountInThirdCurrency,
@Semantics.amount.currencyCode: 'TransactionCurrency'
CADocBPItemTotalAmountInTC,
@Semantics.amount.currencyCode: 'TransactionCurrency'
CADocBPItemOriglOpenAmountInTC,
@Semantics.amount.currencyCode: 'TransactionCurrency'
CAClearingDeductionAmountInTC,
CACashDiscountDueDate,
CACashDiscountRate,
@Semantics.amount.currencyCode: 'TransactionCurrency'
CAEligibleAmountForCshDiscount,
@ObjectModel.foreignKey.association: '_TaxCode'
TaxCode,
CASupplementaryTaxCode,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
CATaxAmountInLocalCurrency,
@Semantics.amount.currencyCode: 'TransactionCurrency'
CATaxAmountInTransCurrency,
@Semantics.amount.currencyCode: 'AdditionalCurrency1'
CATaxAmountInSecondCurrency,
@Semantics.amount.currencyCode: 'AdditionalCurrency2'
CATaxAmountInThirdCurrency,
CADownPaymentTaxAccount,
CADownPaymentOffsetTaxAccount,
@ObjectModel.foreignKey.association: '_TaxJurisdiction'
TaxJurisdiction,
CATaxDate,
WithholdingTaxCode,
CAWithholdingTaxSupplement,
CAWithholdingTaxCategory,
@Semantics.amount.currencyCode: 'TransactionCurrency'
CABaseAmountForWithholdingTax,
@Semantics.amount.currencyCode: 'TransactionCurrency'
CAWithholdingTaxAmount,
CAWithholdingTaxPercentage,
WithholdingTaxCertificate,
CAOtherTaxCode,
CAGroupingCodeForTaxItems,
@Semantics.amount.currencyCode: 'CompanyCodeCurrency'
CATaxPortionInLocalCurrency,
@Semantics.amount.currencyCode: 'TransactionCurrency'
CATaxPortionInTransCurrency,
CATaxIsCalculatedExternally,
CATaxAmountIsSetFromExternal,
TaxCountry,
TransToTaxCntryCrcyCnvrsnFctr,
CAPaymentMethod,
CAPaymentCompanyCode,
CAGroupingForPayment,
CAPaymentSpecificationCategory,
CAClearingStatus,
CAClearingDate,
CAClearingDocumentNumber,
CAPostingDateOfClearingDoc,
CAClearingReason,
CAClearingCurrency,
@Semantics.amount.currencyCode: 'CAClearingCurrency'
CAClearingAmountInClearingCrcy,
@Semantics.amount.currencyCode: 'CAClearingCurrency'
CATaxAmountInClearingCrcy,
@Semantics.amount.currencyCode: 'CAClearingCurrency'
CACashDiscAmountInClearingCrcy,
CAValueDateForClearing,
CAClearingRestrictionCode,
CAClearingPostingIsReset,
CAItemIsWithdrawn,
CAItemIsExcludedFromDunning,
CADunningProcedure,
CAGrpgCodeForTransfToCollAgcy,
CAIsIncludedInCollectionCase,
@ObjectModel.foreignKey.association: '_CashPlanningGroup'
CashPlanningGroup,
PlanningLevel,
CAAdditionalDaysForCashMgmt,
@Semantics.amount.currencyCode: 'TransactionCurrency'
PlannedAmtInTransactionCrcy,
CAAltvBPForPayment,
CABankOfAltvBPForPayment,
CAAddressOfAltvBPForPayment,
CACardOfAltvBPForPayment,
SEPAMandateCAInternalID,
CAGLPostingCurrency,
@Semantics.amount.currencyCode: 'CAGLPostingCurrency'
CAGLPostingAmount,
@Semantics.amount.currencyCode: 'CAGLPostingCurrency'
CAGLPostingTaxAmount,
CAIsSeparateLineItemInGL,
CAIsCashFlowItem,
CACashFlowAccount,
CACashFlowCompanyCode,
CAPaymentPreNotificationCode,
CASEPAPreNotificationNumber,
CASEPAPreNotifOriginCode,
CASEPAPreNotifExecutionDate,
CASEPAPreNotificationRqmtCode,
CARevenueDistrFinalRecipient,
CARevenueDistrCurrentStatus,
CARevenueDistrLastStatus,
CACurrentFactoringStatusOfRbl,
CAFactoringCheckStsForClrgInfo,
CAFactoringItem,
ControllingArea,
ChartOfAccounts,
Country,
@ObjectModel.foreignKey.association: '_TaxCalculationProcedure'
_Country.TaxCalculationProcedure as TaxCalculationProcedure,
concat(CADocumentNumber, concat(CARepetitionItemNumber,
concat (CABPItemNumber, CASubItemNumber))) as CAConcatenatedDocumentNumber,
/* Associations */
// own associations
_AdditionalCurrencyRoles._AdditionalCrcyRole1Currency._Currency as _AdditionalCurrency1,
_AdditionalCurrencyRoles._AdditionalCrcyRole2Currency._Currency as _AdditionalCurrency2,
_CashPlanningGroup,
_TaxCalculationProcedure,
_TaxCode,
_TaxJurisdiction,
// associations from I_CADocumentBPItem
_BusinessArea,
_BusinessPartner,
_CAAccountAssignmentCategory,
_CAAccountDeterminationCode,
_CAApplicationArea,
_CAClearingDocument,
_CAClearingReason,
_CAClearingRestrictionCode,
_CAClearingStatus,
_CADbtflOrValueAdjmtCode,
_CADocument,
_CADocumentType,
_CADunningProcedure,
_CAFactoringClrgCheckStatus,
_CAFactoringReceivableStatus,
_CAInterestCode,
_CAInternalPostingReasonCode,
_CAMainTransaction,
_CANegativePostingControlCode,
_CAOriginDocument,
_CAOriglStatisticalItemCode,
_CAOtherTaxCode,
_CAPartnerSettlementStatus,
_CAPaymentMethod,
_CAPaytPreNotificationCode,
_CAPaytSpecificationCategory,
_CAPeriodCode,
_CAProviderContract,
_CARevenueDistrCurrentStatus,
_CARevenueDistrLastStatus,
_CARoundingItemCode,
_CASEPAPreNotificationRqmtCode,
_CASEPAPreNotifOriginCode,
_CashFlowAccount,
_CashFlowCompanyCode,
_CAStatisticalItemCode,
_CASubApplication,
_CASubstituteDocumentCategory,
_CASubstituteDocument,
_CASubTransaction,
_CAWithholdingTaxCategory,
_CAWithholdingTaxSupplement,
_CAWorkflowCheckProcess,
_CAWorkflowCheckReason,
_ClearingCurrency,
_CollvBillsAltvContractAccount,
_CompanyCode,
_CompanyCodeCurrency,
_ContractAccount,
_ContractAccountPartner,
_ControllingArea,
_ChartOfAccounts,
_Country,
_Division,
_DownPaymentOffsetTaxAccount,
_DownPaymentTaxAccount,
_GLPostingCurrency,
_PartnerCompany,
_PaytAltvBusinessPartner,
_PlanningLevel,
_PaymentCompanyCode,
_ProfitCenter,
_ReceivingCountry,
_ReconciliationAccount,
_RevnDistrFnlRcpntContrAccount,
_Segment,
_TaxCountry,
_TransactionCurrency,
_WithholdingTaxCode,
_CADocumentOriginCode
}