R_BANKRELATIONSHIPDOCTP

CDS View

Bank Relationship Document

R_BANKRELATIONSHIPDOCTP is a CDS View in S/4HANA. Bank Relationship Document. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_BankRelationshipDocTP view_entity projection CONSUMPTION Bank Relationship Document 
@AccessControl.authorizationCheck:#MANDATORY
@EndUserText.label: 'Bank Relationship Document'

@ObjectModel: { usageType: { serviceQuality: #B,
                             sizeCategory:   #S,
                             dataClass:      #MASTER },
                             sapObjectNodeType.name: 'BankRelationshipDocument'}

@VDM:         { usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ],
                viewType:  #TRANSACTIONAL,
                lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
define root view entity R_BankRelationshipDocTP as select from I_BankRelationshipDocument
composition [0..*] of R_BkRelshpDocAcctSelectionTP  as _DocBankAccountSelection
composition [0..*] of R_BkRelshpDocAccountTP        as _DocBankAccount
association [0..*] to I_BkRelshpDocAuthznGroupText   as _BkRelshpDocAuthznGroupText   on $projection.BkRelshpDocAuthorizationGroup = _BkRelshpDocAuthznGroupText.BkRelshpDocAuthorizationGroup
{
  key BankRelationshipDocumentUUID,
  BankRelationshipDocumentID,
  BankRelationshipDocumentDesc,
  BkRelshpDocAuthorizationGroup,
  @Semantics.user.createdBy: true
  CreatedByUser,
  @Semantics.systemDateTime.createdAt: true
  CreationDateTime,
  @Semantics.user.lastChangedBy: true  
  LastChangedByUser,
  //local ETag field --> OData ETag  

  @Semantics.systemDateTime.localInstanceLastChangedAt:true
  LocalLastChangeDateTime,
  //total ETag field

  @Semantics.systemDateTime.lastChangedAt: true  
  LastChangeDateTime,
  @UI.hidden: true
  cast( ' ' as xfeld preserving type )  as BkRelshpDocAttchIsChgd,  
  IsMarkedForDeletion,
  
  //Associations

  _DocBankAccountSelection,
  _DocBankAccount,
  _BkRelshpDocAuthznGroupText,
  _CreatedBy,      
  _LastChangedBy
}

Learn More