A_BusSolnOrdItemSimulation

@VDM: {
  lifecycle.contract.type: #PUBLIC_REMOTE_API,
  usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE],
  viewType: #CONSUMPTION
}

@AccessControl: {
    authorizationCheck: #MANDATORY,
    personalData.blocking: #('TRANSACTIONAL_DATA')
}
@EndUserText.label: 'Item Simulation'
@Metadata.ignorePropagatedAnnotations: true

@OData: {
  entityType.name: 'BusinessSolutionOrderItem_Type'
}

@ObjectModel: {
   semanticKey: [ 'BusinessSolutionOrder', 'BusinessSolutionOrderItem' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #C,
     sizeCategory:   #L
   },
   query.implementedBy: 'ABAP:CL_CRMS4_SOLO_SIMLN_QUERY'
}
define view entity A_BusSolnOrdItemSimulation
  as select from I_ServiceDocumentItemEnhcd


  association        to parent A_BusSolnOrdSimulation  as _BusinessSolutionOrder on  $projection.BusinessSolutionOrder = _BusinessSolutionOrder.BusinessSolutionOrder


  association [0..1] to I_UnitOfMeasure                as _QuantityUnit          on  $projection.QuantityUnit = _QuantityUnit.UnitOfMeasure

  association [0..1] to I_SrvcMgmtObjectStatus         as _ServiceContractDetn   on  $projection.BusinessSolutionOrderItemUUID           = _ServiceContractDetn.SrvcMgmtObjectUUID
                                                                                 and _ServiceContractDetn.SrvcMgmtObjectStatus           = 'I0994'
                                                                                 and _ServiceContractDetn.SrvcMgmtObjectStatusIsInactive = ''
  association [0..1] to I_ServiceDocumentItemPrdcssr_3 as _ReferenceSrvcContract on  $projection.ServiceDocumentItemCharUUID               = _ReferenceSrvcContract.ServiceDocumentItemCharUUID
                                                                                 and _ReferenceSrvcContract.ServiceDocItmPrdcssrBusObjType = 'BUS2000137'
  association [0..1] to I_CustMgmtDateRule             as _SettlementPeriodRule  on  $projection.SettlementPeriodRuleUUID = _SettlementPeriodRule.CustMgmtDateRuleUUID
  
  association [0..1] to E_ServiceDocumentItem          as _Extension             on _Extension.ServiceCategory = 'BUS2000172'
                                                                                 and $projection.BusinessSolutionOrder = _Extension.ServiceOrderItem
                                                                                 and $projection.BusinessSolutionOrderItem = _Extension.ServiceLineExternalID

  composition [0..*] of A_BusSolnOrdItmPriceElmntSimln as _PriceElement
  composition [0..*] of A_BusSolOrdItmBlgReqItmSimln   as _BillingRequestItem
  composition [0..*] of A_BusSolnOrdItemPartnerSimln   as _Partner
{

      /* admin */

  key ServiceDocument                                           as BusinessSolutionOrder,
  key ServiceDocumentItem                                       as BusinessSolutionOrderItem,
      _ParentServiceDocItem_2.ServiceDocumentItem               as ParentBusSolnOrdItem,
      Product,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      SrvcDocItemCumulatedNetAmount,
      ServiceDocumentItemObjectType,
      @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentItemCategory'
      ServiceDocItemCategory                                    as BusSolnOrdItmCategory,
      ServiceDocumentItemDescription                            as BusSolnOrdItmDescription,
      @Semantics.uuid: true
      @Consumption.hidden: true
      ServiceDocumentItemCharUUID,

      //Date

      @Semantics.dateTime: true
      ServiceContrItemStartDateTime,
      @Semantics.dateTime: true
      ServiceContrItemEndDateTime,
      @Semantics.dateTime: true
      RequestedServiceStartDateTime,
      @Semantics.dateTime: true
      RequestedServiceEndDateTime,

      //Quantity

      @Semantics.quantity.unitOfMeasure: 'QuantityUnit'
      @Semantics.quantity.unitOfMeasureSapCode: 'BusSolnOrdItmQtyUnitSAPCode'
      @Semantics.quantity.unitOfMeasureIsoCode: 'BusSolnOrdItmQtyUnitISOCode'
      ServiceDocumentItemQuantity                               as Quantity,
      ServiceDocItemQuantityUnit                                as QuantityUnit,
      _QuantityUnit.UnitOfMeasureSAPCode                        as BusSolnOrdItmQtyUnitSAPCode,
      _QuantityUnit.UnitOfMeasureISOCode                        as BusSolnOrdItmQtyUnitISOCode,

      /* partners */
      SoldToParty,
      ShipToParty,
      BillToParty,
      PayerParty,
      ContactPerson                                             as ContactPersonBusinessPartnerId,
      ResponsibleEmployee                                       as RespEmployeeBusinessPartnerId,

      /* pricing */
      TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      ServiceDocumentItemNetAmount,

      /* shipping */
      @Semantics.quantity.unitOfMeasureSapCode: 'BusSolnOrdItmQtyUnitSAPCode'
      @Semantics.quantity.unitOfMeasureIsoCode: 'BusSolnOrdItmQtyUnitISOCode'
      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      ItemGrossWeight,
      @Semantics.quantity.unitOfMeasureSapCode: 'BusSolnOrdItmQtyUnitSAPCode'
      @Semantics.quantity.unitOfMeasureIsoCode: 'BusSolnOrdItmQtyUnitISOCode'
      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      ItemNetWeight,
      @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
      @Semantics.quantity.unitOfMeasureSapCode: 'UnitOfMeasureSAPCode'
      @Semantics.quantity.unitOfMeasureIsoCode: 'UnitOfMeasureISOCode'
      ItemVolume,
      ItemVolumeUnit,
      _VolumeUnit.UnitOfMeasureSAPCode,
      _VolumeUnit.UnitOfMeasureISOCode,
      ItemWeightUnit,

      //Sales

      cast( case when ServiceDocumentItemObjectType = 'BUS2000131'
      then IncotermsPart1
      else ''
      end as crmt_incoterms1 preserving type )                  as IncotermsPart1,
      cast( case when ServiceDocumentItemObjectType = 'BUS2000131'
      then IncotermsPart2
      else ''
      end as crmt_incoterms2 preserving type )                  as IncotermsPart2,
      cast( case when ServiceDocumentItemObjectType = 'BUS2000131'
      then DeliveryGroup
      else '000'
      end as crmt_dlv_group preserving type )                   as DeliveryGroup,
      cast (case when ServiceDocumentItemObjectType = 'BUS2000131'
      then DeliveryPriority
      else '00'
      end as crmt_dlv_prio preserving type )                    as DeliveryPriority,
      Plant,

      cast (case when _ServiceContractDetn.SrvcMgmtObjectStatus = 'I0994'
      then 'X'
      else ''
      end as xfeld  preserving type )                           as SrvcContrDetnIsSpprsd,

      /* reference documents */
      _ReferenceSrvcContract._ServiceDocItm.ServiceDocument     as ReferenceServiceContract,
      _ReferenceSrvcContract._ServiceDocItm.ServiceDocumentItem as ReferenceServiceContractItem,

      _BillPlanDateRule.CustMgmtDateRuleName                    as SrvcMgmtBillgPlanBillgDateRule,
      @Semantics.uuid: true
      @Consumption.hidden: true
      SettlementPeriodRuleUUID,
      _SettlementPeriodRule.CustMgmtDateRuleName                as SettlementPeriodRule,

      /* organisation */
      SalesOrganization,
      DistributionChannel,
      Division,
      SalesOffice,
      SalesGroup,

      /* common */
      PaymentTerms,

      @Consumption.hidden: true
      ServiceDocumentType                                       as BusSolnOrdType,
      @Consumption.hidden: true
      ServiceObjectType,
      @Consumption.hidden: true
      ServiceDocumentItemUUID                                   as BusinessSolutionOrderItemUUID,

      _BusinessSolutionOrder,
      _PriceElement,
      _BillingRequestItem,
      _Partner

      //      _ProjectManager

}
where
  ServiceObjectType = 'BUS2000172'