R_SubscriptionContractTP

@EndUserText.label: 'Subscription Contract - TP'

@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@AccessControl: {
  authorizationCheck:    #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

@ObjectModel: {
    usageType: {
        dataClass:      #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory:   #L
    },
    sapObjectNodeType.name: 'SubscriptionContract',
    representativeKey: 'SubscriptionContract',
    semanticKey: ['SubscriptionContract']
}

@Metadata.ignorePropagatedAnnotations: true

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */ 
define root view entity R_SubscriptionContractTP
  as select from I_SubscriptionContract

  composition [0..*] of R_SubscriptionContractItemTP as _Item
  composition [0..*] of R_SubscrpnContrPartnerTP     as _SubscrpnContrPartner
  composition [0..*] of R_SubscrpnContrUserStatusTP  as _SubscrpnContrUserStatus
  composition [0..*] of R_SubscrpnContrDurnTP        as _SubscrpnContrDurn
  composition [0..*] of R_SubscrpnContrApptTP        as _SubscrpnContrAppt
  composition [0..1] of R_SubscrpnContrKeyFigureTP   as _SubscrpnContrKeyFigure
  composition [0..*] of R_SubscrpnContrChgProcTP     as _SubscrpnContrChgProc
  composition [0..*] of R_SubscrpnContrPrdcssrTP     as _SubscrpnContrPrdcssr
  composition [0..*] of R_SubscrpnContrSuccessorTP   as _SubscrpnContrSuccessor
  composition [0..*] of R_SubscrpnContrLongTextTP    as _SubscrpnContrLongText

  association [0..1] to I_SbsMssProcgElmContrDocChg  as _SbsMssProcgElmContrDocChg on  _SbsMssProcgElmContrDocChg.SubscriptionContract      = $projection.SubscriptionContract
                                                                                   and _SbsMssProcgElmContrDocChg.SubscrpnMassProcgElmntSts <> 'D'

  association [0..1] to E_ServiceDocument            as _Extension on  _Extension.ServiceCategory       = 'BUS2000266'
                                                                   and $projection.SubscriptionContract = _Extension.ServiceOrder

{
  key SubscriptionContract,
      SubscriptionContractType,
      SubscrpnContractDescription,
      SubscriptionContractUUID,
      ServiceObjectType,
      Language,
      SubscriptionContractPostingDte,
      @ObjectModel.foreignKey.association: '_SubscriptionContractStatus'
      SubscriptionContractStatus,
      @Semantics.booleanIndicator: true
      SubscrpnContractIsCompleted,
      @Semantics.booleanIndicator: true
      SubscriptionContractHasError,

      ServiceDocumentType,

      /* Organizational units with the S/4 SD codes */
      SalesOrganization,
      SalesOffice,
      SalesGroup,

      /* ORGANIZATION UNIT */
      SalesOrganizationOrgUnitID,
      SalesOfficeOrgUnitID,
      SalesGroupOrgUnitID,
      DistributionChannel,
      Division,
      ServiceOrganization,
      SoldToParty,
      ShipToParty,
      BillToParty,
      PayerParty,
      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPersonBusinessPartnerId,
      @ObjectModel.foreignKey.association: '_RespEmployee'
      RespEmployeeBusinessPartnerId,

      /* EXTERNAL REFERENCE*/
      PurchaseOrderByCustomer,

      CreatedByUser,
      @Semantics.dateTime:true
      CreationDateTime,
      LastChangedByUser,
      @Semantics.dateTime:true
      LastChangeDateTime,

      /* PARTNER ASSOCIATION */
      _ServiceObjType,
      _SoldToParty,
      _ShipToParty,
      _BillToParty,
      _PayerParty,
      _RespEmployee,
      _ContactPerson,

      /* ORGANIZATION ASSOCIATION */
      _SalesOrganization,
      _SalesOffice,
      _SalesGroup,
      _SalesOrganizationOrgUnit_2,
      _SalesOfficeOrgUnit_2,
      _SalesGroupOrgUnit_2,
      _DistributionChannel,
      _Division,
      _ServiceOrganizationOrgUnit_2,

      _SubscriptionContractStatus,
      _SbsMssProcgElmContrDocChg,

      /* RAP BO COMPOSITIONS */
      _Item,
      _SubscrpnContrPartner,
      _SubscrpnContrUserStatus,
      _SubscrpnContrDurn,
      _SubscrpnContrAppt,
      _SubscrpnContrKeyFigure,
      _SubscrpnContrChgProc,
      _SubscrpnContrPrdcssr,
      _SubscrpnContrSuccessor,
      _SubscrpnContrLongText

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SUBSCRIPTIONCONTRACT"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CUSTMGMTBUSOBJTYPE",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_SALESGROUP",
"I_SALESOFFICE",
"I_SALESORGANIZATION",
"I_SBSMSSPROCGELMCONTRDOCCHG",
"I_SERVICEDOCUMENTSTATUS",
"I_SRVCMGMTORGANIZATIONUNIT",
"R_SUBSCRIPTIONCONTRACTITEMTP",
"R_SUBSCRPNCONTRAPPTTP",
"R_SUBSCRPNCONTRCHGPROCTP",
"R_SUBSCRPNCONTRDURNTP",
"R_SUBSCRPNCONTRKEYFIGURETP",
"R_SUBSCRPNCONTRLONGTEXTTP",
"R_SUBSCRPNCONTRPARTNERTP",
"R_SUBSCRPNCONTRPRDCSSRTP",
"R_SUBSCRPNCONTRSUCCESSORTP",
"R_SUBSCRPNCONTRUSERSTATUSTP"
],
"BASE":
[
"I_SUBSCRIPTIONCONTRACT"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/