SEPMRA_I_UnitOfMeasureText

@AbapCatalog: {
  sqlViewName: 'SEPMRAIUOMTEXT',
  compiler.compareFilter: true
}

@ClientHandling: {
  type:      #CLIENT_DEPENDENT,
  algorithm: #SESSION_VARIABLE
}

@ObjectModel: {
  dataCategory:      #TEXT,
  representativeKey: 'UnitOfMeasure',
  usageType: {
    serviceQuality: #B,
    sizeCategory:   #M,
    dataClass:      #CUSTOMIZING
  }
}

@Search.searchable: true
@AccessControl.authorizationCheck: #NOT_REQUIRED  -- this view is a text view used in code lists

@EndUserText.label: 'Unit of Measure Text'
define view SEPMRA_I_UnitOfMeasureText
  as select from t006a as Text

  association [0..1] to I_Language as _Language on $projection.Language = _Language.Language
{
      @Semantics: { unitOfMeasure: true }
  key cast( Text.msehi as sepmra_unitofmeasure preserving type ) as UnitOfMeasure,

      @Semantics:   { language: true }
      @ObjectModel: { foreignKey.association: '_Language' }
  key cast( Text.spras as sepmra_language preserving type )      as Language,


      @Search:    { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8 }
      -- TODO: This is actually a text field; but annotating it accordingly would break SADL text denormalization because SADL can handle single text fields only!
      //      @Semantics: { text: true }

      Text.mseht                                                 as UnitOfMeasureName,

      @Search:    { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8 }
      -- TODO: This is actually a text field; but annotating it accordingly would break SADL text denormalization because SADL can handle single text fields only!
      //      @Semantics: { text: true }

      Text.msehl                                                 as UnitOfMeasureLongName,

      @Search:    { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      -- TODO: This is actually a text field; but annotating it accordingly would break SADL text denormalization because SADL can handle single text fields only!
      -- @Semantics: { text: true }
      Text.mseh3                                                 as UnitOfMeasureCommercialName,

      @Search:    { defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8 }
      @Semantics: { text: true }
      Text.mseh6                                                 as UnitOfMeasureTechnicalName,

      ----------------------------------------------------------------------------------------------------------------
      -- Associations                                                                                               --
      ----------------------------------------------------------------------------------------------------------------
      _Language
}  
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"T006A"
],
"ASSOCIATED":
[
"I_LANGUAGE"
],
"BASE":
[],
"ANNO_REF":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/