APS_IAM_INFO_FSP_APP_BASIC

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Fiori Space - Application Basic'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity APS_IAM_INFO_FSP_APP_BASIC
  as select from    APS_IAM_INFO_FSP_FPA_BASIC as SpacePage
    inner join      APS_IAM_INFO_FSP_APP_TILES as pageaiti  on pageaiti.PageId = SpacePage.PageId
  //    left outer join APS_IAM_APP_APPS_LIST_DDL( p_langu: $session.system_language ) as App       on App.InternalId = pageaiti.ChipId

    left outer join aps_iam_a_apps             as App       on App.chip_id = pageaiti.ChipId

  //    left outer join aps_iam_w_bucapp           as bucapp    on bucapp.bu_catalog_app_id = App.bu_catalog_app_id

  //    left outer join aps_iam_w_app              as w_app     on w_app.app_id = bucapp.app_id


    left outer join sui_tm_mm_app              as TileTmApp on TileTmApp.app_id = App.reference_id
  //    left outer join sui_tm_mm_app                                                  as TileTmApp on TileTmApp.app_id = App.FioriAppID

    left outer join sui_tm_mm_appt             as AppText   on  AppText.app_id = TileTmApp.app_id
                                                            and AppText.langu  = $session.system_language

    left outer join APS_IAM_INFO_CHIP          as Chip      on Chip.ChipId = App.chip_id
    left outer join APS_IAM_INFO_BC_APP_BASIC  as Catalog   on Catalog.ChipID = App.chip_id

  association [1..*] to APS_IAM_INFO_FLP_CATEGORY as _LaunchpadTypeText on  _LaunchpadTypeText.KeyValue = SpacePage.FioriSpaceType
                                                                        and _LaunchpadTypeText.Language = $session.system_language
                                                                        and _LaunchpadTypeText.As4local = 'A'
  association [0..1] to APS_TADIR                 as _Component         on  _Component.obj_name = TileTmApp.tcode
                                                                        and _Component.object   = 'SIA6'
                                                                        and _Component.pgmid    = 'R3TR'
{
  key SpacePage.FioriSpaceId,
  key SpacePage.PageId,
      //  key case when App.fiori_id is not initial then App.fiori_id

      //       else w_app.tcode end as FioriID,

  key App.fiori_id                             as FioriID,
      SpacePage.FioriSpaceTitle,
      SpacePage.FioriSpaceDescription,
      SpacePage.PageTitle,
      SpacePage.PageDescription,
      @Consumption.valueHelpDefinition: [{ entity : { name    : 'APS_IAM_INFO_FLP_CATEGORY',
                                                      element : 'KeyValue'} }]
      @ObjectModel.text.element: ['LaunchpadCategoryText']
      SpacePage.FioriSpaceType,
      SpacePage.IsSpaceTemplate,
      SpacePage.IsSpaceTemplate as IsPageTemplate,
      _LaunchpadTypeText.LaunchpadCategoryText,
      //      pageaiti.TileId                                            as AppTileId,

      pageaiti.TileType,
      //      App.FioriAppID  as AppId,

      //      App.Title       as ApplicationText,

      //      App.SubTitle    as AppSubtitle

      TileTmApp.app_id                         as AppId,
      case
        when AppText.tile_title is not initial then AppText.tile_title
        when AppText.alt_smart_link_title is not initial then AppText.alt_smart_link_title
        else Chip.ChipTitle
      end                                      as ApplicationText,
      case
        when AppText.tile_subtitle is not initial then AppText.tile_subtitle
        else Chip.ChipSubtitle
      end                                      as AppSubtitle,
      cast(TileTmApp.tcode as abap.char( 35 )) as FioriTransaction,
      _Component.ach                           as AppComponent,
      Catalog.IsMigrated
}

union

select from       APS_IAM_INFO_FSP_FPA_BASIC as SpacePage
  inner join      APS_IAM_INFO_FSP_APP_UIAD  as PageUiadAssignment on PageUiadAssignment.PageId = SpacePage.PageId
  left outer join aps_iam_a_apps             as App                on App.reference_id = PageUiadAssignment.UiadId
  left outer join aps_iam_w_app              as AppDetails         on AppDetails.tcode = App.fiori_id
  left outer join sui_tm_mm_app              as AppDescriptorItem  on AppDescriptorItem.app_id = PageUiadAssignment.UiadId
  left outer join sui_tm_mm_appt             as AppText            on  AppText.app_id = PageUiadAssignment.UiadId
                                                                   and AppText.langu  = $session.system_language

  left outer join APS_IAM_INFO_CHIP          as Chip               on Chip.ChipId = App.chip_id
  left outer join APS_IAM_INFO_BC_APP_BASIC  as Catalog            on Catalog.ChipID = App.chip_id


association [1..*] to APS_IAM_INFO_FLP_CATEGORY as _LaunchpadTypeText on  _LaunchpadTypeText.KeyValue = SpacePage.FioriSpaceType
                                                                      and _LaunchpadTypeText.Language = $session.system_language
                                                                      and _LaunchpadTypeText.As4local = 'A'
association [0..1] to APS_TADIR                 as _Component         on  _Component.obj_name = $projection.FioriTransaction
                                                                      and _Component.object   = 'SIA6'
                                                                      and _Component.pgmid    = 'R3TR'
{
  key SpacePage.FioriSpaceId,
  key SpacePage.PageId,
  key AppDescriptorItem.tcode   as FioriID,
      SpacePage.FioriSpaceTitle,
      SpacePage.FioriSpaceDescription,
      SpacePage.PageTitle,
      SpacePage.PageDescription,
      SpacePage.FioriSpaceType,
      SpacePage.IsSpaceTemplate,
      SpacePage.IsSpaceTemplate as IsPageTemplate,
      _LaunchpadTypeText.LaunchpadCategoryText,
      //      PageUiadAssignment.TileId as AppTileId,

      PageUiadAssignment.TileType,
      PageUiadAssignment.UiadId as AppId,
      case
        when AppText.tile_title is not initial and AppText.tile_title is not null then AppText.tile_title
        when AppText.alt_smart_link_title is not initial then AppText.alt_smart_link_title
        else Chip.ChipTitle
      end                       as ApplicationText,
      case
        when AppText.tile_subtitle is not initial then AppText.tile_subtitle
        else Chip.ChipSubtitle
      end                       as AppSubtitle,
      AppDetails.app_id         as FioriTransaction,
      _Component.ach            as AppComponent,
      Catalog.IsMigrated
}