R_TransportationOrderStopTP

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl: {
  authorizationCheck: #MANDATORY,
  privilegedAssociations: [
    '_TranspOrdExecTranspActyDep',
    '_TranspOrdExecTranspActyArr',
    '_CapacityStop',
    '_TranspOrdExecution'
  ]
}
@EndUserText.label: 'Transportation Order Stop - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    },
    semanticKey: ['TransportationOrderStop'],
    representativeKey: 'TransportationOrderStopUUID'
}

define view entity R_TransportationOrderStopTP
  as select from I_TransportationOrderStop as TransportationOrderStop
  /* We must join I_TransportationOrder to make I_TransportationOrder.TransportationOrderCategory available in the
   * projection views to filter by TransportationOrderCategory
   */
    inner join   I_TransportationOrder     as TransportationOrder on TransportationOrder.TransportationOrderUUID = TransportationOrderStop.TransportationOrderUUID
  association to parent R_TransportationOrderTP        as _TransportationOrder on $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID
  composition [0..*] of R_TransportationOrderStageTP   as _TranspOrderStage
  composition [0..1] of R_TrOrdStopLocAddrDfltRprstnTP as _TrOrdStopLocAddrDfltRprstn
{
      /* Attributes */

      // Identification

  key TransportationOrderStop.TransportationOrderStopUUID,
      TransportationOrderStop.TransportationOrderUUID,
      TransportationOrderStop.TransportationOrderStop,
      TransportationOrderStop.TranspOrdStopStopParentUUID, // Stop Hierarchies are currently not supported in S/4HANA Cloud


      // Key Characteristics

      TransportationOrderStop.TranspOrdStopCategory,
      TransportationOrderStop.TranspOrdStopRole,

      // Location

      TransportationOrderStop.LocationAdditionalUUID, // This is the RAW16 UUID of the Location; LocationUUID is the CHAR22 GUID

      TransportationOrderStop.LocationId,
      TransportationOrderStop.TranspOrdStopLocUNCode   as LocationUNCode,
      TransportationOrderStop.TranspOrdStopLocIATACode as LocationIATACode,

      // Dates and Times

      TransportationOrderStop.TranspOrdStopAccptblStrtDteTme,
      TransportationOrderStop.TranspOrdStopReqStartDteTme,
      TransportationOrderStop.TranspOrdStopReqEndDteTme,
      TransportationOrderStop.TranspOrdStopAccptblEndDteTme,

      TransportationOrderStop.TranspOrdStopPlanTranspDteTme,
      TransportationOrderStop.TranspOrdStopDteTme,

      TransportationOrderStop.TranspOrdStopApptStrtDteTme,
      TransportationOrderStop.TranspOrdStopApptEndDteTme,

      TransportationOrderStop.TranspStopCarrConfStrtDteTme,
      TransportationOrderStop.TranspStopCarrConfEndDteTme,

      TransportationOrderStop.TranspOrdStopDocCutOffDateTime,
      TransportationOrderStop.TranspOrdStopCrgoCutOffDteTme,
      TransportationOrderStop.TranspOrdStopVGMCutOffDateTime,

      // Further Attributes

      TransportationOrderStop.TranspOrdStopSequencePosition,

      // References to Capacity Documents

      TransportationOrderStop.TranspOrdCapacityStopUUID,
      TransportationOrderStop.TranspOrdStopCapacityItemUUID,

      // Status

      TransportationOrderStop.TranspOrdStopHndlgExecStatus,
      @Semantics.booleanIndicator
      TransportationOrderStop.TranspOrdStopExecIsBlocked,

      // (Technical/Hidden) Attributes

      TransportationOrder.TransportationOrderCategory,

      /* Associations */
      TransportationOrderStop._CapacityStop,
      TransportationOrderStop._LocationAdditional,
      TransportationOrderStop._LocationDescription,
      TransportationOrderStop._TranspHndlgExecStatus,
      TransportationOrderStop._TranspOrdExecTranspActyArr,
      TransportationOrderStop._TranspOrdExecTranspActyDep,
      TransportationOrderStop._TranspOrdExecution,
      TransportationOrderStop._TranspOrdStopCategory,
      TransportationOrderStop._TranspOrdStopRole,
      _TransportationOrder,
      _TranspOrderStage,
      _TrOrdStopLocAddrDfltRprstn
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_TRANSPORTATIONORDER",
"I_TRANSPORTATIONORDERSTOP"
],
"ASSOCIATED":
[
"I_LOCATIONBASIC",
"I_TMLOCATIONDESCRIPTION",
"I_TRANSPHNDLGEXECSTATUS",
"I_TRANSPORDEXECTRANSPACTY",
"I_TRANSPORDEXECUTION",
"I_TRANSPORDSTOPCATEGORY",
"I_TRANSPORDSTOPROLE",
"I_TRANSPORTATIONORDERSTOP",
"R_TRANSPORTATIONORDERSTAGETP",
"R_TRANSPORTATIONORDERTP",
"R_TRORDSTOPLOCADDRDFLTRPRSTNTP"
],
"BASE":
[
"I_TRANSPORTATIONORDERSTOP"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/