R_CONTRACTACCOUNTPARTNERTP

@AccessControl: { authorizationCheck: #MANDATORY,
                  personalData: { blocking: #REQUIRED,
                                  blockingIndicator: ['_BusinessPartner.IsBusinessPurposeCompleted'] },
                  privilegedAssociations: [ '_ContrAcctPrtnBusinessLock', '_Address', '_AlternativePayerAddress',
                                            '_CreatedByUser', '_CreatedByContactCard',
                                            '_LastChangedByUser', '_LastChangedByContactCard' ] }

@EndUserText.label: 'Contract Account Partner - TP'

@ObjectModel: { modelingPattern: #NONE,
                representativeKey: 'BusinessPartner',
                semanticKey: [ 'BusinessPartnerForEdit' ],
                sapObjectNodeType.name: 'ContractAccountPartner',
                usageType: { dataClass: #MASTER,
                             serviceQuality: #C,
                             sizeCategory: #XL } }

@AbapCatalog.extensibility: {
  extensible: true,
  elementSuffix: 'VKP',
  dataSources: [ '_Extension' ],
  quota: {
    maximumFields: 270,
    maximumBytes: 13400
  },
  allowNewCompositions: true
}

@VDM: { lifecycle.contract.type: #SAP_INTERNAL_API,
        viewType: #TRANSACTIONAL }

define view entity R_ContractAccountPartnerTP
  as select from I_ContractAccountPartner

  association        to parent R_ContractAccountTP     as _ContractAccount            on  _ContractAccount.ContractAccount = $projection.ContractAccount

  composition [0..*] of R_ContrAcctPrtnBusinessLockTP  as _ContrAcctPrtnBusinessLock
  composition [0..*] of R_ContrAcctPrtnCorrespncTP     as _ContrAcctPrtnCorrespnc
  composition [0..*] of R_ConAcctPrtnInvcgChrgDscTP    as _ContrAcctPrtnInvcgChrgAndDisc

  association [1..1] to I_ContractAccountPartnerUI     as _ContrAcctPrtnUI            on  $projection.ContractAccount = _ContrAcctPrtnUI.ContractAccount
                                                                                      and $projection.BusinessPartner = _ContrAcctPrtnUI.BusinessPartner
  association [0..1] to I_UserContactCard              as _CreatedByContactCard       on  $projection.CreatedByUser = _CreatedByContactCard.ContactCardID
  association [0..1] to I_UserContactCard              as _LastChangedByContactCard   on  $projection.LastChangedByUser = _LastChangedByContactCard.ContactCardID
  association [0..1] to I_User                         as _CreatedByUser              on  $projection.CreatedByUser = _CreatedByUser.UserID
  association [0..1] to I_User                         as _LastChangedByUser          on  $projection.LastChangedByUser = _LastChangedByUser.UserID



  //Address

  association [0..1] to I_CAContractPartnerAddress     as _Address                    on  $projection.BusinessPartner = _Address.BusinessPartner
                                                                                      and $projection.AddressID       = _Address.AddressNumber

  association [0..1] to I_CAContractPartnerAddress     as _AlternativePayerAddress    on  $projection.CAAlternativePayer = _AlternativePayerAddress.BusinessPartner
                                                                                      and $projection.AddressID          = _AlternativePayerAddress.AddressNumber
  //Payment Card

  association [0..1] to I_CAContractPartnerPaymentCard as _PaytCardForIncomingPayment on  $projection.BusinessPartner                = _PaytCardForIncomingPayment.BusinessPartner
                                                                                      and $projection.CAPaymentCardIDForIncomingPayt = _PaytCardForIncomingPayment.PaymentCardID
  association [0..1] to I_CAContractPartnerPaymentCard as _PaytCardForOutgoingPayment on  $projection.BusinessPartner                = _PaytCardForOutgoingPayment.BusinessPartner
                                                                                      and $projection.CAPaymentCardIDForOutgoingPayt = _PaytCardForOutgoingPayment.PaymentCardID
  //Bank

  association [0..1] to I_CAContractPartnerBank        as _BankForIncomingPayment     on  $projection.BusinessPartner             = _BankForIncomingPayment.BusinessPartner
                                                                                      and $projection.CABankIDForIncomingPayments = _BankForIncomingPayment.BankIdentification
  association [0..1] to I_CAContractPartnerBank        as _BankForOutgoingPayment     on  $projection.BusinessPartner             = _BankForOutgoingPayment.BusinessPartner
                                                                                      and $projection.CABankIDForOutgoingPayments = _BankForOutgoingPayment.BankIdentification

  //Determination code for alternative invoice form

  association [1..1] to I_CADetnCodeForAltvInvcFm      as _CADetnCodeForAltvInvcFm    on  $projection.CADetnCodeForAltvInvoiceForm = _CADetnCodeForAltvInvcFm.CADetnCodeForAltvInvoiceForm
  
  //Last day of billing period

  association [1..1] to I_CALastDayOfBillingPeriod     as _CALastDayOfBillingPeriod   on  $projection.CALastDayOfBillingPeriod = _CALastDayOfBillingPeriod.CALastDayOfBillingPeriod
  
  // Extensibility

  association [1..1] to E_ContractAccountPartner       as _Extension                  on  $projection.ContractAccount = _Extension.ContractAccount
                                                                                      and $projection.BusinessPartner = _Extension.BusinessPartner


{
      @ObjectModel.foreignKey.association: '_ContractAccount'
  key ContractAccount,
  key BusinessPartner,

      @ObjectModel.editableFieldFor: 'BusinessPartner'
      BusinessPartner                                                                                                  as BusinessPartnerForEdit,

      ContractAccountName,
      CreationDate,
      CreationTime,
      cast( dats_tims_to_tstmp( CreationDate, CreationTime, 'UTC', $session.client, 'NULL' ) as vdm_creationdatetime)  as ContrAcctPrtnCreationDateTime,
      CreatedByUser,
      IsMarkedForDeletion,
      LastChangeDate,
      LastChangeTime,

      cast( dats_tims_to_tstmp( LastChangeDate, LastChangeTime, 'UTC', $session.client, 'NULL' ) as vdm_lastchangedon) as ContrAcctPrtnLastChgDateTime,
      LastChangedByUser,
      CABankIDForIncomingPayments,
      CABankIDForOutgoingPayments,
      CAIncomingPaymentMethod,
      CACnctntdOutgPaymentMethods,
      CAFirstOutgoingPaymentMethod,
      CASecondOutgoingPaymentMethod,
      CAThirdOutgoingPaymentMethod,
      CAFourthOutgoingPaymentMethod,
      CAFifthOutgoingPaymentMethod,
      CAHouseBankReference,
      CAPaymentCardIDForIncomingPayt,
      CAPaymentCardIDForOutgoingPayt,
      SEPAMandate,
      CADunningProcedure,
      CADunningNoticeGroup,
      CACorrespondenceDunningProced,
      CACollectionsClerk,
      CACollectionsMasterDataGroup,
      CACollectionStrategy,
      CACollectionsContactPerson,
      ContractAccountForPayment,
      CABusinessPartnerForPayment,
      CAAlternativePayer,
      CAAlternativePayee,
      CAAlternativeDunningRecipient,
      CAAlternativeInvoiceRecipient,
      CAAlternativeCorrespncRcpnt,
      CAAddressIDOfAlternativePayer,
      CAAddressIDOfAlternativePayee,
      CAAddressIDOfAltvDunRecipient,
      CAAddressIDOfAltvInvoiceRcpnt,
      CACurrencyForDirectDebitLimit,
      CADirectDebitLimit,
      CANmbrMnthsForDirectDebitLimit,
      CADirectDebitLimitCalcMode,
      CAStartDateForBillingPeriod,
      ContrAcctPrtnHasInvcgChrgDsc,      
      CATargetCurrencyForInvoicing,
      CAInvcgCategory,
      CAInvcgSchedule,
      CABillgCycle,
      CALastDayOfBillingPeriod,
      CADetnCodeForAltvInvoiceForm,
      CABusinessPartnerForPosting,
      ContractAccountForPosting,
      CABusinessPartnerForInvcgList,
      ContractAccountForInvcgList,
      CAMasterAgreement,
      CAPartnerSettlementRule,
      ValdtyDateForWhldgTaxExmpCert,
      TaxJurisdiction,
      OutgPaytWithholdingTaxCode,
      IncgPaytWithholdingTaxCode,
      WithholdingTaxCertificate,
      CAAdditionalDaysForCashMgmt,
      CABusPartnerPostgLockExstcCode,
      CABusPartnerAddlLockExstcCode,
      CABusinessPartnerLockStartDate,
      CABusinessPartnerLockEndDate,
      CABPReferenceNumber,
      CACompanyCodeGroup,
      CAStandardCompanyCode,
      AltvContractAcctForCollvBills,
      CAInterestCode,
      CashPlanningGroup,
      CARelationshipOfBPToContrAcct,
      AddressID,
      CAAddressIDOfJurisdictionCode,
      CAAuthorizationGroup,
      CAToleranceGroup,
      CACorrespondenceVariant,
      PartnerCompany,
      CACorrespondenceActivityCode,
      CAClearingCategory,
      CADefaultClearingRstrcnCode,
      SupplyingCountry,
      BusinessPlace,
      CASubledgerApplication,
      PaymentCondition,
      CAAccountDeterminationCode,
      BusinessArea,
      CAPaymentCompanyCode,
      Country,
      /* used for bank details */
      // payer

      cast( case
        when CAAlternativePayer <> '' then CAAlternativePayer
        when CAAlternativePayer = '' then BusinessPartner
        end as gpart_kk preserving type )                                                                              as ContractAccountingPayer,
      // payee

      cast( case
        when CAAlternativePayee <> '' then CAAlternativePayee
        when CAAlternativePayee = '' then BusinessPartner
        end as gpart_kk preserving type )                                                                              as ContractAccountingPayee,

      /* Associations */
      _ContractAccount,
      _ContrAcctPrtnBusinessLock,
      _ContrAcctPrtnCorrespnc,
      _ContrAcctPrtnInvcgChrgAndDisc,
      _ContrAcctPrtnUI,


      _Address,
      _AcctDetnCode,
      _AlternativePayee,
      _AlternativePayer,
      _AlternativePayerAddress,
      _AltvContrAcc,
      _AltvCorrespncRcpnt,
      _AltvDunningRecipient,
      _AltvInvoiceRecipient,
      _BankForIncomingPayment,
      _BankForOutgoingPayment,
      _BillgCycle,
      _BPForInvcgList,
      _BPForPayment,
      _BPForPosting,
      _BusinessArea,
      _BusinessPartner,
      _BusinessPlace,
      _CAAuthorizationGroup,
      _CABusPrtnAddlLockExstcCode,
      _CABusPrtnPostgLockExstcCode,
      _CACorrespncActivityCode,
      _CADetnCodeForAltvInvcFm,
      _CADfltClearingRstrcnCode,
      _CADirectDebitLimitCalcMod,
      _CAFifthOutgoingPaymentMethod,
      _CAFirstOutgoingPaymentMethod,
      _CAFourthOutgoingPaymentMethod,
      _CAIncomingPaymentMethod,
      _CALastDayOfBillingPeriod,      
      _CAPartnerSettlementRule,
      _CASecondOutgoingPaymentMethod,
      _CashPlanningGroup,
      _CASubledgerApplication,
      _CAThirdOutgoingPaymentMethod,
      _ClearingCategory,
      _CollContactPerson,
      _CollectionsClerk,
      _CollectionStrategy,
      _CollMasterDataGroup,
      _CompCode,
      _CompCodeGroup,
      _ContrAcctForInvcgList,
      _ContrAcctForPayt,
      _ContrAcctForPosting,
      _CorrespncVar,
      _Country,
      _CreatedByContactCard,
      _CreatedByUser,
      _CurrencyForDDL,
      _CurrencyForInvoicing,
      _DunningProcedure,
      _CorrespncDunningProcedure,
      _DunNoticeGroup,
      _HouseBankRef,
      _InterestCode,
      _InvcgCategory,
      _InvcgSchedule,
      _LastChangedByUser,
      _LastChangedByContactCard,
      _MasterAgreement,
      _PartnerCompany,
      _PaytCardForIncomingPayment,
      _PaytCardForOutgoingPayment,
      _PaymentCompCode,
      _PaymentCondition,
      _RelshpOfBP,
      _SupplyingCountry,
      _ToleranceGroup
}