I_DEFECTAFFECTEDOBJECT

CDS View

Object Affected by Defect

I_DEFECTAFFECTEDOBJECT is a CDS View in S/4HANA. Object Affected by Defect. It contains 10 fields. 3 CDS views read from this table.

Used by 3 CDS view(s) 10 fields

CDS Views using this table (3)

ViewTypeJoinVDMDescription
C_DefectAffectedObjectFDP view_entity from CONSUMPTION FDP view for QM Defect Affected Object
I_DefectAffectedObjectTP view from TRANSACTIONAL Object Affected by Defect
R_DefectAffectedObjectTP view_entity from TRANSACTIONAL Object Affected by Defect

Fields (10)

KeyField CDS FieldsUsed in Views
KEY DefectAffectedObject DefectAffectedObject 3
KEY DefectInternalID DefectInternalID 3
_DefectAffcdObjQuantityUnit _DefectAffcdObjQuantityUnit 1
_Product _Product 1
Batch Batch 3
Defect Defect 2
DefectAffcdObjQuantityUnit DefectAffcdObjQuantityUnit 3
DefectAffectedObjectQuantity DefectAffectedObjectQuantity 3
DefectAffectedObjectType DefectAffectedObjectType 3
Material Material,Product 3 
@EndUserText.label: 'Object Affected by Defect'
@VDM: {
    viewType: #BASIC,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck: #CHECK

@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M,
        serviceQuality: #A },
    representativeKey: 'DefectAffectedObject',
    semanticKey:  [ 'Defect', 'DefectAffectedObject' ]
}
@Analytics.technicalName: 'IDEFAFFCDOBJ'
@Metadata.ignorePropagatedAnnotations: true

define view entity I_DefectAffectedObject as select from qmfe_affctd_obj

  association [1..1] to I_Defect        as _Defect                     on $projection.DefectInternalID = _Defect.DefectInternalID
  association [0..1] to I_Product       as _Product                    on $projection.Material = _Product.Product
  association [0..1] to I_UnitOfMeasure as _DefectAffcdObjQuantityUnit on $projection.DefectAffcdObjQuantityUnit = _DefectAffcdObjQuantityUnit.UnitOfMeasure

  // Extension

  association [1..1] to E_DefectAffectedObject as _Extension           on $projection.DefectInternalID = _Extension.Notification
                                                                      and _Extension.NotificationItem = '0000'
                                                                      and $projection.DefectAffectedObject = _Extension.DefectAffectedObject

{
      @ObjectModel.foreignKey.association: '_Defect'
  key cast( qmnum as qdefectinternalid preserving type )         as DefectInternalID,
//  key fenum not used at Defect layer

  key objcounter            as DefectAffectedObject,
  
      // Use external Defect Id as part of the semantic key

      cast( substring(qmnum,2,11) as qdefectid preserving type ) as Defect,

//    Not decided yet if they are defined as fixed domain values or if there will be a (customizing) table 

      objtype               as DefectAffectedObjectType,
      
      @ObjectModel.foreignKey.association: '_Product'
      material              as Material,
      
      @Semantics.quantity.unitOfMeasure: 'DefectAffcdObjQuantityUnit'
      quantity              as DefectAffectedObjectQuantity,
      
      @ObjectModel.foreignKey.association: '_DefectAffcdObjQuantityUnit'
      quantityunit          as DefectAffcdObjQuantityUnit,
      
      batch                 as Batch,

//    Associations      

      _Defect,
      _Product,
      _DefectAffcdObjQuantityUnit

} where qmnum like '$%'
    and fenum = '0000'

Learn More