R_TRANSPORTATIONORDERTP

CDS View

Transportation Order - TP

R_TRANSPORTATIONORDERTP is a CDS View in S/4HANA. Transportation Order - TP. 6 CDS views read from this table.

Used by 6 CDS view(s)

CDS Views using this table (6)

ViewTypeJoinVDMDescription
A_FreightBooking view_entity projection CONSUMPTION Freight Booking
A_FreightOrder view_entity projection CONSUMPTION Freight Order
A_FreightUnit view_entity projection CONSUMPTION Freight Unit
I_FreightBookingTP view_entity projection TRANSACTIONAL Freight Booking - TP
I_FreightOrderTP view_entity projection TRANSACTIONAL Freight Order - TP
I_FreightUnitTP view_entity projection TRANSACTIONAL Freight Unit - TP 
@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@EndUserText.label: 'Transportation Order - TP'
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    },
    semanticKey: ['TransportationOrder'],
    representativeKey: 'TransportationOrderUUID',
    sapObjectNodeType.name: 'TransportationOrder'
}
@AccessControl: { authorizationCheck: #MANDATORY,
                  privilegedAssociations: ['_TranspOrdResponsiblePerson',
                                           '_CreatedBy',
                                           '_LastChangedBy']}
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  elementSuffix: 'TOR',
  quota: {
    maximumFields: 408, //This is calculated with formula - 2* <Customer Percentage from SCFD_REGISTRY> * <max number of fields in SCFD_REGISTRY>

    maximumBytes: 8160  //This is calculated with formula - 4* <Customer Percentage from SCFD_REGISTRY> * <number of chars as defined in SCFD_REGISTRY>

  }
 }

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
define root view entity R_TransportationOrderTP
  as select from I_TransportationOrder_2 as _TransportationOrder

  composition [0..*] of R_TransportationOrderBPTP     as _TransportationOrderBP
  composition [0..*] of R_TranspOrdDocRefTP           as _TranspOrdDocumentReference
  composition [0..*] of R_TransportationOrderItemTP   as _TransportationOrderItem
  composition [0..*] of R_TransportationOrderStopTP   as _TransportationOrderStop
  composition [0..*] of R_TransportationOrderEventTP  as _TransportationOrderEvent
  composition [0..*] of R_TrOrdMainBPAddrDfltRprstnTP as _TrOrdMainBPAddrDfltRprstn
  composition [0..*] of R_TransportationOrderNoteTP   as _TransportationOrderNote
  // Charges specific composition

  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
  composition [0..1] of R_TransportationOrderChargeTP as _TransportationOrderCharge

  // Role specific associations to Main BP Address Entity

  association [0..1] to R_TrOrdMainBPAddrDfltRprstnTP as _CarrierAddrDfltRprstn       on  $projection.TransportationOrderUUID                = _CarrierAddrDfltRprstn.TransportationOrderUUID
                                                                                      and _CarrierAddrDfltRprstn.TranspOrdBizPartnerFunction = 'U3'
  association [0..1] to R_TrOrdMainBPAddrDfltRprstnTP as _ShipperAddrDfltRprstn       on  $projection.TransportationOrderUUID                = _ShipperAddrDfltRprstn.TransportationOrderUUID
                                                                                      and _ShipperAddrDfltRprstn.TranspOrdBizPartnerFunction = 'U6'
  association [0..1] to R_TrOrdMainBPAddrDfltRprstnTP as _ConsigneeAddrDfltRprstn     on  $projection.TransportationOrderUUID                  = _ConsigneeAddrDfltRprstn.TransportationOrderUUID
                                                                                      and _ConsigneeAddrDfltRprstn.TranspOrdBizPartnerFunction = 'WE'
  association [0..1] to R_TrOrdMainBPAddrDfltRprstnTP as _ExectgCarrierAddrDfltRprstn on  $projection.TransportationOrderUUID                      = _ExectgCarrierAddrDfltRprstn.TransportationOrderUUID
                                                                                      and _ExectgCarrierAddrDfltRprstn.TranspOrdBizPartnerFunction = 'TJ'

  // Position specific associations to Stop Entity

  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
  association [0..1] to R_TransportationOrderStopTP   as _SourceStop                  on  $projection.TransportationOrderUUID       = _SourceStop.TransportationOrderUUID
                                                                                      and _SourceStop.TranspOrdStopSequencePosition = 'F'
  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
  association [0..1] to R_TransportationOrderStopTP   as _DestinationStop             on  $projection.TransportationOrderUUID            = _DestinationStop.TransportationOrderUUID
                                                                                      and _DestinationStop.TranspOrdStopSequencePosition = 'L'

  // Specific associations to Item Entity

  /*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ]  } */
  association [0..1] to R_TransportationOrderItemTP   as _TransportationOrderMainItem on  $projection.TransportationOrderUUID                      = _TransportationOrderMainItem.TransportationOrderUUID
                                                                                      and _TransportationOrderMainItem.TranspOrdItemParentItemUUID = abap.raw'00000000000000000000000000000000' //instead of 'is initial' which causes issues here


  //Extension Association

  association [1]    to E_TransportationOrder            as _Extension                on  $projection.TransportationOrderUUID = _Extension.TransportationOrderUUID
{
      /* Attributes */
      // Identification

  key _TransportationOrder.TransportationOrderUUID,
      _TransportationOrder.TransportationOrder,

      // Key Characteristics

      _TransportationOrder.TransportationOrderType,
      _TransportationOrder.TransportationOrderCategory,
      _TransportationOrder.TransportationShippingType,
      _TransportationOrder.MovementType,
      _TransportationOrder.TransportationMode,
      _TransportationOrder.TransportationModeCategory,

      // Parties

      _TransportationOrder.CarrierUUID,
      _TransportationOrder.Carrier,
      _TransportationOrder.CarrierAddressID,
      _TransportationOrder.StandardCarrierAlphaCode,
      _TransportationOrder.TranspOrdExecutingCarrierUUID,
      _TransportationOrder.TranspOrdExecutingCarrier,
      _TransportationOrder.ExecutingCarrierAddressID,
      _TransportationOrder.ShipperUUID,
      _TransportationOrder.Shipper,
      _TransportationOrder.ShipperAddressID,
      _TransportationOrder.ConsigneeUUID,
      _TransportationOrder.Consignee,
      _TransportationOrder.ConsigneeAddressID,

      // Org. Units (Renaming necessary as APIs were released with wrong Field Names)

      cast( '00000000' as /scmtms/purch_org_id preserving type )                as TranspPurgOrg,      // Deprecated TM specific Org. Unit

      cast( '00000000' as /scmtms/purch_grp_id preserving type )                as TranspPurgGroup,
      cast( _TransportationOrder.TranspPurgOrg as /scmtms/vdm_pur_org_ext_id)   as TranspPurgOrgExtID, // ERP Org. Unit

      cast( _TransportationOrder.TranspPurgGroup as /scmtms/vdm_pur_grp_ext_id) as TranspPurgGroupExtID,
      _TransportationOrder.PurgOrgCompanyCode,
      _TransportationOrder.CarrierAccountNumber,

      // Further Attributes

      _TransportationOrder.TranspMeansOfTransport,
      _TransportationOrder.TranspOrdPartnerReference,
      _TransportationOrder.MasterBillOfLading,
      _TransportationOrder.TranspOrdResponsiblePerson,
      _TransportationOrder.TranspOrdHasMltplExectgPties,
      _TransportationOrder.TranspOrdInvoicingCarrierLevel,

      // Status

      _TransportationOrder.TranspOrdLifeCycleStatus,
      _TransportationOrder.TranspOrderSubcontrgSts,
      _TransportationOrder.TransportationOrderConfSts,
      _TransportationOrder.TransportationOrderExecSts,
      _TransportationOrder.TranspOrdGoodsMovementStatus,
      _TransportationOrder.TranspOrdWhseProcessingStatus,
      _TransportationOrder.TranspOrderDngrsGdsSts,
      _TransportationOrder.TranspOrdPlanningBlock,
      _TransportationOrder.TranspOrdExecutionIsBlocked,
      _TransportationOrder.TranspOrdPlanningStatus,

      // Administrative Data

      _TransportationOrder.TransportationOrderCrtnType,
      _TransportationOrder.CreatedByUser,
      _TransportationOrder.CreationDateTime,
      _TransportationOrder.LastChangedByUser,
      _TransportationOrder.ChangedDateTime,


      /* Associations */
      _TransportationOrder._Carrier,
      _TransportationOrder._Consignee,
      _TransportationOrder._CreatedBy,
      _TransportationOrder._LastChangedBy,
      _TransportationOrder._MeansOfTransport,
      _TransportationOrder._MovementType,
      _TransportationOrder._PurchasingCompanyCode,
      _TransportationOrder._Shipper,
      _TransportationOrder._TranspOrdConfirmationStatus,
      _TransportationOrder._TranspOrdExecutionIsBlocked,
      _TransportationOrder._TranspOrdLifeCycleStatus,
      _TransportationOrder._TranspOrdPlanningBlock,
      _TransportationOrder._TranspOrdPlanningStatus,
      _TransportationOrder._TranspOrdResponsiblePerson,
      _TransportationOrder._TranspOrdShippingType,
      _TransportationOrder._TranspOrdSubcontractingSts,
      _TransportationOrder._TransportationMode,
      _TransportationOrder._TransportationModeCategory,
      _TransportationOrder._TransportationOrderCategory,
      _TransportationOrder._TransportationOrderExecSts,
      _TransportationOrder._TransportationOrderType,
      _TransportationOrder._TranspSCACCode,
      _TransportationOrder._TranspOrdDngrsGdsStatus,

      /* Composition Associations */
      _TransportationOrderBP,
      _TranspOrdDocumentReference,
      _TransportationOrderItem,
      _TransportationOrderStop,
      _TransportationOrderEvent,
      _TrOrdMainBPAddrDfltRprstn,
      _TransportationOrderNote,
      //Charges specific compositions

      _TransportationOrderCharge,

      _CarrierAddrDfltRprstn,
      _ShipperAddrDfltRprstn,
      _ConsigneeAddrDfltRprstn,
      _ExectgCarrierAddrDfltRprstn,

      _SourceStop,
      _DestinationStop,
      _TransportationOrderMainItem
}

Learn More