A_VarCnfContextInstanceSimln

DDL: A_VARCNFCONTEXTINSTANCESIMLN Type: view_entity CONSUMPTION Package: VCH_RAP_CFG

Var Cnf Context Instance Simln

A_VarCnfContextInstanceSimln is a Consumption CDS View that provides data about "Var Cnf Context Instance Simln" in SAP S/4HANA. It reads from 1 data source (R_VarConfigurationInstanceTP) and exposes 12 fields with key fields VarConfigurationBusObjectKey, VarConfigurationBusObjectType, VarConfignInstceInternalID. It has 1 association to related views. It is exposed through 1 OData service (API_SALESORDERSIMULATION). Part of development package VCH_RAP_CFG.

1 data source(s) Exposed by 1 service(s) 12 fields

Data Sources (1)

SourceAliasJoin Type
R_VarConfigurationInstanceTP R_VarConfigurationInstanceTP from

Associations (1)

CardinalityTargetAliasCondition
[0..*] A_VarCnfContextCharcSimln _Characteristic

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Var Cnf Context Instance Simln view
Metadata.ignorePropagatedAnnotations true view
OData.entityType.name VarCnfContextInstanceSimln_Type view
ObjectModel.query.implementedBy ABAP:CL_VCR_SIMULATION_QUERY view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.lifecycle.contract.type #PUBLIC_REMOTE_API view
VDM.viewType #CONSUMPTION view

OData Services (1)

ServiceBindingVersionContractRelease
API_SALESORDERSIMULATION API_SALESORDERSIMULATION V4 C2 C1

Fields (12)

KeyFieldSource TableSource FieldDescription
KEY VarConfigurationBusObjectKey VarConfigurationBusObjectKey
KEY VarConfigurationBusObjectType VarConfigurationBusObjectType
KEY VarConfignInstceInternalID VarConfignInstceInternalID
VarConfignParInstceInternalID VarConfignParInstceInternalID
Product Product
IdentifierBOMItem IdentifierBOMItem
BillOfMaterialItemNumber BillOfMaterialItemNumber
VariantConfigurationQuantity VariantConfigurationQuantity
VarConfignQuantityUnit VarConfignQuantityUnit
VarConfignQuantityISOUnit VarConfignQuantityISOUnit
_VariantConfiguration _VariantConfiguration
_Characteristic _Characteristic 
@AccessControl.authorizationCheck: #NOT_REQUIRED

@EndUserText.label: 'Var Cnf Context Instance Simln'

@Metadata.ignorePropagatedAnnotations: true

//@OData.containment.accessByNavigationOnly: true

@OData.entityType.name: 'VarCnfContextInstanceSimln_Type'

@ObjectModel.query.implementedBy: 'ABAP:CL_VCR_SIMULATION_QUERY'
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #S, dataClass: #TRANSACTIONAL }

@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@VDM.viewType: #CONSUMPTION

define view entity A_VarCnfContextInstanceSimln
  as select from R_VarConfigurationInstanceTP

  association to parent A_VarCnfContextSimulation as _VariantConfiguration
    on  $projection.VarConfigurationBusObjectType = _VariantConfiguration.VarConfigurationBusObjectType
    and $projection.VarConfigurationBusObjectKey  = _VariantConfiguration.VarConfigurationBusObjectKey

  composition [0..*] of A_VarCnfContextCharcSimln   as _Characteristic

{
  key VarConfigurationBusObjectKey,
  key VarConfigurationBusObjectType,
  key VarConfignInstceInternalID,

      VarConfignParInstceInternalID,

      Product,

      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'Product'
      cast('' as rap_null_value_indicator preserving type) as ProductIsNull,

      IdentifierBOMItem,

      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'IdentifierBOMItem'
      cast('' as rap_null_value_indicator preserving type) as IdentifierBOMItemIsNull,

      @Feature: 'VCH_VCR_INSTANCE_SOFT_MATCHING'
      BillOfMaterialItemNumber,
          
      @Feature: 'VCH_VCR_INSTANCE_SOFT_MATCHING'
      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'BillOfMaterialItemNumber'
      cast('' as rap_null_value_indicator preserving type ) as BillOfMaterialItemNumberIsNull,

      @Semantics.quantity: { unitOfMeasure: 'VarConfignQuantityUnit',
                             unitOfMeasureSapCode: 'VarConfignQuantityUnit',
                             unitOfMeasureIsoCode: 'VarConfignQuantityISOUnit' }
      VariantConfigurationQuantity,

      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'VariantConfigurationQuantity'
      cast('' as rap_null_value_indicator preserving type) as VariantConfignQuantityIsNull,

      VarConfignQuantityUnit,

      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'VarConfignQuantityUnit'
      cast('' as rap_null_value_indicator preserving type) as VarConfignQuantityUnitIsNull,

      VarConfignQuantityISOUnit,

      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'VarConfignQuantityISOUnit'
      cast('' as rap_null_value_indicator preserving type) as VarConfignQtyISOUnitIsNull,

      /* Associations */
      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      _VariantConfiguration,

//      @OData.containment.containsTarget: true

      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      _Characteristic
}

Learn More