A_ServiceQuotationItemText

DDL: A_SERVICEQUOTATIONITEMTEXT Type: view_entity COMPOSITE Package: ODATA_CRMS4_SERVICEQUOTATION

Text of Service Quotation Item

A_ServiceQuotationItemText is a Composite CDS View that provides data about "Text of Service Quotation Item" in SAP S/4HANA. It reads from 2 data sources (I_ServiceDocumentItem, I_ServiceDocumentLongText) and exposes 6 fields with key fields ServiceQuotation, ServiceQuotationItem, Language, LongTextID. It has 1 association to related views. Part of development package ODATA_CRMS4_SERVICEQUOTATION.

2 data source(s) 6 fields

Data Sources (2)

SourceAliasJoin Type
I_ServiceDocumentItem ServiceQuotationItem inner
I_ServiceDocumentLongText ServiceQuotationItemText from

Associations (1)

CardinalityTargetAliasCondition
[1] A_ServiceQuotation _ServiceQuotation $projection.ServiceQuotation = _ServiceQuotation.ServiceQuotation

Annotations (11)

NameValueLevelField
EndUserText.label Text of Service Quotation Item view
VDM.viewType #COMPOSITE view
VDM.lifecycle.contract.type #PUBLIC_REMOTE_API view
AccessControl.authorizationCheck #CHECK view
ObjectModel.createEnabled true view
ObjectModel.updateEnabled true view
ObjectModel.deleteEnabled true view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
Metadata.ignorePropagatedAnnotations true view

Fields (6)

KeyFieldSource TableSource FieldDescription
KEY ServiceQuotation I_ServiceDocumentLongText ServiceDocument
KEY ServiceQuotationItem I_ServiceDocumentLongText ServiceDocumentItem
KEY Language I_ServiceDocumentLongText Language
KEY LongTextID I_ServiceDocumentLongText TextObjectType
LongText I_ServiceDocumentLongText ServiceDocumentLongText
_ServiceQuotation _ServiceQuotation 
@EndUserText.label: 'Text of Service Quotation Item'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view entity A_ServiceQuotationItemText
  as select from I_ServiceDocumentLongText as ServiceQuotationItemText
    inner join   I_ServiceDocumentItem     as ServiceQuotationItem on  ServiceQuotationItem.ServiceDocument                = ServiceQuotationItemText.ServiceDocument
                                                                   and ServiceQuotationItem.ServiceDocumentItem            = ServiceQuotationItemText.ServiceDocumentItem
                                                                   and ServiceQuotationItem.ServiceObjectType              = 'BUS2000116'
                                                                   and ServiceQuotationItemText.TextObjectCategory         = 'CRM_ORDERI'
                                                                   and ServiceQuotationItem.ServiceDocumentItemIsQuotation is not initial
                                                                   and ServiceQuotationItem.ServiceDocumentTemplateType    is initial

  association [1] to A_ServiceQuotation as _ServiceQuotation on $projection.ServiceQuotation = _ServiceQuotation.ServiceQuotation
{

  key ServiceQuotationItemText.ServiceDocument         as ServiceQuotation,
  key ServiceQuotationItemText.ServiceDocumentItem     as ServiceQuotationItem,
  key ServiceQuotationItemText.Language,
  key ServiceQuotationItemText.TextObjectType          as LongTextID,
      ServiceQuotationItemText.ServiceDocumentLongText as LongText,

      //Associations

      _ServiceQuotation

}

Learn More