C_BankRelationshipDocTP

DDL: C_BANKRELATIONSHIPDOCTP Type: view_entity CONSUMPTION Package: FCLM_BRM_DOC

Bank Relationship Document

C_BankRelationshipDocTP is a Consumption CDS View that provides data about "Bank Relationship Document" in SAP S/4HANA. It reads from 1 data source (R_BankRelationshipDocTP) and exposes 11 fields with key field BankRelationshipDocumentUUID. It is exposed through 1 OData service (UI_BANKRELATIONSHIPDOC). Part of development package FCLM_BRM_DOC.

1 data source(s) Exposed by 1 service(s) 11 fields

Data Sources (1)

SourceAliasJoin Type
R_BankRelationshipDocTP R_BankRelationshipDocTP projection

Annotations (9)

NameValueLevelField
EndUserText.label Bank Relationship Document view
AccessControl.authorizationCheck #MANDATORY view
Metadata.allowExtensions true view
Search.searchable true view
VDM.viewType #CONSUMPTION view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MASTER view

OData Services (1)

ServiceBindingVersionContractRelease
UI_BANKRELATIONSHIPDOC UI_BANKRELATIONSHIPDOC_O4 V4 C1 NOT_RELEASED

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY BankRelationshipDocumentUUID BankRelationshipDocumentUUID
BankRelationshipDocumentID BankRelationshipDocumentID Bank Relationship Document ID
BankRelationshipDocumentDesc BankRelationshipDocumentDesc Description
BkRelshpDocAuthorizationGroup BkRelshpDocAuthorizationGroup Authorization Group
LastChangeDateTime LastChangeDateTime Last Changed On/At
CreatedByUser CreatedByUser Created By
CreatedByUserDescription _CreatedBy FullName
CreationDateTime CreationDateTime Created On/At
LastChangedByUser LastChangedByUser Last Changed By
LastChangedByUserDescription _LastChangedBy FullName
LocalLastChangeDateTime LocalLastChangeDateTime Last Changed On/At 
@EndUserText.label: 'Bank Relationship Document'
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.allowExtensions: true
@Search.searchable: true
@VDM : { viewType: #CONSUMPTION,
        usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ] }
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
    semanticKey: [ 'BankRelationshipDocumentID' ],
    usageType: {
        serviceQuality: #C,
        sizeCategory:   #S,
        dataClass:      #MASTER
    }
}
define root view entity C_BankRelationshipDocTP
  provider contract transactional_query
  as projection on R_BankRelationshipDocTP
{
  key BankRelationshipDocumentUUID,
  
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @EndUserText.label: 'Bank Relationship Document ID'
      BankRelationshipDocumentID,
      
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #MEDIUM
      @EndUserText.label: 'Description'
      BankRelationshipDocumentDesc,
      @ObjectModel.text.element: ['BkRelshpDocAuthznGroupName']
      @Consumption.valueHelpDefinition: [{ entity.name: 'I_BkRelshpDocAuthznGroupVH',
                                           entity.element: 'BkRelshpDocAuthorizationGroup' }]
      @EndUserText.label: 'Authorization Group'                                            
      BkRelshpDocAuthorizationGroup, 
      _BkRelshpDocAuthznGroupText.BkRelshpDocAuthznGroupName     as BkRelshpDocAuthznGroupName   : localized,
      @Semantics.systemDateTime.lastChangedAt: true
      @EndUserText.label: 'Last Changed On/At'
      LastChangeDateTime,
      @Semantics.user.createdBy: true
      @EndUserText.label: 'Created By'
      @ObjectModel.text.element: ['CreatedByUserDescription']
      CreatedByUser,
      
      _CreatedBy.FullName                                     as CreatedByUserDescription,      
      @Semantics.systemDateTime.createdAt: true
      @EndUserText.label: 'Created On/At'
      CreationDateTime,      
      @Semantics.user.lastChangedBy: true
      @EndUserText.label: 'Last Changed By'
      @ObjectModel.text.element: ['LastChangedByUserDescription']      
      LastChangedByUser,
      
      _LastChangedBy.FullName                                 as LastChangedByUserDescription,
      @Semantics.systemDateTime.localInstanceLastChangedAt: true
      @EndUserText.label: 'Last Changed On/At'
      LocalLastChangeDateTime,
      
      _DocBankAccountSelection : redirected to composition child C_BkRelshpDocAcctSelectionTP,
      _DocBankAccount          : redirected to composition child C_BkRelshpDocAccountTP
}

Learn More