SEPMRA_I_QuantityUnit

@AbapCatalog: {
  sqlViewName: 'SEPMRAIQUANU',
  compiler.compareFilter: true
}

@ClientHandling: {
   type:      #CLIENT_DEPENDENT,
   algorithm: #SESSION_VARIABLE
}

@ObjectModel: {
  representativeKey: 'UnitOfMeasure',
  resultSet: {
    sizeCategory:   #XS       -- display as drop-down list 
  },
  usageType: {
    serviceQuality: #A,
    sizeCategory:   #S,
    dataClass:      #CUSTOMIZING
  }
}

@Search.searchable: true


@AccessControl.authorizationCheck: #NOT_REQUIRED  -- no data access restriction needed: this is a simple code list


@UI.headerInfo: {
  typeName:       'Quantity Unit',
  typeNamePlural: 'Quantity Units',
  typeImageUrl:   'sap-icon://compare',

  title:          { value: 'UnitOfMeasure' }
}

@EndUserText.label: 'Quantity Unit'
define view SEPMRA_I_QuantityUnit
  as select from t006 as UnitOfMeasure

  association [0..*] to SEPMRA_I_UnitOfMeasureText as _Text on $projection.UnitOfMeasure = _Text.UnitOfMeasure

{
      @Search:      { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH }
      @ObjectModel: { text.association: '_Text' }
      @UI.lineItem: [
        { position: 1, importance: #HIGH, type: #STANDARD }
      ]
      @UI.identification: [
        { position: 1, importance: #HIGH, type: #STANDARD }
      ]
  key cast( UnitOfMeasure.msehi as sepmra_quantityunit preserving type ) as UnitOfMeasure,

      @Consumption: {
        filter.hidden: true
      }
      UnitOfMeasure.isocode                                              as UnitOfMeasureISOCode,

      /* associations */
      _Text
}
where
      UnitOfMeasure.dimid      =  'AAAADL'
  and UnitOfMeasure.isocode    <> ''
  and UnitOfMeasure.temp_unit  =  ''
  and UnitOfMeasure.press_unit =  ''
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T006"
],
"ASSOCIATED":
[
"SEPMRA_I_UNITOFMEASURETEXT"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/