A_CustomerReturnItemPartner

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Item Partner'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ACRITMPARTNER',
  compiler.compareFilter: true
}
@AccessControl: { 
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true

define view A_CustomerReturnItemPartner
  as select from I_SDDocumentItemPartner as Partner
    inner join   I_SalesDocumentBasic    as CustomerReturn on  CustomerReturn.SalesDocument = Partner.SDDocument
                                                       and SDDocumentCategory       = 'H'

  association [1..1] to A_CustomerReturn     as _CustomerReturn     on  $projection.CustomerReturn = _CustomerReturn.CustomerReturn
  association [1..1] to A_CustomerReturnItem as _CustomerReturnItem on  $projection.CustomerReturn     = _CustomerReturnItem.CustomerReturn
                                                            and $projection.CustomerReturnItem = _CustomerReturnItem.CustomerReturnItem
  
  association [0..1] to I_BusPartAddress as _BusinessPartnerAddressCP      on Partner.AddressID = _BusinessPartnerAddressCP.AddressID
                                                                           and $projection.ContactPerson is not initial
                                                                           and Partner.SDDocPartnerAddressRefType =  'I' 
{
      @ObjectModel.readOnly: true
  key SDDocument                                      as CustomerReturn,

      @ObjectModel.readOnly: true
  key SDDocumentItem                                  as CustomerReturnItem,

      @ObjectModel.sapObjectNodeTypeReference: 'PartnerFunction'
  key PartnerFunction,
  
      @ObjectModel.readOnly: true
      cast(PartnerFunction as parvw_unv preserving type )    as PartnerFunctionInternalCode,

      Customer,

      Supplier,

      Personnel,

      ContactPerson,
      
      @ObjectModel.readOnly: true
      ReferenceBusinessPartner,
      
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES3, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      case ContactPerson
        when '0000000000' then
         _BusinessPartnerAddress.AddressUUID
       else
         _BusinessPartnerAddressCP.AddressUUID
                                                    end as BusinessPartnerAddressUUID,
      
      @Feature: 'SW:Q2C_MULTIPLE_BP_ADDRESSES3, SW:Q2C_MULTIPLE_BP_ADDRESSES2'
      @ObjectModel.readOnly: true  
      Partner._BPRefAddressForDocSpcfcAddr.AddressUUID  as BPRefAddrForDocSpcfcAddrUUID,    
      

      // For Access control

      @Consumption.hidden: true
      CustomerReturn.SalesDocumentType as CustomerReturnType,
      @Consumption.hidden: true
      CustomerReturn.OrganizationDivision,
      @Consumption.hidden: true
      CustomerReturn.SalesOrganization,
      @Consumption.hidden: true
      CustomerReturn.DistributionChannel,

      //Expose associations

      _CustomerReturn,
      _CustomerReturnItem
}