R_TranspOrdItemNoteTP

@AbapCatalog.viewEnhancementCategory: [#PROJECTION_LIST]
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Transportation Order Item Note - TP'
@Metadata.ignorePropagatedAnnotations: true
@VDM: { lifecycle.contract.type: #SAP_INTERNAL_API,
        viewType: #TRANSACTIONAL }

@ObjectModel:{
        usageType:{
           serviceQuality: #C,
           sizeCategory: #L,
           dataClass: #TRANSACTIONAL
        },
        representativeKey: 'TextCollectionContentUUID'
}
define view entity R_TranspOrdItemNoteTP
  as select from            I_TextCollection        as TextCollectionRoot
    left outer to many join I_TextCollectionType    as _TextCollectionType    on TextCollectionRoot.TextCollectionUUID = _TextCollectionType.TextCollectionUUID
    left outer to one join  I_TextCollectionContent as _TextCollectionContent on _TextCollectionType.TextCollectionTypeUUID = _TextCollectionContent.TextCollectionTypeUUID

  association [0..1] to I_TransportationOrderItem          as _ProductItem             on  $projection.TransportationOrderItemUUID = _ProductItem.TransportationOrderItemUUID
                                                                                       and _ProductItem.TranspOrdItemCategory      = 'PRD'

  // association        to parent R_TransportationOrderTP as _TransportationOrder on  $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID

  association        to parent R_TransportationOrderItemTP as _TransportationOrderItem on  $projection.TransportationOrderItemUUID = _TransportationOrderItem.TransportationOrderItemUUID
  association [1..1] to R_TransportationOrderTP            as _TransportationOrder     on  $projection.TransportationOrderUUID = _TransportationOrder.TransportationOrderUUID

{
  key _TextCollectionContent.TextCollectionContentUUID   as TextCollectionContentUUID,
      _TextCollectionType.TextCollectionTypeUUID         as TextCollectionTypeUUID,
      TextCollectionRoot.TextCollectionUUID              as TextCollectionUUID,
      TextCollectionRoot.TextCollectionSchema            as TextCollectionSchema,
      _TextCollectionType.TextCollectionType             as TextCollectionType,
      @Semantics.user.createdBy: true
      _TextCollectionType.TextCollectionTextCrtedByUser  as TextCollectionTextCrtedByUser,
      @Semantics.systemDate.createdAt: true
      @Semantics.dateTime: true
      _TextCollectionType.TextCollectionTextCrtedDteTime as TextCollectionTextCrtedDteTime,
      @Semantics.systemDate.lastChangedAt: true
      @Semantics.dateTime: true
      _TextCollectionType.TextCollectionTextChgdDateTime as TextCollectionTextChgdDateTime,
      _TextCollectionType.Language                       as Language,
      _TextCollectionContent.TextCollectionContentText   as TextCollectionContentText,
      TextCollectionRoot.HostDocumentBusinessObjectUUID  as HostDocumentBusinessObjectUUID,
      TextCollectionRoot.HostDocumentBusObjNodeUUID      as HostDocumentBusObjNodeUUID,
      TextCollectionRoot.HostDocumentUUID                as TransportationOrderItemUUID,
      _ProductItem.TransportationOrderUUID               as TransportationOrderUUID,

      /* Associations */
      _TransportationOrder,
      _TransportationOrderItem

}
where
      TextCollectionRoot.DocumentHasText                = 'X'
  and _TextCollectionType.TextCollectionTypeIsInternal  = ' '
  and TextCollectionRoot.HostDocumentBusinessObjectUUID = hextobin('80E0ED0A0C021DEE8CE07DB4266D17C4') //BO: TOR

  and TextCollectionRoot.HostDocumentBusObjNodeUUID     = hextobin('80E0ED0A0DD11DDE9DEE71A51A10DEB6') //Node: Item

/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_TEXTCOLLECTION",
"I_TEXTCOLLECTIONCONTENT",
"I_TEXTCOLLECTIONTYPE",
"I_TRANSPORTATIONORDERITEM"
],
"ASSOCIATED":
[
"R_TRANSPORTATIONORDERITEMTP",
"R_TRANSPORTATIONORDERTP"
],
"BASE":
[],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/