I_PURCHASINGINFORECORD

@EndUserText.label: 'Purchasing Info Record'
@AbapCatalog.sqlViewName: 'IPURINFREC'
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'PurchasingInfoRecord'
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
//@VDM.lifecycle.contract.type: #SAP_INTERNAL_API

@AbapCatalog.preserveKey:true 

define view I_PurchasingInfoRecord
  as select from eina

  association [1..*] to I_PurgInfoRecdOrgPlantData as _PurgInfoRecdOrgPlantData on $projection.PurchasingInfoRecord = _PurgInfoRecdOrgPlantData.PurchasingInfoRecord

  association [1..1] to I_Material                 as _Material                 on $projection.Material = _Material.Material

  association [1..1] to I_Supplier                 as _Supplier                 on $projection.Supplier = _Supplier.Supplier

  association [1..1] to I_MaterialGroup            as _MaterialGroup            on $projection.MaterialGroup = _MaterialGroup.MaterialGroup

  association [0..1] to I_UnitOfMeasure            as _BaseUnit                 on $projection.BaseUnit = _BaseUnit.UnitOfMeasure

  association [0..1] to I_UnitOfMeasure            as _PurgDocOrderQuantityUnit on $projection.PurgDocOrderQuantityUnit = _PurgDocOrderQuantityUnit.UnitOfMeasure
  
  association [0..*] to I_SupplierPurchasingOrg    as _SupplierPurchasingOrg    on _SupplierPurchasingOrg.Supplier = $projection.Supplier
  
  association [0..1] to E_PurchasingInforecord     as _PurchasingInforecordExtension on  _PurchasingInforecordExtension.PurchasingInfoRecord = $projection.PurchasingInfoRecord


{
  key infnr              as PurchasingInfoRecord,
      //      @Consumption.valueHelpDefinition: [

      //        { entity:  { name:    'I_Supplier_Vh',

      //                     element: 'Supplier' }

      //                     }]

      @ObjectModel.foreignKey.association: '_Supplier'
      lifnr              as Supplier,
      //      @Consumption.valueHelpDefinition: [

      //        { entity:  { name:    'I_MaterialStdVH',

      //                     element: 'Material' }

      //        }]

      @ObjectModel.foreignKey.association: '_Material'
      matnr              as Material,
      //      @Consumption.valueHelpDefinition: [

      //        { entity:  { name:    'C_MM_MaterialGroupValueHelp',

      //                     element: 'MaterialGroup' }

      //        }]

      @ObjectModel.foreignKey.association: '_MaterialGroup'
// Inforecord Model - The original BO stores either Material or Material Group for every IR.

// However, we want to show Material Group for all inforecords regardless.

// Achieving it here results in ESH object error since case statements are not accepted.

//            case

//             when matkl = ''

//              then _Material.MaterialGroup

//             else

//              matkl

//            end    as MaterialGroup,

      //_Material.MaterialGroup,

      matkl              as MaterialGroup,

      @Semantics.businessDate.createdAt
      erdat              as CreationDate,

      loekz              as IsDeleted,
      
      ernam              as CreatedByUser,

      txz01              as PurchasingInfoRecordDesc,
      
      sortl              as PurgInfoRecNonStockItmSortTerm,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_PurgDocOrderQuantityUnit'
      meins              as PurgDocOrderQuantityUnit,

      umrez              as OrderItemQtyToBaseQtyNmrtr,

      umren              as OrderItemQtyToBaseQtyDnmntr,

      idnlf              as SupplierMaterialNumber,

      verkf              as SupplierRespSalesPersonName,

      telf1              as SupplierPhoneNumber,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_BaseUnit'
      lmein              as BaseUnit,

      wglif              as SupplierMaterialGroup,

      kolif              as PriorSupplier,

      @Semantics.businessDate.from
      lifab              as AvailabilityStartDate,

//      @Semantics.businessDate.to

      lifbi              as AvailabilityEndDate,

      vabme              as VarblPurOrdUnitIsActive,

      mfrnr              as Manufacturer,

      relif              as IsRegularSupplier,

      ltsnr              as SupplierSubrange,

      mahn1              as NoDaysReminder1,

      mahn2              as NoDaysReminder2,

      mahn3              as NoDaysReminder3,

      anzpu              as ProductPurchasePointsQty,

      punei              as ProductPurchasePointsQtyUnit,

      rueck              as ReturnAgreement,

      urztp              as SupplierCertOriginCat,

      urznr              as SupplierCertOriginNumber,

      urzdt              as SupplierCertValidityEndDate,

      urzla              as SupplierCertOriginCountry,

      regio              as SupplierCertOriginRegion,

      urzzt              as SuplrCertOriginClassfctnNumber,

      ltssf              as SupplierSubrangeSortNumber,

      lastchangedatetime as LastChangeDateTime,

      eina.iseopblocked  as IsEndOfPurposeBlocked,

      _PurgInfoRecdOrgPlantData,
      _Material,
      _MaterialGroup,
      _Supplier,
      _BaseUnit,
      _PurgDocOrderQuantityUnit,
      _SupplierPurchasingOrg   
}
where
     iseopblocked <> 'X'
  or iseopblocked = ''