R_SubscriptionContractItemTP

@EndUserText.label: 'Subscription Contract Item - TP'
@VDM: {
  lifecycle.contract.type: #SAP_INTERNAL_API,
  viewType: #TRANSACTIONAL
}

@ObjectModel: {
    usageType: {
        dataClass:      #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory:   #L
    },
    semanticKey: ['SubscriptionContract', 'SubscriptionContractItem']
}

@Metadata.ignorePropagatedAnnotations: true

@AccessControl: {
  authorizationCheck: #MANDATORY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}

/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
define view entity R_SubscriptionContractItemTP
  as select from I_SubscriptionContractItem

  association        to parent R_SubscriptionContractTP as _SubscriptionContract        on  $projection.SubscriptionContract = _SubscriptionContract.SubscriptionContract

  composition [0..*] of R_SbscrContrItmStateTP          as _SbscrContrItmState
  composition [0..*] of R_SbscrContrItmChgProcTP        as _SbscrContrItmChgProc
  composition [0..*] of R_SubscrpnContrItmTechRsceTP    as _SubscrpnContrItmTechRsce
  composition [0..*] of R_SubscrpnContrItmHistTP        as _SubscrpnContrItmHist
  composition [0..*] of R_SubscrpnContrItmDiscTP        as _SubscrpnContrItmDisc
  composition [0..*] of R_SubscrpnContrItmChrgTP        as _SubscrpnContrItmChrg
  composition [0..*] of R_SbscrContrItmLockHistTP       as _SbscrContrItmLockHist
  composition [0..*] of R_SubscrpnContrItmPrElmntTP     as _SubscrpnContrItmPrElmnt
  composition [0..*] of R_SubscrpnContrItmApptTP        as _SubscrpnContrItmAppt
  composition [0..*] of R_SubscrpnContrItmDurnTP        as _SubscrpnContrItmDurn
  composition [0..*] of R_SubscrpnContrItmPrtnTP        as _SubscrpnContrItmPrtn
  composition [0..*] of R_SubscrpnContrItmRefObjTP      as _SubscrpnContrItmRefObj
  composition [0..*] of R_SubscrpnContrItmEquipTP       as _SubscrpnContrItmEquip
  composition [0..*] of R_SubscrpnContrItmUsrStsTP      as _SubscrpnContrItmUsrSts
  composition [0..*] of R_CnvChrgAllwncDefTP            as _CnvChrgAllwncDef
  composition [0..*] of R_CnvChrgAllwncTP               as _CnvChrgAllwnc
  composition [0..1] of R_SbscrContrItmAllwncKeyFigTP   as _SbscrContrItmAllwncKeyFig
  composition [0..1] of R_SubscrpnContrItmKeyFigTP      as _SubscrpnContrItmKeyFig
  composition [0..*] of R_SubscrpnContrItmDteParamTP    as _SubscrpnContrItmDteParam
  composition [0..*] of R_SubscrpnContrItmNmrcParamTP   as _SubscrpnContrItmNmrcParam
  composition [0..*] of R_SubscrpnContrItmStrParamTP    as _SubscrpnContrItmStrParam
  composition [0..*] of R_SubscrpnContrItmTblParamTP    as _SubscrpnContrItmTblParam
  composition [0..*] of R_SubscrpnContrItmConfignTP     as _SubscrpnContrItmConfign
  composition [0..*] of R_SubscrpnContrItmPrdcssrTP     as _SubscrpnContrItmPrdcssr
  composition [0..*] of R_SubscrpnContrItmSuccessorTP   as _SubscrpnContrItmSuccessor
  composition [0..*] of R_SubscrpnContrItemLongTextTP   as _SubscrpnContrItemLongText
  composition [0..*] of R_SbscrContrItmBlgReqItmTP      as _SbscrContrItmBlgReqItm
  
  association [0..1] to I_SbsMssProcgElmntContrItmChg   as _SbsMssProcgElmntContrItmChg on  _SbsMssProcgElmntContrItmChg.SubscriptionContract     = $projection.SubscriptionContract
                                                                                        and _SbsMssProcgElmntContrItmChg.SubscriptionContractItem = $projection.SubscriptionContractItem
                                                                                        and _SbsMssProcgElmntContrItmChg.SubscrpnMassProcgElmntSts <> 'D'

  association [0..1] to E_ServiceDocumentItem           as _Extension                   on  _Extension.ServiceCategory           = 'BUS2000266'
                                                                                        and $projection.SubscriptionContract     = _Extension.ServiceOrderItem
                                                                                        and $projection.SubscriptionContractItem = _Extension.ServiceLineExternalID

{

  key SubscriptionContract,
  key SubscriptionContractItem,
      SubscriptionContractExternalID,
      ServiceObjectType,
      ServiceDocumentType,
      SubscrpnContractItemCategory,
      Product,
      SubscrpnProductSpecification,
      /* QUANTITY */
      @Semantics: { quantity : {unitOfMeasure: 'QuantityUnit'} }
      Quantity,
      @ObjectModel.foreignKey.association: '_SalesUnit'
      QuantityUnit,

      /* AMOUNTS */
      TransactionCurrency,

      // Contract Values

      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      SubscrpnContrItmGrossAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      SubscrpnContrItmNetAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      SubscrpnContrItmNetAmount   as SubscrpnContrItmDspNetAmount,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      SubscrpnContrItmTaxAmount,
      // One Time Values

      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      SubscrpnContrItmNetAmount   as SubscrpnContrItmOneTmeNetAmt,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      SubscrpnContrItmGrossAmount as SubscrpnContrItmOneTmeGrossAmt,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      SubscrpnContrItmTaxAmount   as SubscrpnContrItmOneTmeTaxAmt,
      // Recurring Values

      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      SbscrContrItmRecrrgChrgNetAmt,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      SbscrContrItmRecrrgChrgGrssAmt,
      @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
      SbscrContrItmRecrrgChrgTaxAmt,

      /* PRICING */
      @ObjectModel.foreignKey.association: '_PaymentTerms'
      PaymentTerms,
      @ObjectModel.foreignKey.association: '_CAPartnerSettlementRule'
      CAPartnerSettlementRule,

      /* ITEM DETAILS */
      SubscriptionContrItmDesc,
      @Semantics.uuid: true
      SubscriptionContractUUID,
      @Semantics.uuid: true
      SubscriptionContractItemUUID,
      @Semantics.uuid: true
      SubscrpnContrItmCharUUID,
      @Semantics.uuid: true
      ParentSubscrpnContractItemUUID,
      SubscrpnOrdProdSelType,
      @Semantics.booleanIndicator: true
      SubscrpnContrItmIsMainItem,
      Language,


      /* ORGANIZATIONAL UNITS WITH THE S/4 SD CODES */
      SalesOrganization,
      DistributionChannel,
      Division,
      SalesOffice,
      SalesGroup,

      /* ORGANIZATION UNIT */
      SalesOrganizationOrgUnitID,
      SalesOfficeOrgUnitID,
      SalesGroupOrgUnitID,
      ServiceOrganization,


      /* STATUS */
      @Semantics.booleanIndicator: true
      SubscrpnContractItemIsActive,
      @Semantics.booleanIndicator: true
      SubscrpnContractItemIsRejected,
      @Semantics.booleanIndicator: true
      SubscrpnContrItmIsCancelled,
      @ObjectModel.foreignKey.association: '_SubscrpnContrItmItemStatus'
      SubscriptionContractItemStatus,
      @Semantics.booleanIndicator: true
      SubscrpnContrItmHasError,
      @ObjectModel.foreignKey.association: '_SrvcDocItemCreditStatus'
      SubscrpnContrItmCrdtSts,
      @ObjectModel.foreignKey.association: '_SubscrpnContrItmActvtnSts'
      SubscrpnContrActivationStatus,
      SubscrpnContrTimeSliceStatus,

      /* CANCELLATION */
      SbscrContrItmCanclnProcedure,
      @ObjectModel.foreignKey.association: '_SbscrContrItmCanclnRsn'
      SbscrContrItemCanclnReason,
      @ObjectModel.foreignKey.association: '_SbscrContrItmCanclnPty'
      SbscrContrItemCanclnParty,
      @ObjectModel.foreignKey.association: '_ServiceDocItemRejectionReason'
      SubscrpnContrItmRjcnRsn,

      /* DATES */
      @Semantics.dateTime:true
      SubscrpnContrItmCanclnDteTme,
      @Semantics.dateTime:true
      SubscrpnContrItmStartDateTime,
      @Semantics.dateTime:true
      SubscrpnContrItmEndDateTime,
      @Semantics.dateTime:true
      SbscrContrTimeSliceStrtDteTme,
      @Semantics.dateTime:true
      SbscrContrTimeSliceEndDteTme,

      /* AUTO RENEWAL */
      @Semantics.booleanIndicator: true
      SubscrpnContrAutoRnwlIsActv,
      @Semantics.booleanIndicator: true
      SubscrpnContrAutoRnwlIsActv as SbscrContrAutoRnwlIsActvForDsp,
      @Semantics.dateTime:true
      SubscrpnContrItmRnwlDteTme,
      @Semantics: { quantity : {unitOfMeasure: 'SrvcContrItemRnwlDurationUnit'} }
      SrvcContrItemRnwlDuration,
      SrvcContrItemRnwlDurationUnit,
      @Semantics: { quantity : {unitOfMeasure: 'SrvcContrItemExtnDurationUnit'} }
      SrvcContrItemExtensionDuration,
      SrvcContrItemExtnDurationUnit,

      /* EXTERNAL REFERENCE*/
      PurchaseOrderByCustomer,
      PurchaseOrderByShipToParty,

      /* CHANGE PROCESS */
      SrvcTransChangeProcess,
      SrvcTransChangeProcessType,
      SrvcTransChangeProcessGroup,

      /* PARTNER */
      SoldToParty,
      ShipToParty,
      BillToParty,
      PayerParty,
      @ObjectModel.foreignKey.association: '_ContactPerson'
      ContactPersonBusinessPartnerId,
      @ObjectModel.foreignKey.association: '_RespEmployee'
      RespEmployeeBusinessPartnerId,
      ContractAccount,

      /* SUBSCRIPTION SPECIFIC */
      CABillgCycle,
      SubscrpnContrItmBillgPlnCyc,
      CrsCatalogMappingVersionNumber,
      SbscrContrItmRecrrgChrgDurn,
      SbscrContrItmRcrChrDurUnit,

      /* MASTER AGREEMENT */
      CustMgmtMasterAgreement,
      CustMgmtMstrAgrmtItem,
      CustMgmtMstrAgrmtParentItem,
      SbscrShContrSvTrMtAgrItmUUID,
      SbscrShContrSvTrMtAgrItmCstPrd,
      @Semantics.booleanIndicator:true
      SvTrMtAgrItmIsFxdConfign,

      /* SHARING */
      SharingContractID,
      SubscrpnContractSharingGroupID,

      /* CONFIGURATION */
      ConfigurationNumber,
      @Semantics.booleanIndicator: true
      SubscrpnContrItmHasConfign,

      /* PHASED DEAL */
      @Semantics.booleanIndicator: true
      SubscrpnContrItemIsPhased,
      SbscrContrItmPhasedPrdcssrItm,

      /* CREATED, CHANGED USER ID */
      SubscrpnContrItmPostgDte,
      SubscrpnContrItmCrtedByUsr,
      SubscrpnContrItmChgdByUsr,
      @Semantics.dateTime:true
      SubscrpnContrItmCrtnDteTme,
      @Semantics.dateTime:true
      SubscrpnContrItmChgdDteTme,

      /* RAP : Inheritance of Complex Set */
      SubscrpnContrItmPrtnRefItm,
      SubscrpnContrItmApptRefObjUUID,
      SubscrpnContrItmApptRefItm,

      /* Withdrawal */
      @Semantics.booleanIndicator: true
      SubscrpnContrItmIsWithdrawn,
      @ObjectModel.foreignKey.association: '_SubscrpnContrItmWthdrwlRsn'
      SubscrpnContrItmWthdrwlRsn,
      @ObjectModel.foreignKey.association: '_SubscrpnContrItmRfndType'
      SubscrpnContrItmRfndType,

      /* Account Assignment e.g. WBS Element for Type = '03' */
      SbscrContrItmAcctAssgmtObjType,
      SbscrContrItmAcctAssgmtObject,
      WBSElementExternalID,

      /* Item Usage - Item Origin */
      SubscrpnContrSubitemOrigin,

      /* Billing */
      SubscrpnContrItmBillgPlnType,

      /* ASSOCIATIONS */
      /* ITEM KEY ASSOCIATION */
      _ServiceObjType,
      _ParentServiceDocItem_2,

      // ITEM - PRODUCT ASSOCIATION */

      _SalesUnit,
      _Product,

      /* MASTER AGREEMENT */
      _SrvcTransMasterAgreementItem,
      _SbscrShContrSvTrMtAgrItm,

      /* PARTNER ASSOCIATION */
      _SoldToParty,
      _ShipToParty,
      _BillToParty,
      _PayerParty,
      _RespEmployee,
      _ContactPerson,
      _ContractAccountPartner,

      /* ORGANIZATION ASSOCIATION */
      _SalesOrganization,
      _SalesOffice,
      _SalesGroup,
      _SalesOrganizationOrgUnit_2,
      _SalesOfficeOrgUnit_2,
      _SalesGroupOrgUnit_2,
      _DistributionChannel,
      _Division,
      _ServiceOrganizationOrgUnit_2,

      /* PRICING ASSOCIATION */
      _TransactionCurrency,
      _PaymentTerms,

      /* ITEM - SERVICE ASSOCIATION */
      _SrvcContrItemRnwlDurationUnit,
      _SrvcContrItemExtnDurationUnit,


      /* SUBSCRIPTION ASSOCIATION */
      _CrsCtlgUsableMappingVersion,
      _BillgCycle,
      _BillgPlanCycle,
      _TechResource,
      _ExternalReference,
      _CAPartnerSettlementRule,
      _SubscrpnContrItmShrngGrp,
      _SrvcDocDurationUnitText,
      _SubscrpnProdSpec,
      _SubscrpnProductSpecification,
      _SbsMssProcgElmntContrItmChg,

      /* STATUS */
      _SubscrpnContrItmActvtnSts,
      _SubscrpnContrItmItemStatus,
      _SrvcDocItemCreditStatus,


      /* CANCELLATION */
      _SbscrContrItmCanclnPty,
      _SbscrContrItmCanclnRsn,
      _ServiceDocItemRejectionReason,

      /* WITHDRAWAL */
      _SubscrpnContrItmWthdrwlRsn,
      _SubscrpnContrItmRfndType,

      /* WBS Element */
      _WBSElementBasicData,

      /* RAP BO COMPOSITIONS */
      _SubscriptionContract,
      _SbscrContrItmState,
      _SbscrContrItmChgProc,
      _SubscrpnContrItmTechRsce,
      _SubscrpnContrItmHist,
      _SubscrpnContrItmDisc,
      _SubscrpnContrItmChrg,
      _SbscrContrItmLockHist,
      _SubscrpnContrItmPrElmnt,
      _SubscrpnContrItmAppt,
      _SubscrpnContrItmDurn,
      _SubscrpnContrItmPrtn,
      _SubscrpnContrItmRefObj,
      _SubscrpnContrItmEquip,
      _SubscrpnContrItmUsrSts,
      _CnvChrgAllwncDef,
      _CnvChrgAllwnc,
      _SbscrContrItmAllwncKeyFig,
      _SubscrpnContrItmKeyFig,
      _SubscrpnContrItmDteParam,
      _SubscrpnContrItmNmrcParam,
      _SubscrpnContrItmStrParam,
      _SubscrpnContrItmTblParam,
      _SubscrpnContrItmConfign,
      _SubscrpnContrItmPrdcssr,
      _SubscrpnContrItmSuccessor,
      _SubscrpnContrItemLongText,
      _SbscrContrItmBlgReqItm

}
/*+[internal] {
"BASEINFO":
{
"FROM":
[
"I_SUBSCRIPTIONCONTRACTITEM"
],
"ASSOCIATED":
[
"I_BUSINESSPARTNER",
"I_CABILLGCYCLE",
"I_CAPARTNERSETTLEMENTRULE",
"I_CONTRACTACCOUNTPARTNER",
"I_CRSCTLGUSABLEMAPPINGVERSION",
"I_CURRENCY",
"I_CUSTMGMTBUSOBJTYPE",
"I_DISTRIBUTIONCHANNEL",
"I_DIVISION",
"I_PAYMENTTERMS",
"I_PRODUCT",
"I_SALESDOCUMENTRJCNREASON",
"I_SALESGROUP",
"I_SALESOFFICE",
"I_SALESORGANIZATION",
"I_SBSCRCONTRITMCANCLNPTY",
"I_SBSCRCONTRITMCANCLNRSN",
"I_SBSMSSPROCGELMNTCONTRITMCHG",
"I_SERVICEDOCUMENTITEMENHCD",
"I_SERVICEDOCUMENTSTATUS",
"I_SRVCDOCDURATIONUNITTEXT",
"I_SRVCDOCITEMCREDITSTATUS",
"I_SRVCMGMTORGANIZATIONUNIT",
"I_SRVCTRANSMASTERAGREEMENTITEM",
"I_SUBSCRPNCONTRITMACTVTNSTS",
"I_SUBSCRPNCONTRITMEXTREF",
"I_SUBSCRPNCONTRITMRFNDTYPE",
"I_SUBSCRPNCONTRITMSHRNGGRP",
"I_SUBSCRPNCONTRITMWTHDRWLRSN",
"I_SUBSCRPNITMTECHRESOURCE",
"I_SUBSCRPNPRODSPEC",
"I_UNITOFMEASURE",
"I_WBSELEMENTBASICDATA",
"R_CNVCHRGALLWNCDEFTP",
"R_CNVCHRGALLWNCTP",
"R_SBSCRCONTRITMALLWNCKEYFIGTP",
"R_SBSCRCONTRITMBLGREQITMTP",
"R_SBSCRCONTRITMCHGPROCTP",
"R_SBSCRCONTRITMLOCKHISTTP",
"R_SBSCRCONTRITMSTATETP",
"R_SUBSCRIPTIONCONTRACTTP",
"R_SUBSCRPNCONTRITEMLONGTEXTTP",
"R_SUBSCRPNCONTRITMAPPTTP",
"R_SUBSCRPNCONTRITMCHRGTP",
"R_SUBSCRPNCONTRITMCONFIGNTP",
"R_SUBSCRPNCONTRITMDISCTP",
"R_SUBSCRPNCONTRITMDTEPARAMTP",
"R_SUBSCRPNCONTRITMDURNTP",
"R_SUBSCRPNCONTRITMEQUIPTP",
"R_SUBSCRPNCONTRITMHISTTP",
"R_SUBSCRPNCONTRITMKEYFIGTP",
"R_SUBSCRPNCONTRITMNMRCPARAMTP",
"R_SUBSCRPNCONTRITMPRDCSSRTP",
"R_SUBSCRPNCONTRITMPRELMNTTP",
"R_SUBSCRPNCONTRITMPRTNTP",
"R_SUBSCRPNCONTRITMREFOBJTP",
"R_SUBSCRPNCONTRITMSTRPARAMTP",
"R_SUBSCRPNCONTRITMSUCCESSORTP",
"R_SUBSCRPNCONTRITMTBLPARAMTP",
"R_SUBSCRPNCONTRITMTECHRSCETP",
"R_SUBSCRPNCONTRITMUSRSTSTP"
],
"BASE":
[
"I_SUBSCRIPTIONCONTRACTITEM"
],
"ANNO_REF":
[],
"SCALAR_FUNCTION":
[],
"VERSION":0,
"ANNOREF_EVALUATION_ERROR":""
}
}*/