C_DefectAffectedObjectFDP

@AccessControl: {
    authorizationCheck: #MANDATORY,
    personalData.blocking: #BLOCKED_DATA_EXCLUDED
}
@EndUserText.label: 'FDP view for QM Defect Affected Object'
@VDM: {
    viewType: #CONSUMPTION,
    lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
    [ #OUTPUT_FORM_DATA_PROVIDER ]
@ObjectModel.modelingPattern: #OUTPUT_FORM_DATA_PROVIDER
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        sizeCategory: #M,
        serviceQuality: #D },
    representativeKey: 'DefectAffectedObject',
    semanticKey:  [ 'Defect', 'DefectAffectedObject' ]
}    
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@Consumption.semanticObject: 'Defect'

define view entity C_DefectAffectedObjectFDP as select from I_DefectAffectedObject as _DefectAffectedObject

    association [1..1] to C_DefectFDP               as _Defect                        on $projection.DefectInternalID = _Defect.DefectInternalID
  
    // associations which are missing in source view

    association [0..1] to I_DefectAffectedObjLastTask as _DefectAffectedObjLastTask   on  $projection.DefectInternalID     = _DefectAffectedObjLastTask.DefectInternalID
                                                                                      and $projection.DefectAffectedObject = _DefectAffectedObjLastTask.DefectAffectedObject
                                                    
    // new associations for text fields

    association [0..*] to I_UnitOfMeasureText       as _DefectAffcdObjQuantityUnitT   on $projection.DefectAffcdObjQuantityUnit = _DefectAffcdObjQuantityUnitT.UnitOfMeasure
    
    // Extension

    association [1..1] to E_DefectAffectedObject    as _Extension        on $projection.DefectInternalID = _Extension.Notification
                                                                        and _Extension.NotificationItem = '0000'
                                                                        and $projection.DefectAffectedObject = _Extension.DefectAffectedObject
  
{   
    @ObjectModel.foreignKey.association: '_Defect'
    key _DefectAffectedObject.DefectInternalID,
    key _DefectAffectedObject.DefectAffectedObject,
    
    _DefectAffectedObject.Defect,
    @Consumption.hidden: true
    _DefectAffectedObject.DefectAffectedObjectType,
    _DefectAffectedObject.Material as Product,
    _DefectAffectedObject._Product._Text[ 1: Language = $session.system_language ].ProductName,
    @Semantics.quantity.unitOfMeasure: 'DefectAffcdObjQuantityUnit'
    _DefectAffectedObject.DefectAffectedObjectQuantity,
    @ObjectModel.text.association: '_DefectAffcdObjQuantityUnitT'
    _DefectAffectedObject.DefectAffcdObjQuantityUnit,
    _DefectAffectedObject.Batch,
    _DefectAffectedObjLastTask.QltyTaskFollowUpAction,
    _DefectAffectedObjLastTask._QltyTaskFollowUpAction._QltyTaskFollowUpActionText[ 1: Language = $session.system_language ].QltyTaskFollowUpActionText,
    _DefectAffectedObjLastTask.QltyTaskFllwUpActionSts,
    _DefectAffectedObjLastTask._QltyTaskFllwUpActionSts._QltyTaskFllwUpActionStsTxt[ 1: Language = $session.system_language ].QltyTaskFllwUpActionStsTxt,
    _DefectAffectedObjLastTask.QualityTask,
    @Semantics.booleanIndicator: true
    case DefectAffectedObjectType
      when '01' 
        then
          case when Material is not initial and Material = _Defect.Product and Batch = _Defect.Batch
            then cast( 'X' as qfaffcdobjisdefective preserving type )
            else cast( ' ' as qfaffcdobjisdefective preserving type )
          end
        else cast( ' ' as qfaffcdobjisdefective preserving type )
    end                                                                    as DefectAffcdObjIsDefective,
    
    // Associations

    _DefectAffcdObjQuantityUnitT,
    
    // Association for ACL

    _Defect
}