A_CustomerReturn

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Returns Order Header'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ACUSTOMERRETURN',
  compiler.compareFilter: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'CustomerReturn',
   createEnabled: true,
   updateEnabled: true,
   deleteEnabled: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #XL
   }
}
@Metadata.ignorePropagatedAnnotations: true
define view A_CustomerReturn 
  as select from I_CustomerReturnEnhanced as CustomerReturn

  association [0..*] to A_CustomerReturnItem          as _Item           on _Item.CustomerReturn = $projection.CustomerReturn

  association [0..*] to A_CustomerReturnPartner       as _Partner        on _Partner.CustomerReturn = $projection.CustomerReturn

  association [0..*] to A_CustomerReturnPrcgElmnt     as _PricingElement on _PricingElement.CustomerReturn = $projection.CustomerReturn

  association [0..*] to A_CustomerReturnText          as _Text           on _Text.CustomerReturn = $projection.CustomerReturn

  association [0..*] to A_CustomerReturnRelatedObject as _RelatedObject  on _RelatedObject.CustomerReturn = $projection.CustomerReturn
  
  association [0..1] to A_CustomerReturnOverviewStatus as _CustomerReturnOverviewStatus on  $projection.RetsMgmtProcess = _CustomerReturnOverviewStatus.RetsMgmtProcess
 
  //Extensibility

  association [0..1] to E_SalesDocumentBasic          as _Extension      on $projection.CustomerReturn = _Extension.SalesDocument

{

  key CustomerReturn,

      CustomerReturnType,

      SalesOrganization,
      DistributionChannel,
      OrganizationDivision,

      SalesGroup,
      SalesOffice,
      SalesDistrict,

      SoldToParty,

      @ObjectModel.readOnly: true
      CreationDate,

      @ObjectModel.readOnly: true
      CreatedByUser,

      @ObjectModel.readOnly: true
      LastChangeDate,

      @ObjectModel.readOnly:true
      SenderBusinessSystemName,

      @ObjectModel.readOnly: true
      case tstmp_is_valid(LastChangeDateTime)
        when 0 then cast( dats_tims_to_tstmp( CreationDate, CreationTime, 'UTC', $session.client, 'NULL' ) as timestampl )
        else LastChangeDateTime
      end as LastChangeDateTime,

      PurchaseOrderByCustomer,
      @ObjectModel.sapObjectNodeTypeReference: 'PurchaseOrderTypeByCustomer'
      CustomerPurchaseOrderType,
      CustPurOrdTypeByShipToParty,
      CustomerPurchaseOrderDate,
      PurchaseOrderByShipToParty,
      CorrespncExternalReference,
      CorrespncExtRefByShipToParty,


      CustomerReturnDate,

      @ObjectModel.readOnly: true
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,
      @Semantics.currencyCode: true
      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      TransactionCurrency,

      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocumentReason'
      SDDocumentReason,
      PricingDate,

      RequestedDeliveryDate,
      
      ShippingType,
      
      @ObjectModel.sapObjectNodeTypeReference: 'BillingBlockReason'
      HeaderBillingBlockReason,
      DeliveryBlockReason,

      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsClassification'
      IncotermsClassification,
      IncotermsTransferLocation,
      IncotermsLocation1,
      IncotermsLocation2,
      @ObjectModel.sapObjectNodeTypeReference: 'IncotermsVersion'
      IncotermsVersion,

      CustomerPaymentTerms,
      PaymentMethod,
      
      //Tax Classfication

      CustomerTaxClassification1,
      CustomerTaxClassification2,
      CustomerTaxClassification3,
      CustomerTaxClassification4,
      CustomerTaxClassification5,
      CustomerTaxClassification6,
      CustomerTaxClassification7,
      CustomerTaxClassification8,
      CustomerTaxClassification9,
      
      @ObjectModel.readOnly: true
      RetsMgmtProcess,

      ReferenceSDDocument,
       
      @ObjectModel.readOnly: true
      ReferenceSDDocumentCategory,
      AccountingDocExternalReference,
      
      AssignmentReference,

      CustomerReturnApprovalReason,
      @ObjectModel.sapObjectNodeTypeReference: 'SalesDocApprovalStatus'
      SalesDocApprovalStatus,

      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CUSTOMER_RETURN_OPG_VE'
      @ObjectModel.filter.transformedBy: 'ABAP:CL_CUSTOMER_RETURN_SADL_FILTER'
      @ObjectModel.sort.transformedBy: 'ABAP:CL_CUSTOMER_RETURN_SADL_FILTER'
      cast('' as return_log_procg_status)                                           as RetsMgmtLogProcgStatus,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CUSTOMER_RETURN_OPG_VE'
      @ObjectModel.filter.transformedBy: 'ABAP:CL_CUSTOMER_RETURN_SADL_FILTER'
      @ObjectModel.sort.transformedBy: 'ABAP:CL_CUSTOMER_RETURN_SADL_FILTER'
      cast('' as msr_fin_status)                                                    as RetsMgmtCompnProcgStatus,
      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CUSTOMER_RETURN_OPG_VE'
      @ObjectModel.filter.transformedBy: 'ABAP:CL_CUSTOMER_RETURN_SADL_FILTER'
      @ObjectModel.sort.transformedBy: 'ABAP:CL_CUSTOMER_RETURN_SADL_FILTER'
      cast('' as msr_proc_status)                                                   as RetsMgmtProcessingStatus,

      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDProcessStatus'
      OverallSDProcessStatus,

      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'TotalCreditCheckStatus'
      TotalCreditCheckStatus,

      @ObjectModel.readOnly: true
      @ObjectModel.sapObjectNodeTypeReference: 'OverallSDDocumentRejectionSts'
      OverallSDDocumentRejectionSts,

      // Expose own associations

      _Item,
      _Partner,
      _PricingElement,
      _Text,
      _RelatedObject,
      
//      @Consumption.filter.hidden: true

      _CustomerReturnOverviewStatus
}