APS_IAM_INFO_CHIP

CDS View

IAM Info System: Fiori Chips

APS_IAM_INFO_CHIP is a CDS View in S/4HANA. IAM Info System: Fiori Chips. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
APS_IAM_INFO_FSP_APP_BASIC view_entity left_outer Fiori Space - Application Basic 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'IAM Info System: Fiori Chips'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity APS_IAM_INFO_CHIP
  as select from    /ui2/pb_c_chip  as Chip
    left outer join /ui2/pb_c_propt as PropertyText on  PropertyText.bag_parentid = Chip.referencechipid
                                                    and PropertyText.langu        = $session.system_language
                                                    and PropertyText.name         = 'display_title_text'
    left outer join /ui2/pb_c_propt as PropertySub  on  PropertyText.bag_parentid = Chip.referencechipid
                                                    and PropertyText.langu        = $session.system_language
                                                    and PropertyText.name         = 'display_subtitle_text'
{
  key Chip.id                    as ChipId,
  key PropertyText.bag_parentid  as BagParentid,
      Chip.referencechipid       as Referencechipid,
      Chip.tcode                 as Tcode,
      Chip.uiad_id               as UiadId,
      PropertyText.bag_parentid2 as BagParentid2,
      PropertyText.value         as ChipTitle,
      PropertySub.value          as ChipSubtitle
}

union

select from       /ui2/pb_c_chipm as ChipM
  left outer join /ui2/pb_c_propt as PropertyText on  PropertyText.bag_parentid = ChipM.referencechipid

                                                  and PropertyText.langu        = $session.system_language
                                                  and PropertyText.name         = 'display_title_text'
  left outer join /ui2/pb_c_propt as PropertySub  on  PropertyText.bag_parentid = ChipM.referencechipid

                                                  and PropertyText.langu        = $session.system_language
                                                  and PropertyText.name         = 'display_subtitle_text'
{
  key ChipM.id                   as ChipId,
  key PropertyText.bag_parentid  as BagParentid,
      ChipM.referencechipid      as Referencechipid,
      ''                         as Tcode,
      ChipM.uiad_id              as UiadId,
      PropertyText.bag_parentid2 as BagParentid2,
      PropertyText.value         as ChipTitle,
      PropertySub.value          as ChipSubtitle
}

Learn More