C_ContractAccountPartner

@AccessControl: { authorizationCheck: #MANDATORY,
                  personalData: { blocking: #REQUIRED,
                                  blockingIndicator: ['_BusinessPartner.IsBusinessPurposeCompleted'] } }

@EndUserText.label: 'Contract Account Partner'

@ObjectModel: { representativeKey: 'BusinessPartner',
                usageType: { dataClass: #TRANSACTIONAL,
                             sizeCategory: #XL,
                             serviceQuality: #C } }

@Search.searchable: true

@UI.headerInfo: { typeName: 'Contract Account',
                  typeNamePlural: 'Contract Accounts',
                  title.targetElement: 'ContractAccount' }

@VDM.viewType: #CONSUMPTION

define view entity C_ContractAccountPartner
  as projection on R_ContractAccountPartnerTP

{
      @Consumption: {
        filter: { mandatory: false , multipleSelections: true },
        semanticObject: 'ContractAccount'
      }
      @UI: {
        lineItem: [{position: 10 }, {type: #FOR_INTENT_BASED_NAVIGATION, semanticObjectAction: 'manage'}],
        selectionField: [{ position: 10 }]
      }
      @ObjectModel.text.element: ['ContractAccountName']
      @Search : {defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #HIGH}
      @Consumption.valueHelpDefinition: [
          { entity:  { name:    'I_ContractAccountPartnerStdVH',
                       element: 'ContractAccount' }
          }]
      @ObjectModel.foreignKey.association: '_ContractAccount'
      @UI.textArrangement: #TEXT_FIRST
  key ContractAccount,


      @Consumption: {
        filter: { mandatory: false , multipleSelections: true },
        semanticObject: 'CAContractPartner',
        valueHelpDefinition: [{ entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner'} }]
      }
      @UI: {
        lineItem: [{position: 20 }],
        selectionField: [{position: 20}]
      }
      @ObjectModel.text.element: ['BusinessPartnerFullName']
      @Semantics:   { contact.type: #PERSON }
      @Search : {defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #HIGH}
  key BusinessPartner,

      @Search : {defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #HIGH}
      @Consumption.filter.hidden: false
      //      @EndUserText.label: 'Contract Account Name'

      ContractAccountName,

      @Consumption.filter.hidden: true
      @UI.hidden: true
      _ContrAcctPrtnUI.BusinessPartnerFullName,

      @UI.lineItem: [{position: 30, label: 'Standard Company Code' }]
      @Consumption.semanticObject: 'CompanyCode'
      @Consumption.valueHelpDefinition: [{entity: { name: 'C_CACompanyCodeVH', element: 'CompanyCode'}}]
      @ObjectModel: { text.element:  [ 'CompanyCodeName' ] }
      @UI.selectionField: [{position: 30}]
      @UI.fieldGroup:[{ qualifier: 'Business Partner'}]
      @EndUserText.label: 'Standard Company Code'
      CAStandardCompanyCode,

      @ObjectModel.text.element: ['ContractAccountCategoryName']
      @EndUserText.label: 'Contract Account Category'
      @Search : {defaultSearchElement: true, fuzzinessThreshold: 0.7, ranking: #HIGH}
      _ContrAcctPrtnUI.ContractAccountCategory,

      @UI.hidden: true
      @Semantics.text

      _ContrAcctPrtnUI.ContractAccountCategoryName,

      @Consumption.filter.hidden: false
      @Consumption.filter.selectionType: #INTERVAL
      CreationDate,

      @Consumption.filter.hidden: false
      CreatedByUser,

      @Consumption.filter.hidden: true
      LastChangedByUser,

      @Consumption.filter.hidden: true
      @Consumption.filter.selectionType: #INTERVAL
      LastChangeDate,

      @Consumption.filter.hidden: true
      @EndUserText.label: 'Target Currency for Invoicing'
      CATargetCurrencyForInvoicing,

      @Consumption.filter.hidden: true
      CABPReferenceNumber,

      @Consumption.filter.hidden: true
      CACompanyCodeGroup,

      @UI.hidden
      _ContrAcctPrtnUI.CompanyCodeName,

      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner'} }]
      }
      @UI.fieldGroup:[{qualifier: 'AccountAssignment', groupLabel: 'Additional', importance: #HIGH}]
      @EndUserText.label: 'Alternative Payer'
      cast(CAAlternativePayer as abwre_gfn_kk preserving type ) as CAAlternativePayer,

      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner'} }]
      }
      @UI.fieldGroup:[{qualifier: 'AccountAssignment', groupLabel: 'Additional', importance: #HIGH}]
      @EndUserText.label: 'Alternative Payee'
      cast(CAAlternativePayee as abwra_gfn_kk preserving type ) as CAAlternativePayee,

      @Consumption: {
       valueHelpDefinition: [{ entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner'} }]
      }
      @UI.fieldGroup:[{qualifier: 'AccountAssignment', groupLabel: 'Additional', importance: #HIGH}]
      @EndUserText.label: 'Alternative Dunning Recipient'
      CAAlternativeDunningRecipient,

      @Consumption.filter.hidden: true
      @EndUserText.label: 'Alternative Correspondence Recipient'
      CAAlternativeCorrespncRcpnt,

      @Consumption.filter.hidden: true
      @EndUserText.label: 'Incoming Payment Method'
      CAIncomingPaymentMethod,

      @Consumption.filter.hidden: true
      IsMarkedForDeletion,

      @Consumption.filter.hidden: true
      CAInterestCode,

      @Consumption.filter.hidden: true
      CADunningProcedure,

      @Consumption.filter.hidden: true
      CADunningNoticeGroup,

      @Consumption.filter.hidden: true
      CAToleranceGroup,

      @Consumption.filter.hidden: true
      TaxJurisdiction,

      @Consumption.filter.hidden: true
      @EndUserText.label: 'Correspondence Variant'
      CACorrespondenceVariant,

      @Consumption.filter.hidden: true
      PartnerCompany,

      @Consumption.filter.hidden: true
      @EndUserText.label: 'Correspondence Dunning Procedure'
      CACorrespondenceDunningProced,

      @Consumption.filter.hidden: true
      CAClearingCategory,

      @Consumption.filter.hidden: true
      CADefaultClearingRstrcnCode,

      @Consumption.filter.hidden: true
      BusinessPlace,

      @Consumption.filter.hidden: true
      @UI.hidden: true
      CACollectionsClerk,

      @Consumption.filter.hidden: true
      CAInvcgCategory,

      //Collections

      @Consumption.filter.hidden: true
      @EndUserText.label: 'Collections Master Data Group'
      CACollectionsMasterDataGroup,

      @Consumption.filter.hidden: true
      @EndUserText.label: 'Collections Contact Person'
      CACollectionsContactPerson,

      @Consumption.filter.hidden: true
      CAMasterAgreement,

      @Consumption.filter.hidden: true
      CAPartnerSettlementRule,


      //Address

      @UI: {
        lineItem: [{ position: 40 }],
        fieldGroup: [{ qualifier: 'Address', groupLabel: 'Address', position: 10 ,importance: #HIGH }]
      }
      @Consumption.filter.hidden: true
      _ContrAcctPrtnUI.AddressLine1,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      @UI.hidden: true
      @Consumption.filter.hidden: true
      _ContrAcctPrtnUI.StreetName,

      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.9 }
      @UI.hidden: true
      @Consumption.filter.hidden: true
      _ContrAcctPrtnUI.HouseNumber,

      @UI: {
        lineItem: [{position: 50 }],
        fieldGroup: [{qualifier: 'Address' }]
      }
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'C_CAContractPartnerValueHelp', element: 'PostalCode'} }]
      }
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.9 }
      @Consumption.filter.hidden: true
      _ContrAcctPrtnUI.PostalCode,

      @UI: {
        lineItem: [{position: 60}],
        fieldGroup:[{qualifier: 'Address'}]
      }
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      @Consumption.filter.hidden: true
      _ContrAcctPrtnUI.CityName,

      @UI: {
        lineItem: [{position: 70 }],
        fieldGroup: [{qualifier: 'Address' }]
      }
      @Consumption: {
        valueHelpDefinition: [{ entity: { name: 'I_CountryVH', element: 'Country'} }]
      }
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8 }
      @UI.textArrangement: #TEXT_ONLY
      @EndUserText.label: 'Country / Region'
      @ObjectModel: { text.element:  ['CountryName']}
      _ContrAcctPrtnUI.Country,

      @UI.hidden: true
      _ContrAcctPrtnUI.CountryName,

      @Consumption.filter.hidden: true
      @EndUserText.label: 'Account Used for Payment'
      ContractAccountForPayment,

      @Consumption.filter.hidden: true
      CABusinessPartnerForPayment,

      CAAuthorizationGroup,

      //associations

      _ContractAccount,
      _ContrAcctPrtnUI,
      _BusinessPartner,
      _ContrAcctForPayt
}