A_VarCnfContextCharcSimln

DDL: A_VARCNFCONTEXTCHARCSIMLN Type: view_entity CONSUMPTION Package: VCH_RAP_CFG

Var Cnf Context Characteristic Simln

A_VarCnfContextCharcSimln is a Consumption CDS View that provides data about "Var Cnf Context Characteristic Simln" in SAP S/4HANA. It reads from 1 data source (R_VarConfignCharacteristicTP) and exposes 17 fields with key fields VarConfigurationBusObjectKey, VarConfigurationBusObjectType, VarConfignInstceInternalID, Characteristic. It has 1 association to related views. It is exposed through 1 OData service (API_SALESORDERSIMULATION). Part of development package VCH_RAP_CFG.

1 data source(s) Exposed by 1 service(s) 17 fields

Data Sources (1)

SourceAliasJoin Type
R_VarConfignCharacteristicTP R_VarConfignCharacteristicTP from

Associations (1)

CardinalityTargetAliasCondition
[0..*] A_VarCnfContextAssgdValSimln _AssignedValue

Annotations (10)

NameValueLevelField
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Var Cnf Context Characteristic Simln view
Metadata.ignorePropagatedAnnotations true view
OData.entityType.name VarCnfContextCharcSimln_Type view
ObjectModel.query.implementedBy ABAP:CL_VCR_SIMULATION_QUERY view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
VDM.lifecycle.contract.type #PUBLIC_REMOTE_API view
VDM.viewType #CONSUMPTION view

OData Services (1)

ServiceBindingVersionContractRelease
API_SALESORDERSIMULATION API_SALESORDERSIMULATION V4 C2 C1

Fields (17)

KeyFieldSource TableSource FieldDescription
KEY VarConfigurationBusObjectKey VarConfigurationBusObjectKey
KEY VarConfigurationBusObjectType VarConfigurationBusObjectType
KEY VarConfignInstceInternalID VarConfignInstceInternalID
KEY Characteristic Characteristic
CharcDataType CharcDataType
CharcTemplate CharcTemplate
Currency Currency
CharcValueUnit CharcValueUnit
VarCnfCharcISOUnit VarCnfCharcISOUnit
IsReadOnly IsReadOnly
EntryIsRequired EntryIsRequired
CharcIsHidden CharcIsHidden
AdditionalValueIsAllowed AdditionalValueIsAllowed
MultipleValuesAreAllowed MultipleValuesAreAllowed
_VariantConfiguration _VariantConfiguration
_Instance _Instance
_AssignedValue _AssignedValue 
@AccessControl.authorizationCheck: #NOT_REQUIRED

@EndUserText.label: 'Var Cnf Context Characteristic Simln'

@Metadata.ignorePropagatedAnnotations: true

//@OData.containment.accessByNavigationOnly: true

@OData.entityType.name: 'VarCnfContextCharcSimln_Type'

@ObjectModel.query.implementedBy: 'ABAP:CL_VCR_SIMULATION_QUERY'
@ObjectModel.usageType: { serviceQuality: #C, sizeCategory: #S, dataClass: #TRANSACTIONAL }

@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@VDM.usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ]
@VDM.viewType: #CONSUMPTION

define view entity A_VarCnfContextCharcSimln
  as select from R_VarConfignCharacteristicTP

  association to parent A_VarCnfContextInstanceSimln as _Instance
    on  $projection.VarConfigurationBusObjectType = _Instance.VarConfigurationBusObjectType
    and $projection.VarConfigurationBusObjectKey  = _Instance.VarConfigurationBusObjectKey
    and $projection.VarConfignInstceInternalID    = _Instance.VarConfignInstceInternalID

  association to        A_VarCnfContextSimulation    as _VariantConfiguration
    on  $projection.VarConfigurationBusObjectType = _VariantConfiguration.VarConfigurationBusObjectType
    and $projection.VarConfigurationBusObjectKey  = _VariantConfiguration.VarConfigurationBusObjectKey

  composition [0..*] of A_VarCnfContextAssgdValSimln as _AssignedValue

{
  key VarConfigurationBusObjectKey,
  key VarConfigurationBusObjectType,
  key VarConfignInstceInternalID,
  key Characteristic,

      CharcDataType,
      CharcTemplate,

      Currency,

      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'Currency'
      cast('' as rap_null_value_indicator preserving type) as CurrencyIsNull,

      CharcValueUnit,

      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'CharcValueUnit'
      cast('' as rap_null_value_indicator preserving type) as CharcValueUnitIsNull,

      VarCnfCharcISOUnit,

      @Consumption.hidden: true
      @Semantics.nullValueIndicatorFor: 'VarCnfCharcISOUnit'
      cast('' as rap_null_value_indicator preserving type) as VarCnfCharcISOUnitIsNull,

      IsReadOnly,
      EntryIsRequired,
      CharcIsHidden,
      AdditionalValueIsAllowed,
      MultipleValuesAreAllowed,

      /* Associations */
      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      _VariantConfiguration,

      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      _Instance,

//      @OData.containment.containsTarget: true

      @ObjectModel.filter.enabled: false
      @ObjectModel.sort.enabled: false
      _AssignedValue
}

Learn More