R_TransportationOrderItemTP

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl: {
  authorizationCheck: #MANDATORY,
  privilegedAssociations: [
    '_TranspOrdItemParentItem',
    '_SourceStop',
    '_DestinationStop'
  ]
}
@EndUserText.label: 'Transportation Order Item - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@VDM.viewType: #TRANSACTIONAL
@ObjectModel: {
    usageType: {
        sizeCategory: #L,
        serviceQuality: #C,
        dataClass:#TRANSACTIONAL
    },
    semanticKey: ['TranspOrdItem'],
    representativeKey: 'TransportationOrderItemUUID'
}

@AbapCatalog.extensibility: {
  extensible: true,
  dataSources: ['_Extension'],
  elementSuffix: 'TOI',
  quota: {
    maximumFields: 408, //This is calculated with formula - 2* <Customer Percentage from SCFD_REGISTRY> * <max number of fields in SCFD_REGISTRY>

    maximumBytes: 8160  //This is calculated with formula - 4* <Customer Percentage from SCFD_REGISTRY> * <number of chars as defined in SCFD_REGISTRY>

  }
}

define view entity R_TransportationOrderItemTP
  as select from I_TransportationOrderItem as TransportationOrderItem
  /* We must join I_TransportationOrder to make I_TransportationOrder.TransportationOrderCategory available in the
   * projection views to filter by TransportationOrderCategory  */
    inner join   I_TransportationOrder     as TransportationOrder on TransportationOrder.TransportationOrderUUID = TransportationOrderItem.TransportationOrderUUID
  composition [0..*] of R_TranspOrdItemSealTP          as _TranspOrdItemSeal
  composition [0..*] of R_TranspOrdItemDocRefTP        as _TranspOrdItemDocRef
  composition [0..*] of R_TranspOrdItemCommodityCodeTP as _TranspOrdItemCommodityCode
  composition [0..*] of R_TrOrdItmMnBPAddrDfltRprstnTP as _TrOrdItmMnBPAddrDfltRprstn
  composition [0..*] of R_TranspOrdItemNoteTP          as _TranspOrdItemNote
  association     to parent R_TransportationOrderTP    as _TransportationOrder       on $projection.TransportationOrderUUID      = _TransportationOrder.TransportationOrderUUID
  association [0..1] to R_TrOrdItmMnBPAddrDfltRprstnTP as _ShipperAddrDfltRprstn     on $projection.TransportationOrderItemUUID  = _ShipperAddrDfltRprstn.TransportationOrderItemUUID
                                                                                    and _ShipperAddrDfltRprstn.TranspOrdBizPartnerFunction   = 'U6'
  association [0..1] to R_TrOrdItmMnBPAddrDfltRprstnTP as _ConsigneeAddrDfltRprstn   on $projection.TransportationOrderItemUUID  = _ConsigneeAddrDfltRprstn.TransportationOrderItemUUID
                                                                                    and _ConsigneeAddrDfltRprstn.TranspOrdBizPartnerFunction = 'WE'  
  //Extension Association

  association [1] to E_TransportationOrderItem         as _Extension               on $projection.TransportationOrderItemUUID = _Extension.TransportationOrderItemUUID
{
      /* Attributes */
      // Identification

  key TransportationOrderItem.TransportationOrderItemUUID,
      TransportationOrderItem.TransportationOrderUUID,
      TransportationOrderItem.TranspOrdItem,
      TransportationOrderItem.TranspOrdItemType,
      TransportationOrderItem.TranspOrdItemCategory,

      TransportationOrderItem.TranspOrdItemParentItemUUID,
      TransportationOrderItem.TranspOrdItemDesc,
      @Semantics.booleanIndicator
      TransportationOrderItem.IsMainCargoItem,
      TransportationOrderItem.TransportationMode,
      TransportationOrderItem.TransportationModeCategory,
      TransportationOrderItem.MeansOfTransport               as TranspMeansOfTransport,
      TransportationOrderItem.TranspOrdItemSorting,

      // Locations

      TransportationOrderItem.SourceStopUUID,
      TransportationOrderItem.DestinationStopUUID,

      // Parties

      TransportationOrderItem.ShipperUUID,
      TransportationOrderItem.Shipper,
      TransportationOrderItem.ShipperAddressID,
      TransportationOrderItem.ConsigneeUUID,
      TransportationOrderItem.Consignee,
      TransportationOrderItem.ConsigneeAddressID,

      // Document References

      TransportationOrderItem.FreightUnitUUID,
      TransportationOrderItem.PredecessorTransportationOrder,
      TransportationOrderItem.TranspOrdDocReferenceID        as TranspBaseDocument,
      TransportationOrderItem.TranspOrdDocReferenceType      as TranspBaseDocumentType,
      TransportationOrderItem.TranspOrdDocReferenceItmID     as TranspBaseDocumentItem,
      TransportationOrderItem.TranspOrdDocReferenceItmType   as TranspBaseDocumentItemType,

      // Equipment Attributes

      TransportationOrderItem.TranspOrdItmEquipmentGroup     as TransportationEquipmentGroup,
      TransportationOrderItem.TranspOrdItmEquipmentType      as TransportationEquipmentType,
      TransportationOrderItem.TranspOrdItmCtnIsShprOwnd      as TranspEquipmentIsShipperOwned,
      TransportationOrderItem.TranspOrdActvVehRscePltNmbr    as TranspEquipmentPlateNumber,
      TransportationOrderItem.TranspOrdItmRegnCtryReg        as TranspEquipRegistrationCountry,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityUnit'
      TransportationOrderItem.TranspOrdItemCapacityLength    as TranspEquipCapacityLength,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityUnit'
      TransportationOrderItem.TranspOrdItemCapacityWidth     as TranspEquipCapacityWidth,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityUnit'
      TransportationOrderItem.TranspOrdItemCapacityHeight    as TranspEquipCapacityHeight,
      TransportationOrderItem.TranspOrdItemCapacityUnit      as TranspEquipCapacityUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityWeightUnit'
      TransportationOrderItem.TranspOrdItmCapGrossWeight     as TranspEquipCapacityWeight,
      TransportationOrderItem.TranspOrdItmCapGrossWeightUnit as TranspEquipCapacityWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspEquipCapacityVolumeUnit'
      TransportationOrderItem.TranspOrdItmCapGrossVolume     as TranspEquipCapacityVolume,
      TransportationOrderItem.TranspOrdItmCapGrossVolumeUnit as TranspEquipCapacityVolumeUnit,

      // Package Attributes

      TransportationOrderItem.TranspOrdItemPackageID,

      // Product Attributes

      TransportationOrderItem.ProductUUID,
      TransportationOrderItem.ProductID,
      TransportationOrderItem.MaterialFreightGroup,
      TransportationOrderItem.TransportationGroup,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemTemperatureUnit'
      TransportationOrderItem.TranspOrdItmMinTemp,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemTemperatureUnit'
      TransportationOrderItem.TranspOrdItmMaxTemp,
      TransportationOrderItem.TranspOrdItemTemperatureUnit,

      // Quantities

      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemQuantityUnit'
      TransportationOrderItem.TranspOrdItemQuantity,
      TransportationOrderItem.TranspOrdItemQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemGrossWeightUnit'
      TransportationOrderItem.TranspOrdItemGrossWeight,
      TransportationOrderItem.TranspOrdItemGrossWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemGrossVolumeUnit'
      TransportationOrderItem.TranspOrdItemGrossVolume,
      TransportationOrderItem.TranspOrdItemGrossVolumeUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdItemNetWeightUnit'
      TransportationOrderItem.TranspOrdItemNetWeight,
      TransportationOrderItem.TranspOrdItemNetWeightUnit,

      // Status

      TransportationOrderItem.TranspOrdItemHndlgExecStatus,
      TransportationOrderItem.TranspOrdItemDngrsGdsSts,

      // (Technical/Hidden) Attributes

      TransportationOrder.TransportationOrderCategory,

      /* Associations */
      TransportationOrderItem._BusTransDocTypeCode,
      TransportationOrderItem._Consignee,
      TransportationOrderItem._DestinationStop,
      TransportationOrderItem._MaterialFreightGroup,
      TransportationOrderItem._MeansOfTransport,
      TransportationOrderItem._PrdcssrTransportationOrder,
      TransportationOrderItem._Product,
      TransportationOrderItem._Shipper,
      TransportationOrderItem._SourceStop,
      TransportationOrderItem._TranspOrdItemCategory,
      TransportationOrderItem._TranspOrdItemGrossVolumeUnit,
      TransportationOrderItem._TranspOrdItemGrossWeightUnit,
      TransportationOrderItem._TranspOrdItemNetWeightUnit,
      TransportationOrderItem._TranspOrdItemParentItem,
      TransportationOrderItem._TranspOrdItemQuantityUnit,
      TransportationOrderItem._TranspOrdItemType,
      TransportationOrderItem._TransportationGroup,
      TransportationOrderItem._TransportationMode,
      TransportationOrderItem._TransportationModeCategory,
      _TransportationOrder,
      _TranspOrdItemSeal,
      _TranspOrdItemDocRef,
      _TranspOrdItemCommodityCode,
      _TrOrdItmMnBPAddrDfltRprstn,
      _ShipperAddrDfltRprstn,
      _ConsigneeAddrDfltRprstn,
      _TranspOrdItemNote
}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_TRANSPORTATIONORDER",
"I_TRANSPORTATIONORDERITEM"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_BUSTRANSDOCTYPECODE",
"I_MATERIALFREIGHTGROUP",
"I_MEANSOFTRANSPORT",
"I_PRODUCT",
"I_TRANSPORDITEMCATEGORY",
"I_TRANSPORDITEMTYPE",
"I_TRANSPORTATIONGROUP",
"I_TRANSPORTATIONMODE",
"I_TRANSPORTATIONMODECATEGORY",
"I_TRANSPORTATIONORDER",
"I_TRANSPORTATIONORDERITEM",
"I_TRANSPORTATIONORDERSTOP",
"I_UNITOFMEASURE",
"R_TRANSPORDITEMCOMMODITYCODETP",
"R_TRANSPORDITEMDOCREFTP",
"R_TRANSPORDITEMNOTETP",
"R_TRANSPORDITEMSEALTP",
"R_TRANSPORTATIONORDERTP",
"R_TRORDITMMNBPADDRDFLTRPRSTNTP"
],
"BASE":
[
"I_TRANSPORTATIONORDERITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/