A_FreightOrder

@EndUserText.label: 'Freight Order'
@AccessControl.authorizationCheck: #MANDATORY
@VDM.lifecycle.contract.type: #PUBLIC_REMOTE_API
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass: #TRANSACTIONAL
    }}
@VDM.viewType: #CONSUMPTION
@OData.entityType.name: 'FreightOrder_Type'
@Metadata.ignorePropagatedAnnotations: true

define root view entity A_FreightOrder
  provider contract transactional_query
  as projection on R_TransportationOrderTP as FreightOrder

{
      /* Attributes */
      // Identification

  key TransportationOrderUUID,
      TransportationOrder,

      // Key Characteristics

      @ObjectModel.sapObjectNodeTypeReference: 'TransportationOrderType'      
      TransportationOrderType,
      @ObjectModel.sapObjectNodeTypeReference: 'TransportationOrderCategory'      
      TransportationOrderCategory,
      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrderShippingType'      
      TransportationShippingType,
      //MovementType,  // MovementType is currently not used for Freight Orders

      @ObjectModel.sapObjectNodeTypeReference: 'TransportationMode'      
      TransportationMode,
      @ObjectModel.sapObjectNodeTypeReference: 'TransportationModeCategory'      
      TransportationModeCategory,

      // Parties

      CarrierUUID,
      Carrier,
      @ObjectModel.sapObjectNodeTypeReference: 'StandardCarrierAlphaCode'      
      StandardCarrierAlphaCode,
      TranspOrdExecutingCarrierUUID,
      TranspOrdExecutingCarrier,
      ShipperUUID,
      Shipper,
      ShipperAddressID,
      ConsigneeUUID,
      Consignee,
      ConsigneeAddressID,

      TranspPurgOrg,
      TranspPurgOrgExtID,
      TranspPurgGroup,
      TranspPurgGroupExtID,
      PurgOrgCompanyCode,
      //PlngAndExecOrganization,  // Planning and Execution Organization and Group is currently not used in Freight Orders

      //PlngAndExecGroup,

      CarrierAccountNumber,

      // Further Attributes

      @ObjectModel.sapObjectNodeTypeReference: 'TransportationMeansOfTransport'      
      TranspMeansOfTransport,
      TranspOrdPartnerReference,
      //MasterBillOfLading,  // Master Bill of Lading is currently not used in Freight Orders

      TranspOrdResponsiblePerson,
      TranspOrdHasMltplExectgPties,
      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrdInvoicingCarrierLevel'      
      TranspOrdInvoicingCarrierLevel,

      // Status

      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrderLifecycleStatus'
      TranspOrdLifeCycleStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrdSubcontractingStatus'       
      TranspOrderSubcontrgSts,
      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrderConfirmationStatus'       
      TransportationOrderConfSts,
      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrderExecutionStatus'      
      TransportationOrderExecSts,
      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrdGoodsMovementStatus'       
      TranspOrdGoodsMovementStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrdWhseProcessingStatus'      
      TranspOrdWhseProcessingStatus,
      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrdDangerousGoodsStatus'      
      TranspOrderDngrsGdsSts,
      //TranspOrdPlanningBlock,  // Planning Block is currently not used in Freight Orders

      @Semantics.booleanIndicator: true
      TranspOrdExecutionIsBlocked,

      // Administrative Data

      @ObjectModel.sapObjectNodeTypeReference: 'TranspOrderCreationType'
      TransportationOrderCrtnType,
      CreatedByUser,
      CreationDateTime,
      LastChangedByUser,
      ChangedDateTime,

      /* Redirections */
      FreightOrder._TransportationOrderBP       as _FreightOrderBusinessPartner   : redirected to composition child A_FreightOrderBusinessPartner,
      FreightOrder._TranspOrdDocumentReference  as _FreightOrderDocumentReference : redirected to composition child A_FreightOrderDocRef,
      FreightOrder._TransportationOrderItem     as _FreightOrderItem              : redirected to composition child A_FreightOrderItem,
      FreightOrder._TransportationOrderStop     as _FreightOrderStop              : redirected to composition child A_FreightOrderStop,
      FreightOrder._TransportationOrderEvent    as _FreightOrderEvent             : redirected to composition child A_FreightOrderEvent,
      FreightOrder._TransportationOrderCharge   as _FreightOrderCharge            : redirected to composition child A_FreightOrderCharge,
      FreightOrder._TrOrdMainBPAddrDfltRprstn   as _FrtOrdMainBPAddrDfltRprstn    : redirected to composition child A_FrtOrdMainBPAddrDfltRprstn,

      /* Association redirections */
      FreightOrder._CarrierAddrDfltRprstn       as _CarrierAddrDfltRprstn         : redirected to A_FrtOrdMainBPAddrDfltRprstn,
      FreightOrder._ShipperAddrDfltRprstn       as _ShipperAddrDfltRprstn         : redirected to A_FrtOrdMainBPAddrDfltRprstn,
      FreightOrder._ConsigneeAddrDfltRprstn     as _ConsigneeAddrDfltRprstn       : redirected to A_FrtOrdMainBPAddrDfltRprstn,
      FreightOrder._ExectgCarrierAddrDfltRprstn as _ExectgCarrierAddrDfltRprstn   : redirected to A_FrtOrdMainBPAddrDfltRprstn
}
where
  TransportationOrderCategory = 'TO'