I_DELIVERYDOCUMENTTYPE

CDS View

Delivery Document Type

I_DELIVERYDOCUMENTTYPE is a CDS View in S/4HANA. Delivery Document Type. 8 CDS views read from this table.

Used by 8 CDS view(s)

CDS Views using this table (8)

ViewTypeJoinVDMDescription
C_DelivTypeNoRefVH view from CONSUMPTION Delivery Document Types without a Reference Value Help
C_DelivTypeRefVH view from CONSUMPTION Delivery Document Types with a Reference Value Help
C_OutboundDeliveryTypeVH view_entity from CONSUMPTION Outbound Delivery Type Value Help
I_DeliveryDocumentTypeStdVH view_entity from COMPOSITE Delivery Document Type
I_MRPExtRqmtOrderTypeText view_entity union_all BASIC External Requirements Order Type - Text
P_AR_LengthOfRefDoc view inner COMPOSITE Private View to find the length of ReferenceDocument
P_MRPExtRqmtOrderType view_entity union_all BASIC External Requirements Order Type
P_SDDocumentType view union_all BASIC SD Document Type 
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'DeliveryDocumentType'
@ObjectModel.usageType.dataClass: #CUSTOMIZING
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #S
@EndUserText.label: 'Delivery Document Type'
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@VDM.viewType: #BASIC
@AccessControl.authorizationCheck:#NOT_REQUIRED
@AbapCatalog.sqlViewName: 'ILEDELIVDOCTYPE'
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations:true
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #ANALYTICAL_DIMENSION ]
@ObjectModel.modelingPattern: [ #ANALYTICAL_DIMENSION ]
@ObjectModel.sapObjectNodeType.name: 'DeliveryDocumentType'

define view I_DeliveryDocumentType
  as select from tvlk

  association [0..*] to I_DeliveryDocumentTypeText   as _Text                          on  $projection.DeliveryDocumentType = _Text.DeliveryDocumentType
  association [1..1] to I_SDDocumentCategory         as _SDDocumentCategory            on  $projection.SDDocumentCategory = _SDDocumentCategory.SDDocumentCategory
  association [0..1] to I_SalesDocumentType          as _SDDocumentType                on  $projection.DefaultOrderType = _SDDocumentType.SalesDocumentType
  association [0..1] to I_TextDeterminationProcedure as _TextDeterminationProcedure    on  $projection.TextDeterminationProcedure         = _TextDeterminationProcedure.TextDeterminationProcedure
                                                                                       and _TextDeterminationProcedure.TextObjectCategory = 'VBBK'
  association [0..1] to I_PartDeterminationProcedure as _PartnerDeterminationProcedure on  $projection.PartnerDeterminationProcedure = _PartnerDeterminationProcedure.PartnerDeterminationProcedure
  association [0..1] to I_UnitOfMeasure              as _ExtTransfOfCtrlDateOffsetUnit on  $projection.ExtTransfOfCtrlDateOffsetUnit = _ExtTransfOfCtrlDateOffsetUnit.UnitOfMeasure
  association [0..1] to I_UnitOfMeasure              as _IntTransfOfCtrlDateOffsetUnit on  $projection.IntTransfOfCtrlDateOffsetUnit = _IntTransfOfCtrlDateOffsetUnit.UnitOfMeasure
{
      @ObjectModel.text.association: '_Text'
  key lfart                as DeliveryDocumentType,

      @ObjectModel.foreignKey.association: '_SDDocumentCategory'
      vbtyp                as SDDocumentCategory,

      aufer                as PrecedingDocumentRequirement,

      @Semantics.booleanIndicator: true
      itmac                as TradeComplianceIsActive,

      numki                as NumberRangeForIntIDAssignment,

      numke                as NumberRangeForExtIDAssignment,

      incpo                as IncrementItemNumber,

      @ObjectModel.foreignKey.association: '_SDDocumentType'
      daart                as DefaultOrderType,

      reglg                as StorageLocationRule,

      @ObjectModel.foreignKey.association: '_TextDeterminationProcedure'
      txtgr                as TextDeterminationProcedure,

      routf                as RouteDetermination,

      @Semantics.booleanIndicator: true
      lnspl                as DeliveryIsSplitByWarehouse,

      @Semantics.booleanIndicator: true
      dsfad                as DeliveryIsSplitByPartner,

      @Semantics.booleanIndicator: true
      averp                as DeliveryIsPackedAutomatically,

      @Semantics.booleanIndicator: true
      pm_item_gen          as DelivItmsAreGnrtdForPackggMatl,

      @ObjectModel.foreignKey.association:'_PartnerDeterminationProcedure'
      pargr                as PartnerDeterminationProcedure,

      neute                as RescheduleDeliveries,

      @Semantics.quantity.unitOfMeasure: 'IntTransfOfCtrlDateOffsetUnit'
      int_tocd_offset      as IntTransfOfControlDateOffset,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association:'_IntTransfOfCtrlDateOffsetUnit'
      int_tocd_offset_unit as IntTransfOfCtrlDateOffsetUnit,

      @Semantics.quantity.unitOfMeasure: 'ExtTransfOfCtrlDateOffsetUnit'
      ext_tocd_offset      as ExtTransfOfControlDateOffset,

      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association:'_ExtTransfOfCtrlDateOffsetUnit'
      ext_tocd_offset_unit as ExtTransfOfCtrlDateOffsetUnit,

      j_1adoccls           as AR_ElectronicDocDocumentClass,


      //Associations

      _SDDocumentCategory,
      _SDDocumentType,
      _TextDeterminationProcedure,
      _PartnerDeterminationProcedure,
      _ExtTransfOfCtrlDateOffsetUnit,
      _IntTransfOfCtrlDateOffsetUnit,
      _Text
};

Learn More