A_ServiceQuotationItem

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Service Quotation Item'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASRVQTANITEM',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true
@AbapCatalog.preserveKey:true

define view A_ServiceQuotationItem
  as select from I_ServiceDocumentItemEnhcd as ServiceQuotationItem

  association [0..*] to A_ServiceQtanItemRefObject     as _ReferenceObject        on  $projection.ServiceQuotation     = _ReferenceObject.ServiceQuotation
                                                                                  and $projection.ServiceQuotationItem = _ReferenceObject.ServiceQuotationItem

  association [0..*] to A_ServiceQuotationItemText     as _Text                   on  $projection.ServiceQuotation     = _Text.ServiceQuotation
                                                                                  and $projection.ServiceQuotationItem = _Text.ServiceQuotationItem

  association [0..*] to A_ServiceQtanItemPriceElement  as _PricingElement         on  $projection.ServiceQuotation     = _PricingElement.ServiceQuotation
                                                                                  and $projection.ServiceQuotationItem = _PricingElement.ServiceQuotationItem

  association [1]    to A_ServiceQuotation             as _ServiceQuotation       on  $projection.ServiceQuotation = _ServiceQuotation.ServiceQuotation

  association [0..1] to I_ServiceDocumentItemSuccssr_2 as _RefServiceOrderItem    on  ServiceQuotationItem.ServiceDocumentItemCharUUID    = _RefServiceOrderItem.ServiceDocumentItemCharUUID
                                                                                  and _RefServiceOrderItem.ServiceDocItmSuccssrBusObjType = ServiceQuotationItem.ServiceDocumentItemObjectType

  association [0..1] to A_ServiceOrdItmRefSrvcContr    as _RefServiceContractItem on  $projection.ServiceQuotationItemUUID = _RefServiceContractItem.ServiceOrderItemUUID

  association [0..1] to I_CustMgmtExtRefID             as _CustMgmtExtRef         on  $projection.ServiceQuotation         = _CustMgmtExtRef.CustMgmtDocument
                                                                                  and _CustMgmtExtRef.CustMgmtObjectType   = ServiceObjectType
                                                                                  and $projection.ServiceQuotationItem     = _CustMgmtExtRef.CustMgmtDocumentItem
                                                                                  and _CustMgmtExtRef.CustMgmtExtRefIDType = '0010'

  association [0..1] to I_StatusObjectUUIDStatus       as _SrvcDocSystemStatus    on  $projection.ServiceQuotationItemUUID = _SrvcDocSystemStatus.StatusObjectUUID
                                                                                  and (

                                                                                     _SrvcDocSystemStatus.StatusCode       = 'I1005' // Rejected or accepted

                                                                                   )
                                                                                  and _SrvcDocSystemStatus.StatusIsActive  = 'X'
  //  Extensibility

  association [0..1] to E_ServiceDocumentItem          as _Extension              on  _Extension.ServiceCategory       = 'BUS2000116'
                                                                                  and $projection.ServiceQuotation     = _Extension.ServiceOrderItem
                                                                                  and $projection.ServiceQuotationItem = _Extension.ServiceLineExternalID

  association [0..1] to I_CustMgmtPartner              as _ServicePerformer       on  CustMgmtPartnerFunction          = '00000028'
                                                                                  and CustMgmtPartFunctionCategory     = '0091'
                                                                                  and $projection.ServiceQuotation     = _ServicePerformer.CustMgmtDocument
                                                                                  and $projection.ServiceQuotationItem = _ServicePerformer.CustMgmtDocumentItem

{

      /* QuotationADM_I */
  key ServiceDocument                                                      as ServiceQuotation,
  key ServiceDocumentItem                                                  as ServiceQuotationItem,
      ServiceDocItemCategory,
      ServiceDocumentItemUUID                                              as ServiceQuotationItemUUID,
      ServiceDocumentItemDescription                                       as ServiceQtanItemDescription,
      Language,
      OriginallyRequestedProduct                                           as Product,
      ServiceDocItemQuantityUnit                                           as QuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      ServiceDocumentItemQuantity                                          as Quantity,

      ServiceDuration,
      ServiceDurationUnit,
      @ObjectModel.readOnly: true
      ServiceDocumentItemIsQuotation,

      @ObjectModel.readOnly: true
      ServiceDocItemChangedDateTime,
      
      @ObjectModel.readOnly: true
      ServiceDocItemChangedByUser,

      //BillableControl,


      _CustMgmtExtRef.CustMgmtExtRefID                                     as ServiceQtanItemExtReference,

      /* PARTNER */
      SoldToParty,
      ShipToParty,
      ResponsibleEmployee                                                  as PersonResponsible,
      _ServicePerformer.CustMgmtBusinessPartner                            as ServicePerformer,

      /* STATUS */
      case _SrvcDocSystemStatus.StatusCode
      when 'I1005' then case ServiceDocumentItemIsRejected
                     when 'X' then ''
                     else 'X'
                     end
      else ''
      end                                                                  as ServiceQuotationItemIsAccepted,
      ServiceDocumentItemIsRejected                                        as ServiceQuotationItemIsRejected,
      ServiceDocItemRejectionReason                                        as SrvcQtanItmRejectionReason,

      TimeSheetOvertimeCategory,

      _RefServiceContractItem.ReferenceServiceContract                     as ReferenceServiceContract,
      _RefServiceContractItem.ReferenceServiceContractItem                 as ReferenceServiceContractItem,
      _RefServiceOrderItem._ServiceDocItm._ServiceDocument.ServiceDocument as ServiceQtanSuccessorOrder,
      _RefServiceOrderItem._ServiceDocItm.ServiceDocumentItem              as ServiceQtanSuccessorOrderItem,


      _ParentServiceDocItem.ServiceDocumentItem                            as ParentServiceQuotationItem,

      @ObjectModel.sapObjectNodeTypeReference: 'PaymentTerms'
      PaymentTerms,

      /********************************************************/
      /*********  Cloud Specific Fields **************************/
      /* Dont delete this comment:
            This field always should be commented while publishing and add it later as the ATC will not allow to delete the field which is already released.
            In end of 2008 we have removed it at the time of API publishing since this field is not required to be exposed to the customer, with help of API
            hub team. Later in 2011 it was decided to remove it from odata, which was not possible. Since depreaction was not possible, we added this field
            back to the odata. This is a work around until a permanent solution is found*/
      @Feature: 'BF:API_ESSENTIALSCOPE'
      RespyMgmtServiceTeam,

      @Feature: 'BF:API_ESSENTIALSCOPE'
      @ObjectModel.readOnly: true
      _ServiceTeamHeader.TeamName                                          as RespyMgmtServiceTeamName,

      @Feature: 'BF:API_ESSENTIALSCOPE'
      _ServiceTeamHeader.RespyMgmtGlobalTeamID                             as RespyMgmtGlobalTeamID,
      /********************************************************/

      //      Associations

      _ReferenceObject,
      _Text,
      _ServiceQuotation,
      _PricingElement

}

where
      ServiceObjectType              = 'BUS2000116'
  and ServiceDocumentItemIsQuotation = 'X' //  Service Process