UPOV_UOM_WCDPS

@AbapCatalog.sqlViewName: 'UPOS_UOM_WCDPS'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@EndUserText.label: 'Well Completion Daily Pressures (UOM)'
define view UPOV_UOM_WCDPS
  as select from    gho_imrg_std_h        as MeasStdHeader
    inner join      gho_iflot_ext         as PNfLoc     on PNfLoc.tplnr = MeasStdHeader.netid
    inner join      gho_iflot_ext         as WCfLoc     on WCfLoc.gho_wc_ref_id = MeasStdHeader.netobj
    inner join      upot_int_nobj         as wlLabel    on wlLabel.tplnr = WCfLoc.gho_wc_ref_id
    inner join      upot_int_nobj         as wcLabel    on wcLabel.tplnr = WCfLoc.tplnr
    inner join      upot_int_wcdpsno      as wcdpsno    on wcdpsno.bus_key = MeasStdHeader.bus_key
    inner join      gho_imrg_ext          as MeasDocExt on MeasDocExt.mdocm = MeasStdHeader.mdocm
    inner join      gho_imptt_ext         as mpttExt    on mpttExt.measmnt_point = MeasDocExt.measmnt_point
    left outer join UPOV_WCDPS_MEAS_VALUE as MeasValue  on MeasValue.mdocm = MeasStdHeader.mdocm


{
  cast(wlLabel.converted_label as oiu_wl_no)                                                                                                                                                                                                                                                                                                                                 as  WL_NO, //Well ID number

  cast(wcLabel.converted_label as oiu_wc_no)                                                                                                                                                                                                                                                                                                                                 as  WC_NO, //Well Completion Number

  cast(dats_tims_to_tstmp(MeasDocExt.idate, MeasDocExt.itime,PNfLoc.gho_pn_tz,$session.client,'NULL') as oiu_eff_from_ts)                                                                                                                                                                                                                                                    as  EFF_FROM_TS, //Effective from timestamp

  cast( dats_tims_to_tstmp(
        cast(case MeasStdHeader.frequency
          when 'D' then MeasDocExt.idate
          when 'Y' then concat(concat(left(MeasDocExt.idate,4),'12'),'31')
          when 'M' then
      DATS_ADD_DAYS(DATS_ADD_MONTHS(cast( CONCAT(LEFT(MeasDocExt.idate, 6), '01') as abap.dats),1, 'UNCHANGED'),-1, 'UNCHANGED')
          else MeasDocExt.idate
          end as imrc_idate ), MeasDocExt.itime,PNfLoc.gho_pn_tz,$session.client,'NULL')  as oiu_eff_from_ts)                                                                                                                                                                                                                                                                as  EFF_TO_TS, //Effective to timestamp


  cast(cast(MeasValue.ChokeSize as abap.quan( 13, 3 )) as  oiu_cho_sz)                                                                                                                                                                                                                                                                                                       as  CHO_SZ, //Choke size

  cast(MeasValue.ChokeSizeUnit as  oiu_cho_sz_u)                                                                                                                                                                                                                                                                                                                             as  CHO_SZ_U, //Choke size unit

  cast(cast(MeasValue.TubingPressure as abap.quan( 13, 3 )) as  oiu_tub_ps)                                                                                                                                                                                                                                                                                                  as  TUB_PS, //Tubing pressure                                                                                                                                                                                                                                                        as  TUB_PS, //Tubing pressure

  cast(MeasValue.TubingPressureUnit  as  oiu_tub_ps_u)                                                                                                                                                                                                                                                                                                                       as  TUB_PS_U, //Tubing Pressure Unit

  cast(wcdpsno.wcdps_no  as  oiupr_wcdps_no)                                                                                                                                                                                                                                                                                                                                 as  WCDPS_NO, //WC daily pressures - header number

  cast(wcdpsno.doc_year  as  oiu_doc_year)                                                                                                                                                                                                                                                                                                                                   as  DOC_YEAR, //Document year

  MeasStdHeader.created_by                                                                                                                                                                                                                                                                                                                                                   as  OIU_CRUSER, //Name of Person Who Created Object

  MeasStdHeader.created_tst                                                                                                                                                                                                                                                                                                                                                  as  OIU_TIMESTAMP //UTC Time Stamp in Short Form (YYYYMMDDhhmmss)


}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"UPOV_WCDPS_MEAS_VALUE",
"GHO_IFLOT_EXT",
"GHO_IMPTT_EXT",
"GHO_IMRG_EXT",
"GHO_IMRG_STD_H",
"UPOT_INT_NOBJ",
"UPOT_INT_WCDPSNO"
],
"ASSOCIATED":
[],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/