UPOV_WCDPS_MEAS_VALUE

@AbapCatalog.sqlViewName: 'UPOS_WCDPMEAVAL'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@EndUserText.label: 'WCDPS - Choke Size and Tubing Pressure'
define view UPOV_WCDPS_MEAS_VALUE
  as select from    gho_imrg_std_h         as MeasStdHeader
    inner join      gho_iflot_ext          as WLfLoc         on  WLfLoc.tplnr           = MeasStdHeader.netobj
                                                             and WLfLoc.gho_netobj_type = 'GHO_WELL'
    left outer join gho_imrg_item          as ChokeSize      on ChokeSize.mdocm = MeasStdHeader.mdocm
    inner join      UPOV_WCDPS_MEATYPE_FLD as MeasTypChokSz  on  MeasTypChokSz.measmnt = ChokeSize.measmnt
                                                             and MeasTypChokSz.fldnm_r = 'CHO_SZ'
                                                             and MeasTypChokSz.fldnm_u = 'CHO_SZ_U'
    left outer join gho_imrg_item          as TubingPressure on TubingPressure.mdocm = MeasStdHeader.mdocm
    inner join      UPOV_WCDPS_MEATYPE_FLD as MeasTypTubPr   on  MeasTypTubPr.measmnt = TubingPressure.measmnt
                                                             and MeasTypTubPr.fldnm_r = 'TUB_PS'
                                                             and MeasTypTubPr.fldnm_u = 'TUB_PS_U'
{
  MeasStdHeader.mdocm,
  cast(cast(
  case
  when (ChokeSize.mdocm is null) then '0'
  when (ChokeSize.mdocm is not null and ChokeSize.recdv = '') then '0'
  else replace(ChokeSize.recdv,',','.')
  end
  as abap.numc( 22 ) ) as abap.quan( 13, 3 ))
                                          as ChokeSize,
  ChokeSize.recdu                         as ChokeSizeUnit,
  cast(cast(
  case
  when TubingPressure.mdocm is  null then '0'
  when (TubingPressure.mdocm is not null and TubingPressure.recdv = '') then '0'
  else replace(TubingPressure.recdv,',','.')
  end
   as abap.numc(22))as abap.quan( 13, 3 ))
                                          as TubingPressure,
  TubingPressure.recdu                    as TubingPressureUnit
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"UPOV_WCDPS_MEATYPE_FLD",
"GHO_IFLOT_EXT",
"GHO_IMRG_ITEM",
"GHO_IMRG_STD_H"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/