SEPMRA_C_CurrencyValueHelp

@AbapCatalog: {
  sqlViewName:  'SEPMRACCURRVH',
  compiler.compareFilter: true
}

@ClientHandling: {
  type:      #CLIENT_DEPENDENT,
  algorithm: #SESSION_VARIABLE
}

@ObjectModel: {
  representativeKey: 'Currency',
  usageType: {
    serviceQuality: #B,
    sizeCategory:   #S,
    dataClass:      #CUSTOMIZING
  }
}

@EndUserText.label: 'Currency'


@Search.searchable: true

@AccessControl.authorizationCheck: #NOT_REQUIRED  -- no data access restriction needed: this is a simple code list

@UI.headerInfo: {
  typeName:       'Currency',
  typeNamePlural: 'Currencies',
  typeImageUrl:   'sap-icon://lead',

  title:          { type: #STANDARD, value: 'Currency' }
}

define view SEPMRA_C_CurrencyValueHelp
  as select from I_Currency as Currency

{
      @Search:      {
        defaultSearchElement: true,
        ranking:              #HIGH,
        fuzzinessThreshold:   0.75
      }
      @UI.lineItem: [
        { position: 1, importance: #HIGH, type: #STANDARD }
      ]
      @UI.identification: [
        { position: 1, importance: #HIGH, type: #STANDARD }
      ]
      @ObjectModel: {
        text.element: ['CurrencyT']
      }
  key Currency.Currency,

      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.8
      }
      @Consumption: {
        groupWithElement: 'Currency'
      }
      @Semantics: {
        text: true
      }
      @EndUserText: {
         label:     'Name',
         quickInfo: 'Currency Name'
      }
      _Text[1: Language = $session.system_language].CurrencyName as CurrencyT
}
where
  Currency.CurrencyISOCode = Currency.Currency
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_CURRENCY",
"I_CURRENCYTEXT"
],
"ASSOCIATED":
[],
"BASE":
[],
"VERSION":0
}
}*/