I_MRPExtRqmtOrderTypeText

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'External Requirements Order Type - Text'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'OrderType'
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #CUSTOMIZING
}
@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #BASIC

@Search.searchable: true
define view entity I_MRPExtRqmtOrderTypeText 
as select from I_BillingDocumentType
association [0..1] to I_SDDocumentCategory as _DocumentCategory on  $projection.MRPOrderCategory = _DocumentCategory.SDDocumentCategory
{
      @ObjectModel.text.element: ['OrderTypeName']
  key cast ( BillingDocumentType as auart preserving type ) as OrderType,
      @ObjectModel.foreignKey.association: '_DocumentCategory'
  key SDDocumentCategory as MRPOrderCategory,
      @Semantics.language:true 
  key _Text.Language,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      _Text.BillingDocumentTypeName                         as OrderTypeName,
      
      _DocumentCategory
}
union all select from I_DeliveryDocumentType
association [0..1] to I_SDDocumentCategory as _DocumentCategory on  $projection.MRPOrderCategory = _DocumentCategory.SDDocumentCategory
{
  key cast ( DeliveryDocumentType as auart preserving type ) as OrderType,
  key SDDocumentCategory as MRPOrderCategory,
  key _Text.Language,
      _Text.DeliveryDocumentTypeName                         as OrderTypeName,
      
      _DocumentCategory
}
union all select from I_SalesDocumentType
association [0..1] to I_SDDocumentCategory as _DocumentCategory on  $projection.MRPOrderCategory = _DocumentCategory.SDDocumentCategory
{
  key cast ( SalesDocumentType as auart preserving type ) as OrderType,
  key SDDocumentCategory as MRPOrderCategory,
  key _Text.Language,
      _Text.SalesDocumentTypeName                         as OrderTypeName,
      
      _DocumentCategory
}
union all select from I_PurchasingDocumentType
association [0..1] to I_SDDocumentCategory as _DocumentCategory on  $projection.MRPOrderCategory = _DocumentCategory.SDDocumentCategory
{
  key cast ( PurchasingDocumentType as auart preserving type ) as OrderType,
  key PurchasingDocumentCategory as MRPOrderCategory,
  key _Text.Language,
      _Text.PurchasingDocumentTypeName                         as OrderTypeName,
      
      _DocumentCategory
}