R_TransportationOrderStageTP

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl: {
  authorizationCheck: #MANDATORY,
  privilegedAssociations: [
    '_TranspOrdStageSrceStop',
    '_TranspOrdStageDestStop'
  ]
}
@EndUserText.label: 'Transportation Order Stage - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    },
    semanticKey: ['TransportationOrderStage'],
    representativeKey: 'TransportationOrderStageUUID'
}
@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  elementSuffix: 'TSS',
  quota: {
    maximumFields: 408, //This is calculated with formula - 2* <Customer Percentage from SCFD_REGISTRY> * <max number of fields in SCFD_REGISTRY>

    maximumBytes: 8160  //This is calculated with formula - 4* <Customer Percentage from SCFD_REGISTRY> * <number of chars as defined in SCFD_REGISTRY>

  }
}

define view entity R_TransportationOrderStageTP
  as select from I_TransportationOrderStage as TransportationOrderStage
  /* We must join I_TransportationOrder to make I_TransportationOrder.TransportationOrderCategory available in the
   * projection views to filter by TransportationOrderCategory
   */
    inner join   I_TransportationOrder                     as TransportationOrder on TransportationOrder.TransportationOrderUUID = TransportationOrderStage.TransportationOrderUUID
  composition [0..*] of R_TrOrdStgeBPAddrDfltRprstnTP      as _TrOrdStgeBPAddrDfltRprstn
  association        to parent R_TransportationOrderStopTP as _TranspOrderStop     on $projection.TranspOrdStageSrceStopUUID = _TranspOrderStop.TransportationOrderStopUUID
  association [1..1] to R_TransportationOrderTP            as _TransportationOrder on $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID
  
  association [0..1] to R_TrOrdStgeBPAddrDfltRprstnTP      as _ExectgCarrierAddrDfltRprstn on $projection.TransportationOrderStageUUID  = _ExectgCarrierAddrDfltRprstn.TransportationOrderStageUUID
                                                                                          and _ExectgCarrierAddrDfltRprstn.TranspOrdBizPartnerFunction = 'TJ'
  association [0..1] to R_TrOrdStgeBPAddrDfltRprstnTP      as _InvcgCarrierAddrDfltRprstn  on $projection.TransportationOrderStageUUID  = _InvcgCarrierAddrDfltRprstn.TransportationOrderStageUUID
                                                                                          and _InvcgCarrierAddrDfltRprstn.TranspOrdBizPartnerFunction  = 'U3'  
  //Extension Association

  association [1]    to E_TransportationOrderStage         as _Extension           on $projection.TransportationOrderStageUUID = _Extension.TransportationOrderStageUUID
{
      /* Attributes */
      // Identification

  key TransportationOrderStage.TransportationOrderStageUUID,
      TransportationOrderStage.TransportationOrderUUID,
      TransportationOrderStage.TransportationOrderStage,

      // Key Characteristics

      TransportationOrderStage.TranspOrdStageType,
      TransportationOrderStage.TranspOrdStageCategory,
      TransportationOrderStage.TransportationMode,
      TransportationOrderStage.TransportationModeCategory,
      TransportationOrderStage.TranspOrdStageShippingType as TransportationShippingType,
      TransportationOrderStage.TranspOrdStageVoyage,
      TransportationOrderStage.TranspOrdStageVessel,
      TransportationOrderStage.TranspOrdStageFlight,

      // Parties

      TransportationOrderStage.TranspOrdStgeInvcgCarrLvl,

      TransportationOrderStage.CarrierUUID,
      TransportationOrderStage.Carrier,
      TransportationOrderStage.TranspOrdStageSCACCode,

      TransportationOrderStage.TranspOrdStgeInvcgCarrUUID,
      TransportationOrderStage.TranspOrdStageInvoicingCarrier,
      TransportationOrderStage.TranspOrdStgeInvcgSCACCode,

      TransportationOrderStage.TranspOrdStageAirlineIATACode,

      // Distance and Duration

      @Semantics.quantity.unitOfMeasure: 'TranspOrdStageDistanceUnit'
      TransportationOrderStage.TranspOrdStageDistance,
      TransportationOrderStage.TranspOrdStageDistanceUnit,
      TransportationOrderStage.TranspOrdStageNetDuration,


      TransportationOrderStage.TranspOrdStageSrceStopUUID,
      TransportationOrderStage.TranspOrdStageDestStopUUID,
      TransportationOrderStage.TranspOrdStageDestStopCategory,
      TransportationOrderStage.MeansOfTransport           as TranspOrdStageMeansOfTransport,
      TransportationOrderStage.TranspOrdStageAirWayBill,
      TransportationOrderStage.TranspOrdStageIMOShip,

      // (Technical/Hidden) Attributes

      TransportationOrder.TransportationOrderCategory,

      /* Associations */
      TransportationOrderStage._Carrier,
      TransportationOrderStage._MeansOfTransport,
      TransportationOrderStage._TranspAirlineIATACode,
      TransportationOrderStage._TranspOrdStageCategory,
      TransportationOrderStage._TranspOrdStageDestStop,
      TransportationOrderStage._TranspOrdStageSrceStop,
      TransportationOrderStage._TranspOrdStageType,
      TransportationOrderStage._TransportationMode,
      TransportationOrderStage._TransportationModeCategory,
      _TransportationOrder,
      _TrOrdStgeBPAddrDfltRprstn,
      _ExectgCarrierAddrDfltRprstn,
      _InvcgCarrierAddrDfltRprstn,
      _TranspOrderStop

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_TRANSPORTATIONORDER",
"I_TRANSPORTATIONORDERSTAGE"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_MEANSOFTRANSPORT",
"I_TRANSPAIRLINEIATACODE",
"I_TRANSPORDSTAGECATEGORY",
"I_TRANSPORDSTAGETYPE",
"I_TRANSPORTATIONMODE",
"I_TRANSPORTATIONMODECATEGORY",
"I_TRANSPORTATIONORDERSTOP",
"R_TRANSPORTATIONORDERSTOPTP",
"R_TRANSPORTATIONORDERTP",
"R_TRORDSTGEBPADDRDFLTRPRSTNTP"
],
"BASE":
[
"I_TRANSPORTATIONORDERSTAGE"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/