C_CABillgDocHeader

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #REQUIRED,
  privilegedAssociations: [ '_CAInvcgUserContact' ]
}
@EndUserText.label: 'Abrechnungsbelegkopf anzeigen'
@Consumption.semanticObject: 'CABillgDocument'
@Search.searchable: true
@Metadata.allowExtensions: true

@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory: #XL,
    dataClass: #MIXED
  },
  semanticKey: [ 'CABillgDocument' ],
  representativeKey: 'CABillgDocument'
}
@OData.entitySet.name: 'C_CABillgDocDisp'
@OData.entityType.name: 'C_CABillgDocDispType'

@VDM: {
  viewType: #CONSUMPTION,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
}

define root view entity C_CABillgDocHeader
  provider contract transactional_query
  as projection on R_CABillgDocumentTP as _CABillgDocHeader

  // UI FACETS

  association [1..*] to C_CABillgDocItem           as _CABillgDocItem            on $projection.CABillgDocument = _CABillgDocItem.CABillgDocument
  association [1..*] to C_CABillgDocSource         as _CABillgDocSource          on $projection.CABillgDocument = _CABillgDocSource.CABillgDocument
  association [1..*] to C_CABillgDocTax            as _CABillgDocTax             on $projection.CABillgDocument = _CABillgDocTax.CABillgDocument
  association [1..*] to C_CABillgDocPayment        as _CABillgDocPayment         on $projection.CABillgDocument = _CABillgDocPayment.CABillgDocument
  association [1..*] to C_CABillgDocAdditional     as _CABillgDocAdditional      on $projection.CABillgDocument = _CABillgDocAdditional.CABillgDocument
  association [1..*] to C_CABillgDocReference      as _CABillgDocReference       on $projection.CABillgDocument = _CABillgDocReference.CABillgDocument
  association [1..*] to C_CABillgDocInvcgDocSource as _CABillgDocInvcgDocSource  on $projection.CABillgDocument = _CABillgDocInvcgDocSource.CABillgDocument

  // required for in-app-navigation

  association [0..1] to C_CABillgDocHeader         as _CABillgReversedDocument   on $projection.CABillgReversedDocument = _CABillgReversedDocument.CABillgDocument
  association [0..1] to C_CABillgDocHeader         as _CABillgReversalDocument   on $projection.CABillgReversalDocument = _CABillgReversalDocument.CABillgDocument
  association [0..1] to C_CABillgDocHeader         as _CABillgAdjustedDocument   on $projection.CABillgAdjustedDocument = _CABillgAdjustedDocument.CABillgDocument
  association [0..1] to C_CABillgDocHeader         as _CABillgAdjustmentDocument on $projection.CABillgAdjustmentDocument = _CABillgAdjustmentDocument.CABillgDocument

{

          //BILLDOCNO

  key     _CABillgDocHeader.CABillgDocument,

          //INVDOCNO

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
          CAInvoicingDocument,
          
          //EXT_INVDOCNO

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
  virtual CAInvcgDocExternal             : ext_invdocno_kk,
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
  virtual CAInvcgDocExternalIsHidden     : boolean,
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
  virtual CAInvcgDocExternalSemObj       : semantic_object_kk,
          
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
  virtual UICT_CABillgDocument : abap.char(50),

          //GPART

          @ObjectModel.filter.enabled: false
          _CAInvcgBPAddress.BusinessPartnerFullName,

          @ObjectModel.filter.enabled: false
          _CAInvcgBPAddress.StreetName,

          @ObjectModel.filter.enabled: false
          _CAInvcgBPAddress.AddressCityName,

          @ObjectModel.filter.enabled: false
          _CAInvcgBPAddress.CountryName,

          @ObjectModel.text.element: ['BusinessPartnerFullName']
          _CABillgDocHeader.BusinessPartner,

          //VKONT

          @ObjectModel.text.element: ['ContractAccountName']
          _CABillgDocHeader.ContractAccount,

          @ObjectModel.filter.enabled: false
          _ContractAccountHeader.ContractAccountName,

          //VTREF

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
  virtual CAContract                     : vtref_kk,

          //bill_type

          @ObjectModel.text.element: ['CABillgTypeText']
          _CABillgDocHeader.CABillgType,

          _CABillgType._CABillgTypeText.CABillgTypeText                                         : localized,

          //date_from

          _CABillgDocHeader.CABillgDocPeriodStartDate,

          //date_to

          _CABillgDocHeader.CABillgDocPeriodEndDate,

          //CRDATE - only ui.hidden, as it is needed for change documents

          _CABillgDocHeader.CABillgDocCreationDate,

          //crtime

          _CABillgDocHeader.CABillgDocCreationTime,

          //combined field of crdate and crtime

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
          @ObjectModel.sort.transformedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_FILTER_DATETIME'
  virtual CABillgDocCreationDateTime     : billdoc_crtsmp_kk,

          //revreason

          @ObjectModel.text.element: [ 'CABillgDocReversalReasonText']
          _CABillgDocHeader.CABillgDocumentReversalReason,

          _CABillgDocReversalReason._CABillgDocReversalReasonText.CABillgDocReversalReasonText  : localized,

          //simulated

          _CABillgDocHeader.CABillgIsDocumentSimulated,

          //refdocno

          _CABillgDocHeader.CABillgDocumentExternal,

          //log_system

          _CABillgDocHeader.LogicalSystem,

          //applk

          _CABillgDocHeader.CAApplicationArea,

          //srcprocess

          @ObjectModel.text.element: ['CABillgDocOriginProcessText']
          _CABillgDocHeader.CABillgDocOriginProcess,

          _CABillgDocOriginProcess._CABillgDocOriginProcessText.CABillgDocOriginProcessText     : localized,

          //srcdoctype

          @ObjectModel.text.element: ['CAInvcgSourceDocTypeText']
          _CABillgDocHeader.CAInvcgSourceDocumentType,

          _CAInvcgSourceDocType._CAInvcgSourceDocTypeText.CAInvcgSourceDocTypeText              : localized,

          //techdoctype

          @ObjectModel.text.element: ['CAInvcgDocTechDocTypeText' ]
          _CABillgDocHeader.CAInvcgTechnicalDocumentType,

          _CAInvcgDocTechDocType._CAInvcgDocTechDocTypeText.CAInvcgDocTechDocTypeText           : localized,

          //doctype

          @ObjectModel.text.element: ['CAInvcgDocumentTypeText' ]
          _CABillgDocHeader.CAInvcgDocumentType,

          _CAInvcgDocumentType._CAInvcgDocumentTypeText.CAInvcgDocumentTypeText                 : localized,

          //targprocess

          @ObjectModel.text.element:  [ 'CAInvcgTargetProcText' ]
          _CABillgDocHeader.CAInvcgTargetProcess,

          _CAInvcgTargetProc._CAInvcgTargetProcText.CAInvcgTargetProcText                       : localized,

          //mdcat

          @ObjectModel.text.element: [ 'CAInvcgMasterDataTypeText' ]
          _CABillgDocHeader.CAInvcgMasterDataType,

          _CAInvcgMasterDataType._CAInvcgMasterDataTypeText.CAInvcgMasterDataTypeText           : localized,

          //gpart_inv

          _CABillgDocHeader.CAInvcgAltvBusinessPartner,

          //vkont_inv

          _CABillgDocHeader.CAInvcgAltvContractAccount,

          //bill_basedate

          _CABillgDocHeader.CABillgBaseDate,

          //bill_curr

          _CABillgDocHeader.CABillgCurrency,

          //inv_curr

          _CABillgDocHeader.CAInvcgCurrency,

          //tax_det_type

          @ObjectModel.text.element: [ 'CATaxDetnTypeText' ]
          _CABillgDocHeader.CATaxDetnType,

          _CATaxDetnType._CATaxDetnTypeText.CATaxDetnTypeText                                   : localized,

          //tax_date_type

          @ObjectModel.text.element: [ 'CATaxDateTypeText' ]
          _CABillgDocHeader.CATaxDateType,

          _CATaxDateType._CATaxDateTypeText.CATaxDateTypeText                                   : localized,

          //inv_category

          @ObjectModel.text.element: [ 'CAInvcgCategoryText' ]
          _CABillgDocHeader.CAInvcgCategory,

          _CAInvcgCategory._CAInvcgCategoryText.CAInvcgCategoryText                             : localized,

          //separate_inv

          @ObjectModel.text.element: [ 'CAInvcgControlOfInvcgUnitTxt' ]
          _CABillgDocHeader.CAInvcgControlOfInvoicingUnit,

          _CAInvcgControlOfInvcgUnit._CAInvcgControlOfInvcgUnitTxt.CAInvcgControlOfInvcgUnitTxt : localized,

          //invoice_first

          _CABillgDocHeader.CAInvcgFirstDate,

          //reversaldoc

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
          _CABillgDocHeader.CABillgReversalDocument,

          //reverseddoc

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
          _CABillgDocHeader.CABillgReversedDocument,

          //adjustmentdoc

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
          _CABillgDocHeader.CABillgAdjustmentDocument,

          //adjusteddoc

          @ObjectModel.filter.transformedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
          _CABillgDocHeader.CABillgAdjustedDocument,

          //corrcat

          @ObjectModel.text.element: [ 'CAInvcgCorrectionCatText']
          _CABillgDocHeader.CAInvcgCorrectionCategory,

          _CAInvcgCorrectionCat._CAInvcgCorrectionCatText.CAInvcgCorrectionCatText              : localized,

          //trigdeleted

          _CABillgDocHeader.CaInvcgIsOrderDeleted,

          //xinfbill

          @ObjectModel.text.element: [ 'CABillgAdditionalInvoiceText']
          _CABillgDocHeader.CABillgHasAdditionalInvoice,

          _CABillgExistsAddInvcg._CABillgExistsAddInvcgText.CABillgAdditionalInvoiceText        : localized,

          //xbillac

          _CABillgDocHeader.CAInvcgIsAccrualPostingRlvt,

          //invlock

          @ObjectModel.text.element:            ['CABillgLockedForInvcgText']
          _CABillgDocHeader.CABillgLockedForInvoicing,

          _CABillgLockedForInvcg._CABillgLockedForInvcgText.CABillgLockedForInvcgText           : localized,

          //add_group

          _CABillgDocHeader.CABillgGrpgOfAdditionalItems,

          //xinvbill_x

          _CABillgDocHeader.CABillgDocHasRefObjects,

          //recnum

          _CABillgDocHeader.CABillgDocumentNumberOfItems,

          //bit_number

          _CABillgDocHeader.CABllbleItmNumber,

          //crname

          _CABillgDocHeader.CreatedByUser,

          //billrunno

          _CABillgDocHeader.CABillgDocInternalNumber,

          //bill_process

          @ObjectModel.text.element: [ 'CABillgProcessText']
          _CABillgDocHeader.CABillgProcess,

          _CABillgProcess._CABillgProcessText.CABillgProcessText                                : localized,

          //prepaid_incl

          _CABillgDocHeader.CABillgDocHasPrepaidItems,

          //pprefill_incl

          _CABillgDocHeader.CABillgDocHasRefillItems,

          //revrec_incl

          _CABillgDocHeader.CABillgDocHasRevnRecgnItems,

          //ptsrl

          _CABillgDocHeader.CAPartnerSettlementRule,

          //invstatus

          @ObjectModel.text.element: [ 'CABillgDocumentInvcgStatusText']
          _CABillgDocHeader.CABillgDocumentInvcgStatus,

          _CABillgDocInvcgStatus._CABillgDocInvcgStatusText.CABillgDocumentInvcgStatusText      : localized,

          //invcrdate

          _CABillgDocHeader.CAInvcgCreationDate,

          //keypp

          _CABillgDocHeader.CASubAreaForParallelization,

          //altmd_orig_incl

          _CABillgDocHeader.CAAltvMDOriginalIsIncluded,

          // Action control: Invoicing

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
  virtual CABillgDocumentInvcgIsEnabled  : xfeld,

          // Action control: Reversal

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
  virtual CABillgDocReversalIsEnabled    : xfeld,

          // Action control: Create Clarification Case

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
  virtual CAInvcgClrfctnCreateIsEnabled  : xfeld,


          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
  virtual CAInvcgClarificationIsExisting : xfeld,

          // Make association public

          _CABillgDocItem,
          _CABillgDocTax,
          _CABillgDocSource,
          _CABillgDocPayment,
          _CABillgDocAdditional,
          _CABillgDocReference,
          @ObjectModel.filter.enabled: false
          _CABillgDocInvcgDocSource,

          // Foreign Key Associations

          _ContractAccountPartner,
          _BusinessPartner,
          _ContractAccountHeader,
          _CAInvcgAltvBusinessPartner,
          _CAInvcgAltvContractAccount,
          _CABillgReversalDocument,
          _CABillgReversedDocument,
          _CABillgAdjustedDocument,
          _CABillgAdjustmentDocument,
          _CAApplicationArea,
          _CABillgCurrency,
          _CAInvcgCurrency,
          _CABillgDocOriginProcess,
          _CAInvcgSourceDocType,
          _CAInvcgTargetProc,
          _CAInvcgCategory,
          _CABillgProcess,
          _CABillgType,
          _CAInvcgDocTechDocType,
          _CAInvcgMasterDataType,
          _CATaxDetnType,
          _CATaxDateType,
          _CAInvcgDocumentType,
          _CAInvcgControlOfInvcgUnit,
          _CAInvcgCorrectionCat,
          _CABillgExistsAddInvcg,
          _CABillgLockedForInvcg,
          _CABillgDocInvcgStatus,
          _CABillgDocReversalReason,
          _CAInvcgUserContact,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
  virtual CAInvcgSourceDocumentNumber    : srcdocno_kk,

          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_BILLDOC_DSP'
  virtual CAInvcgSourceDocumentCat       : srcdoccat_kk
}