A_BusSolnOrdSimulation

//@ClientHandling.algorithm:#SESSION_VARIABLE

@EndUserText.label: 'Header Simulation'
@VDM: {
  lifecycle.contract.type: #PUBLIC_REMOTE_API,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE],
  viewType: #CONSUMPTION
}

@AccessControl: {
    authorizationCheck: #MANDATORY,
    personalData.blocking: #('TRANSACTIONAL_DATA')
}
@Metadata.ignorePropagatedAnnotations: true

@OData: {
  entityType.name: 'BusinessSolutionOrder_Type'
}

@ObjectModel: {
   semanticKey: [ 'BusinessSolutionOrder' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   },
   query.implementedBy: 'ABAP:CL_CRMS4_SOLO_SIMLN_QUERY'
}
define root view entity A_BusSolnOrdSimulation
  as select from I_ServiceDocumentEnhcd

  association [0..1] to E_ServiceDocument  as _Extension on $projection.BusinessSolutionOrder = _Extension.ServiceOrder
                                                         and _Extension.ServiceCategory = 'BUS2000172'  
  
  composition [0..*] of A_BusSolnOrdItemSimulation as _Item
  composition [0..*] of A_BusSolnOrdPartnerSimulation  as _Partner
{
  key ServiceDocument            as BusinessSolutionOrder,
      @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentType'
      ServiceDocumentType        as BusSolnOrdType,
      ServiceDocumentDescription as BusSolnOrdDescription,
      @ObjectModel.sapObjectNodeTypeReference: 'PaymentTerms'
      PaymentTerms,
      Language,
      
//      @Semantics.booleanIndicator: true

//      cast( ' ' as   xfeld preserving type) as ForceSyncCallFlag,

      
      ServiceDocumentCreatedByUser,

      // Partners

      SoldToParty,
      ShipToParty,
      BillToParty,
      PayerParty,
      ContactPerson              as ContactPersonBusinessPartnerId,
      ResponsibleEmployee        as RespEmployeeBusinessPartnerId,

      // Pricing

      @ObjectModel.sapObjectNodeTypeReference: 'Currency'
      TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      ServiceDocNetAmount,
      
      // Organization

      SalesOrganization,
      DistributionChannel,
      @ObjectModel.sapObjectNodeTypeReference: 'Division'
      Division,
      SalesOffice,
      SalesGroup,

      // Status

      @Semantics.booleanIndicator : true
      ServiceDocumentHasError    as BusSolnOrdHasError,
      
      @Consumption.hidden: true
      ServiceObjectType,

      //Compositions

      @ObjectModel.filter.enabled: false
      _Item,
      _Partner

      
}
where
  ServiceObjectType = 'BUS2000172'